[kallioma]

Путь к xml надо указывать полностью!

[Spirkaa]

Столкнулся с проблемой. При установке OS на диск D:\, Photoshop устанавливается на C:\. Я попробЫвал изменить путь в файле Deployment.xml с

Код:

<Property name="INSTALLDIR">C:\Program Files\Adobe</Property><Property name="installLanguage">en_US</Property></Properties>

на

Код:

<Property name="INSTALLDIR">%PROGRAMFILES%\Adobe</Property><Property name="installLanguage">en_US</Property></Properties>

но сабж не установился вообще

Помогите разобраться, хочется универсальности

[hobbit25]

ПОМОГИТЕ растолкуйте как можно запустить его из CMD файла !! и нужно ли прописывать конкретные пути к XML файлам

[Salt]

hobbit25
Вот пример простейшего CMD-файла, запускающего автоматическую установку Adobe Photoshop CS3 в Windows XP Rus:

Код:

@ECHO OFF

CHDIR /D "%~dp0"

REM Установка Adobe Photoshop CS3
START "Adobe Photoshop CS3 Setup" /WAIT setup.exe --mode=Silent --deploymentFile=Deployment.xml

REM Остановка службы Bonjour
REG ADD "HKLM\SYSTEM\CurrentControlSet\Services\Bonjour Service" /V "Start" /T REG_DWORD /D "4" /F

REM Создание ярлыков в панели Быстрого запуска для текущего и будущих пользователей
COPY /B /Y "%ALLUSERSPROFILE%\Главное меню\Программы\Adobe Photoshop CS3.lnk" "%SYSTEMDRIVE%\Documents and Settings\Default User\Application Data\Microsoft\Internet Explorer\Quick Launch"
COPY /B /Y "%ALLUSERSPROFILE%\Главное меню\Программы\Adobe Photoshop CS3.lnk" "%USERPROFILE%\Application Data\Microsoft\Internet Explorer\Quick Launch"

EXIT

Файл с этим командным сценарием следует поместить в ту же папку, где находятся файлы setup.exe и Deployment.xml дистрибутива Photoshop CS3.

[vek]

hobbit25
У меня примерно так-же как и у Salt:
Установка:

читать дальше »

Файл setup.bat (находится в корневой папке, вместе с Setup.exe и Deployment.xml):

Код:

cmdow @ /HID
@ECHO OFF
SET wdir=%~dp0
SET wdir=%wdir:~0,-1%

@ECHO Install Photoshop CS3
Start /wait %wDir%\setup.exe --mode=Silent --deploymentFile=Deployment.xml
@ECHO Registring Photoshop CS3
xcopy "%wDir%\photoshop.exe" "%PROGRAMFILES%\Adobe\Adobe Photoshop CS3\" /y /s /e /q

@ECHO Shortcut Photoshop CS3
attrib -a "%ALLUSERSPROFILE%\Главное меню\Программы\Adobe Photoshop CS3.lnk"
MKDIR "%ALLUSERSPROFILE%\Главное меню\Программы\Графика"
xcopy "%ALLUSERSPROFILE%\Главное меню\Программы\Adobe Photoshop CS3.lnk" "%ALLUSERSPROFILE%\Главное меню\Программы\Графика" /y /q
DEL /F /Q "%SYSTEMDRIVE%\Documents and Settings\All Users\Главное меню\Программы\Adobe Photoshop CS3.lnk"

где photoshop.exe - файл регистрации (находится в корневой папке, вместе с Setup.exe и Deployment.xml)

Файл конфигурации для 7z:

читать дальше »

Код:

;!@Install@!UTF-8!
RunProgram="hidcon:\"Setup.bat\""
InstallPath="%SystemRoot%\\TEMP\\"
GUIMode="2"
;!@InstallEnd@!

Установка дополнений:

читать дальше »

Структура папок
[Action]
[Brushes]
[Filters]
[Patterns]
[Shapes]
[Styles]
Install.cmd
Содержимое Install.cmd

Код:

@ECHO off
SET wdir=%~dp0
SET wdir=%wdir:~0,-1%
SET pscs=%SYSTEMDRIVE%\Program Files\Adobe\Adobe Photoshop CS3
xcopy "%wDir%\Action" "%pscs%\Presets\Actions\" /s /e /y 
xcopy "%wDir%\Brushes" "%pscs%\Presets\Brushes\" /s /e /y
xcopy "%wDir%\Filters" "%pscs%\Plug-Ins\Filters\" /s /e /y
xcopy "%wDir%\Patterns" "%pscs%\Presets\Patterns\" /s /e /y
xcopy "%wDir%\Shapes" "%pscs%\Presets\Custom Shapes\" /s /e /y
xcopy "%wDir%\Styles" "%pscs%\Presets\Styles\" /S /e /y
exit

Упаковывать все это дело не стал, чтоб удобней было обновлять или редактировать.

[hobbit25]

vekphotoshop.exe а этим файликом можеш поделиться я к те в аську стуканулся ты в офлайне можеш зайти там добнее пораспросить будет!!

Salt спасиюо буду пробовать!!!

[hobbit25]

Salt

CS3>\payloads\AdobePhotoshop10en_US_volume под именем application.xml.override

а расшмрение у файлика какое должно быть???

[Spirkaa]

hobbit25 .override и есть расширение

Так никто и не знает как быть с установкой на другой диск ?

[Salt]

Spirkaa
В свойстве INSTALLDIR нельзя использовать переменные, надо указывать абсолютный путь. В Базе знаний и на форумах Adobe, к сожалению, не нашел ответа на Ваш вопрос.

Могу предложить только такое, не слишком изящное, но вполне работоспособное решение: поместите прикрепленные к этому сообщению два файла в папку с дистрибутивом CS3, создайте файл с командным сценарием, приведенным ниже, скопируйте его туда же, запустите CMD-файл... и Photoshop CS3 установится в %ProgramFiles%\Adobe

CMD-файл

Код:

@ECHO OFF

CHDIR /D "%~dp0"

ECHO %PROGRAMFILES%\Adobe > "%TEMP%\PF.txt"
COPY /Y Head.txt + "%TEMP%\PF.txt" + Tail.txt "%TEMP%\Install.xml" /B

REM Установка Adobe Photoshop CS3
START "Adobe Photoshop CS3 Setup" /WAIT setup.exe --mode=Silent --deploymentFile="%TEMP%\Install.xml"

DEL /F /Q "%TEMP%\PF.txt"
DEL /F /Q "%TEMP%\Install.xml"

[MaxDELETE]

Столкнулся с такой проблемой:
Для установки прог пользуюсь WPI (сейчас версия 6)
Ну соответственно в конфиге прописываю путь , т.е. ...Setup.exe --mode=Silent --deploymentFile=Deployment.xml
Запускаю, скрипт отраюатывает секунд 10 и все. В диспетчере задач процесс Setup.exe тоже соответственно отображается, а потом вылетает.
Запускаю то же самое при помощи "Выполнить" и все проходит на ура.
Вот мне просто интересно в чем проблема