[Iska]

1. Приведите точный путь к приложению, и его командную строку.
2. Как понимать «ее автоматического завершения»?

[Black_Raven_]

1. C:\Program Files\Zona\Zona.exe
2. она сама закрывается по неизвестным причинам

[Iska]

1. C:\Program Files\Zona\Zona.exe »

На WSH:

Код:

Option Explicit

Dim strFile

Dim collSWbemObjectSet


strFile = "C:\Program Files\Zona\Zona.exe"

With WScript.CreateObject("Scripting.FileSystemObject")
	If .FileExists(strFile) Then
		Set collSWbemObjectSet = WScript.CreateObject("WbemScripting.SWbemLocator").ConnectServer(".", "root\cimv2").ExecNotificationQuery( _
			"SELECT * FROM __InstanceDeletionEvent WITHIN 1 " & _
			"WHERE TargetInstance ISA 'Win32_Process' " & _
			"AND TargetInstance.ExecutablePath = '" & Replace(strFile, "\", "\\") & "'" _
		)
		
		Do
			collSWbemObjectSet.NextEvent
			WScript.CreateObject("WScript.Shell").Run """" & strFile & """"
		Loop
		
		Set collSWbemObjectSet = Nothing
	Else
		WScript.Echo "Can't find file [" & strFile & "]."
		WScript.Quit 1
	End If
End With

WScript.Quit 0

2. она сама закрывается по неизвестным причинам »

Крайне рекомендуется вместо использования скрипта исследовать, найти и ликвидировать эти причины.

[Black_Raven_]

спасибо за код, только я в этом совсем не разбираюсь, а можете написать подробнее что и как сделать, что куда скопировать, что запустить, заранее благодарен

[Iska]

Скопируйте вышеприведённый код. Сохраните в файл с расширением «.vbs» и запустите его.

[omegastripes]

Приведенные ниже скрипты будут перезапускать определенную программу, как только она будет закрыта. В качестве примера используется C:\Windows\notepad.exe. Этот путь в тексте скрипта нужно заменить на свой, кавычки не трогать. Итак, неубиваемый блокнот :

Версия VBscript. Поместить этот код в текстовый файл и сохранить с расширением .vbs

Код:

Do: CreateObject("WScript.Shell").Run """C:\Windows\notepad.exe""", , True: Loop

Версия BAT или CMD (точнее это VBS, "завернутый" в BAT или CMD). Поместить этот код в текстовый файл и сохранить с расширением .bat или .cmd

Код:

' & start "" wscript /e:vbscript "%~dpf0"
Do: CreateObject("WScript.Shell").Run """C:\Windows\notepad.exe""", , True: Loop

Для остановки скрипта в диспетчере задач завершить процесс wscript.exe

Источники:
http://forum.script-coding.com/viewtopic.php?id=6519
http://ss64.com/nt/start.html

[Black_Raven_]

всем откликнувшимся огромное спасибо, все работает, все здорово, спасибо что написали как остановить его