[Iska]

Ну, тогда как-то так:

Код:

^(.+) (\d+) (\d+) (\d+)(?:| (.+))$

VB6 у меня под рукой нету, на WSH выглядит так:

Скрытый текст

Код:

Option Explicit

Dim objFSO
Dim arrContent
Dim objRegExp

Dim elem
Dim i


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

With objFSO.OpenTextFile("C:\Мои проекты\0041\0001.txt")
	arrContent = Split(.ReadAll(), vbCrLf)
	.Close
End With

Set objRegExp = WScript.CreateObject("VBScript.RegExp")

objRegExp.Pattern = "^(.+) (\d+) (\d+) (\d+)(?:| (.+))$"

For Each elem In arrContent
	WScript.Echo elem
	
	If objRegExp.Test(elem) Then
		With objRegExp.Execute(elem).Item(0).Submatches
			For i = 0 To .Count - 1
				WScript.Echo vbTab, i, ": [" & .Item(i) & "]"
			Next
		End With
	End If
	
	WScript.Echo
Next

Set objRegExp = Nothing
Set objFSO = Nothing

WScript.Quit 0

Скрытый текст

Обратите внимание: поскольку Вы пишете про «андроид, юникс система» — вероятно, концы строк в файле будут в формате Unix, и тогда потребуется заменить в Split() vbCrLf на vbLf.

[blackeangel]

Iska, классно работает, но разжуйте этот кусок

Код:

For Each elem In arrContent
	WScript.Echo elem 'вывод 
	
	If objRegExp.Test(elem) Then
		With objRegExp.Execute(elem).Item(0).Submatches
			For i = 0 To .Count - 1
				WScript.Echo vbTab, i, ": [" & .Item(i) & "]" 'вывод 
			Next
		End With
	End If
	WScript.Echo 'вывод 
Next

Особенно эти 3 строки

Код:

	If objRegExp.Test(elem) Then
		With objRegExp.Execute(elem).Item(0).Submatches
			For i = 0 To .Count - 1

И как выводить все это не на экран, а в массив?
А VB6 портативный вот https://yadi.sk/d/5TQWB-A83DvtLx

[Iska]

А VB6 портативный вот https://yadi.sk/d/5TQWB-A83DvtLx »

Я, пожалуй, воздержусь от такого.

И как выводить все это не на экран, а в массив? »

А зачем Вам массив? Что Вы с ним делать будете? Ладно, число токенов известно заранее — пять, но число строк-то неизвестно. И делать каждый раз Redim Preserve?! Или сначала посчитать строки, а затем определять размер массива?! Ни то, ни другое не есть хорошо и правильно. Здесь я бы использовал словарь, содержащий в качестве ключа — саму строку, а в качестве значения — коллекцию SubMatches из токенов.

Код — чтение из файла в словарь и пример работы со словарём

Код:

Option Explicit

Sub Main()
    Dim objFSO As New FileSystemObject
    Dim arrContent() As String
    Dim objRegExp As New RegExp
    Dim objTokens As New Dictionary
    
    Dim elem As Variant
    Dim i As Integer
    
    Dim strKey As Variant
    Dim strToken As Variant
    
    
    With objFSO.OpenTextFile("C:\Temp\0002\0001.txt")
        arrContent = Split(.ReadAll(), vbCrLf)
        .Close
    End With
    
    objRegExp.Pattern = "^(.+) (\d+) (\d+) (\d+)(?:| (.+))$"
    
    For Each elem In arrContent
        If objRegExp.Test(elem) Then
            With objRegExp.Execute(elem).Item(0)
                objTokens.Add elem, .Submatches
            End With
        End If
    Next elem
    
    For Each strKey In objTokens
        Debug.Print strKey
        
        For Each strToken In objTokens.Item(strKey)
            Debug.Print vbTab, i, ": [" & strToken & "]"
        Next strToken
    Next strKey
    
    Set objRegExp = Nothing
    Set objFSO = Nothing
End Sub

Картинка с демонстрацией результата работы кода

Сам проект в архиве: SampleProject.7z.

[Iska]

но разжуйте этот кусок »

Код:

For Each elem In arrContent ' Для каждого элемента из массива строк…
	WScript.Echo elem
	
	If objRegExp.Test(elem) Then ' Строка подходит под заданный шаблон?
		With objRegExp.Execute(elem).Item(0).Submatches ' Наложить шаблон на строку, взять первое из совпадений, взять для него коллекцию подгрупп
			For i = 0 To .Count - 1 ' Перебрать всю коллекцию подгрупп, от первого её элемента до последнего
				WScript.Echo vbTab, i, ": [" & .Item(i) & "]" ' Вывести очередную подгруппу
			Next
		End With
	End If

	WScript.Echo
Next

[blackeangel]

Iska, количество строк тоже известно оно равно кол-ву строк прочитанного файла.А вот как записать это в массив это что то не понятное. 2 раза for? 1й по количеству строк, второй по столбцам.
Что с массивом делать буду? Ой, много чего. И так крутить и сяк вертеть и накладывать на другой.

Код:

For i = 0 To .Count - 1
For k = LBound(arrContent) to UBound(arrContent)
For l = 0 to 4
arr(k,l) = arrContent(l)
Next: Next: Next

Или как то по другому?

[Iska]

Iska, количество строк тоже известно оно равно кол-ву строк прочитанного файла. »

blackeangel, а) заранее не известно и б) кто сказал, что все строки попадут под шаблон? Так что так.

Что с массивом делать буду? Ой, много чего. И так крутить и сяк вертеть и накладывать на другой. »

Ну, давайте, рассказывайте как обгонял, как подрезал, что и как будете с ним делать. Хотелось бы увидеть и понять преимущества использования в данном конкретном случае массива перед тем же словарём или таблицей базы данных.

Или как то по другому? »

От Вы упорный. Говорю же — нельзя заранее предсказать, сколько строк попадёт под шаблон. Да даже тупо будет где-нибудь пустая строка (например, в конце файла) — и уже отличие. Поизвращаться можно, но я хочу понять — зачем.

[blackeangel]

Iska, количество строк тоже известно оно равно кол-ву строк прочитанного файла. » blackeangel, а) заранее не известно и б) кто сказал, что все строки попадут под шаблон? Так что так. Что с массивом делать буду? Ой, много чего. И так крутить и сяк вертеть и накладывать на другой. » Ну, давайте, рассказывайте как обгонял, как подрезал, что и как будете с ним делать. Хотелось бы увидеть и понять преимущества использования в данном конкретном случае массива перед тем же словарём или таблицей базы данных. Или как то по другому? » От Вы упорный. Говорю же — нельзя заранее предсказать, сколько строк попадёт под шаблон. Да даже тупо будет где-нибудь пустая строка (например, в конце файла) — и уже отличие. Поизвращаться можно, но я хочу понять — зачем.

Ну пустая строка в конце файла это не проблема - гонять цикл на одну строку меньше.
Так шаблон один, как вы говорите, универсальный, так и кладем его на файл, который читаем. В котором куча всего.

[blackeangel]

Например, содержимое этого файла надо загнать в массив, разбить на столбцы. Ваш шаблон подо все подойдет? Вроде да. Или ошибаюсь? Я старался предусмотреть все варианты.
А что с ним делается дальше смотрите тут
https://gist.github.com/blackeangel/...239ad6898343e6

[Iska]

А что с ним делается дальше смотрите тут »

blackeangel, словами, словами рассказывайте. Чем и как массив лучше словаря или таблицы БД.

[blackeangel]

А что с ним делается дальше смотрите тут » blackeangel, словами, словами рассказывайте. Чем и как массив лучше словаря или таблицы БД.

БД вообще мне не нужна для задачи.
А словарь не катит ТК не поддерживает частичного совпадения. И самое главное - про словарь не знаю ничего, не разу им не пользовался, обходился массивами всегда.