[Iska]

И, кстати,зачем? »

Затем:

готовый скрипт? »

Не должно быть более 1 точки или 1 тире подряд. Точка-тире или тире-точка или подобные сочетания недопустимы. »

Точек подряд быть не может — это разделитель. Тире Дефис — может. Вы же не хотите отсечь национальные домены, в том числе такой домен, как, например, президент.рф ?

Пример с шаблоном, найденным мною, и шаблоном коллеги DJ Mogarych:

Скрытый текст

Код:

Option Explicit

Dim arrDNSName
Dim objRegExp

Dim elem


arrDNSName = Array( _
				"device.domain.zone", _
				"Device1.domain1.ru", _
				"device-2.domain.1.ru3", _
				"45-deVice.3.domain-4.5ru", _
				"45-deVice..domain-4.5ru", _
				"45-deVice.3.domain--4.5ru", _
				"45-deVice.3.domain-.5ru", _
				"45-deVice.3.-domain.5ru", _
				"45-deVice.3.domain-4.5ru." _
			)

Set objRegExp = WScript.CreateObject("VBScript.RegExp")

objRegExp.IgnoreCase = False
objRegExp.Pattern    = "^([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9])(\.([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9]))*$"

For Each elem In arrDNSName
	If objRegExp.Test(elem) Then
		WScript.Echo "Match    : " & elem
	Else
		WScript.Echo "Not match: " & elem
	End If
Next

WScript.Echo "==============================================="

objRegExp.Pattern    = "^([A-Za-z0-9-]+\.){2}[A-Za-z0-9-]+$"

For Each elem In arrDNSName
	If objRegExp.Test(elem) Then
		WScript.Echo "Match    : " & elem
	Else
		WScript.Echo "Not match: " & elem
	End If
Next

Set objRegExp = Nothing

WScript.Quit 0

[glukin]

Спасибо.
И всё-таки: точка-дефис или дефис-точка или подобные сочетания недопустимы.
Да,я хочу отсечь национальные домены, ибо DNS внутренний, а не интернетный.

[Iska]

И всё-таки: точка-дефис или дефис-точка или подобные сочетания недопустимы. »

Первое и второе недопустимы. Разве я сказал что-то другое?!

ибо DNS внутренний, а не интернетный. »

А какая разница? Пространство имён одинаково для всех. Реализации локальных серверов могут отличаться в ту или иную степень упоротости, хотите упарываться вослед — делайте, кто ж запретит.

[YuS_2]

Первое и второе недопустимы. »

Вроде бы, не совсем так:

Код:

<#
[enum]::GetNames("UriHostNameType")
Basic		1	узел установлен, однако не удается определить тип.
Dns		2	Имя узла представлено в виде DNS-имени.
IPv4		3	Имя узла представлено в формате IPv4.
IPv6		4	Имя узла представлено в формате IPv6.
Unknown	0	Тип имени узла не поддерживается.
#>

$arr = @(
	"device.domain.zone"
	"device.domain.zone."
	".device.domain.zone"
	"Device1.domain1.ru"
	"device-2.domain.1.ru3"
	"45-deVice.3.domain-4.5ru"
	"45-deVice..domain-4.5ru"
	"45-deVice.3.domain--4.5ru"
	"45-deVice.3.domain-.5ru"
	"45-deVice.3.-domain.5ru"
	"45-deVice.3.domain-4.5ru."
)
$arr|%{ $_ + ' - ' + ([uri]::CheckHostName("$_"))}

[Iska]

YuS_2, я исходил из RFC 1034 - Domain names - concepts and facilities:

Код: <domain> ::= <subdomain> | " " <subdomain> ::= <label> | <subdomain> "." <label> <label> ::= <letter> [ [ <ldh-str> ] <let-dig> ] <ldh-str> ::= <let-dig-hyp> | <let-dig-hyp> <ldh-str> <let-dig-hyp> ::= <let-dig> | "-" <let-dig> ::= <letter> | <digit> <letter> ::= any one of the 52 alphabetic characters A through Z in upper case and a through z in lower case <digit> ::= any one of the ten digits 0 through 9

Как можно увидеть, дефис ни в начале октета, ни в конце октета наличествовать не может. В начале октета может быть только буква, в конце октета — только буква или цифра.

[Busla]

Iska, октет тут наверное не при чём

glukin, сделайте простую проверку, какую сможете
а более строго проверит уже то ПО, которое будет эти данные использовать

[glukin]

Busla, не, тут смысл сделать проверку именно до ПО, так как оно не стартует с ошибочными dns-записями.

Iska, извините, забыл добавить, что "--" тоже недопустимо.
Вот это вроде работает, но пропускает "--"
^([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9])(\.([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9]))*$

[Iska]

Iska, октет тут наверное не при чём »

Да, попутал термины.

что "--" тоже недопустимо. »

Я же писал, с точки зрения RFC — допустимо.

Вот это вроде работает, но пропускает "--" »

Ну, дабы не усложнять регулярку, сделайте две проверки:

Скрытый текст

Код:

Option Explicit

Dim arrDNSName
Dim elem


arrDNSName = Array( _
				"device.domain.zone", _
				"Device1.domain1.ru", _
				"device--2.domain.1.ru3", _
				"45-deVice.3.domain-4.5ru", _
				"45-deVice..domain-4.5ru", _
				"45-deVice.3.domain--4.5ru", _
				"45-deVice.3.domain-.5ru", _
				"45-deVice.3.-domain.5ru", _
				"45-deVice.3.domain-4.5ru." _
			)

With WScript.CreateObject("VBScript.RegExp")
	.IgnoreCase = False
	
	For Each elem In arrDNSName
		.Pattern    = "^([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9])(\.([a-zA-Z0-9]|[a-zA-Z0-9][a-zA-Z0-9\-]{0,61}[a-zA-Z0-9]))*$"
		
		If .Test(elem) Then
			.Pattern = "-{2,}"
			
			If Not .Test(elem) Then
				WScript.Echo "Match    : " & elem
			Else
				WScript.Echo "Not match: " & elem
			End If
		Else
			WScript.Echo "Not match: " & elem
		End If
	Next
End With

WScript.Quit 0

[YuS_2]

я исходил из RFC 1034 - Domain names - concepts and facilities: »

Да, возможно, спорить не буду.
Просто, есть подозрение, что RFC датированный 1987 годом, наверное несколько устарел, к тому же, не думаю, что микрософт выпускает софт противоречащий неким стандартам доменных имен. Искать стандарты просто лень, но есть ссылка на документацию от микрософт.

[glukin]

Iska,

Ну, дабы не усложнять регулярку, сделайте две проверки »

Спасибо, вроде все как мне нужно работает! Тему можно закрывать.