[Iska]

активно окно браузера к примеру(или любое другое приложение) и чтобы после запуска скрипта на создание шаблона документа этот созданный документ открывался поверх активного окна приложения. А то он(документ) появляется у меня в свёрнутом виде в диспетчере задач и по нему надо кликать,вот этот клик и хотелось бы исключить... »

Как Вы тогда запускаете скрипт при активном окне браузера?

[Chestnut]

Как Вы тогда запускаете скрипт при активном окне браузера? »

Горячей клавишей с клавиатуры( привязал запуск скрипта в программе Comfort Keys).

[Iska]

Горячей клавишей с клавиатуры( привязал запуск скрипта в программе Comfort Keys). »

Покажите скриншотами, как Вы сие сделали.

[Chestnut]

Вот, пожалуйста

[Iska]

Chestnut, у меня окно Word'а с созданным документом и так становится активным.

Давайте попробуем так:

читать дальше »

Код:

Option Explicit

Const wdUserTemplatesPath = 2
Const wdDoNotSaveChanges  = 0

Dim objFSO
Dim objWshShell
Dim objWord

Dim strTemplateName
Dim strDocumentName
Dim strPath2Save

Dim strPath2Template
Dim strPath2File

Dim objTask


Set objFSO      = WScript.CreateObject("Scripting.FileSystemObject")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWord     = WScript.CreateObject("Word.Application")

strTemplateName = "My Template.dotx"
strDocumentName = "Документы.docx"
strPath2Save    = objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), "Docs")

With objWord
	strPath2Template = objFSO.BuildPath(.Options.DefaultFilePath(wdUserTemplatesPath), strTemplateName)
	
	If objFSO.FileExists(strPath2Template) Then
		If objFSO.FolderExists(strPath2Save) Then
			strPath2File = objFSO.BuildPath(strPath2Save, strDocumentName)
			
			With .Documents.Add(strPath2Template)
				If objFSO.FileExists(strPath2File) Then
					objFSO.DeleteFile strPath2File, True
				End If
				
				.SaveAs strPath2File
				.Close wdDoNotSaveChanges
			End With
			
			.Documents.Open strPath2File
			.Visible = True
			
			For Each objTask In .Tasks
				If objTask.Name = strDocumentName & " - " & .Name Then
					objTask.Activate
				End If
			Next
			
			'MsgBox strDocumentName & " - " & .Name
		Else
			WScript.Echo "Folder [" & strPath2Save & "] not found"
			.Quit
		End If
	Else
		WScript.Echo "Template [" & strPath2Template & "] not found"
		.Quit
	End If
End With

Set objWord     = Nothing
Set objWshShell = Nothing
Set objFSO      = Nothing

WScript.Quit 0

Если не сработает — раскомментируйте:

Код:

'MsgBox strDocumentName & " - " & .Name

запустите скрипт, дождитесь появления окна сообщения, нажмите в нём Ctrl-C и вставьте результат из буфера обмена сюда, обрамив его тэгом [code].

И ещё можно ли так, чтоб после копирования при закрытии документа не выводило окна с вопросом да\нет, а сохраняло и закрывало сразу? »

Какого копирования?

[Chestnut]

Давайте попробуем так: »

Не помог к сожалению предложенный вами вариант. Скрип срабатывает, но документ им создаваемый всё равно на заднем плане открывается - за активным окном браузера, то есть документ не в свёрнутом виде создаётся , я неправильно описал изначально - он не замещает собой уже активное окно как бы)). Документы без шаблона открываются как и положено "поверху".

Какого копирования? »

после редактирования(вставки инфы и закрытия).

[Iska]

Chestnut, в предыдущем коде по недосмотру я оставил после отладки не те значения «strTemplateName» и «strDocumentName», что использовались в примерах ранее. Я поправил код.

Не помог к сожалению предложенный вами вариант. »

Читайте, что было написано дальше:

Если не сработает — раскомментируйте: Код: 'MsgBox strDocumentName & " - " & .Name запустите скрипт, дождитесь появления окна сообщения, нажмите в нём Ctrl-C и вставьте результат из буфера обмена сюда, обрамив его тэгом [code]. »

Жду результата.

после редактирования(вставки инфы и закрытия). »

Ясно. Вставьте в модуль ThisDocument шаблона документа (именно в модуль шаблона, а не документа!) — в примерах это «My Template.dotx» — следующий код:

Код:

Option Explicit

Private Sub Document_Close()
    Me.Save
End Sub

[Chestnut]

Iska,



вот что пишет скрипт,как его обрамлять - не понял,да и думаю этот не тот случай

---------------------------
Windows Script Host
---------------------------
Template [c:\users\jk\appdata\roaming\microsoft\шаблоны\My Template.dotx] not found
---------------------------
ОК
---------------------------

Ясно. Вставьте в модуль ThisDocument шаблона документа (именно в модуль шаблона, а не документа!) — в примерах это «My Template.dotx» — следующий код: »

я не создавал никаких шаблонов,а просто скопировал данный вами код, поменял нужное название и расположение папки создаваемого файла и изменил на .vbs.

в общем я перестал понимать)), увы. Ладно, итак всё хорошо. Спасибо большое.

[Iska]

как его обрамлять - не понял »

Здесь: [code] — написано.

вот что пишет скрипт »

А что Вы тогда раньше указывали в качестве шаблона:

Код:

strTemplateName = "My Template.dotx"

? Раньше ж работало у Вас?

[Chestnut]

А что Вы тогда раньше указывали в качестве шаблона: Код: strTemplateName = "My Template.dotx" ? Раньше ж работало у Вас? »

Там я указал название документа(в обоих строчках одинаковое). И сейчас работает по-прежнему, то есть документ создаётся нормально, я наверное просто неправильно имя папки задал,когда копировал последний ваш код,потом поправил. Но документ открывается всё так же - "сзади" активного окна((

вот так у меня сейчас:

читать дальше »

Dim strTemplateName
Dim strDocumentName
Dim strPath2Save

Dim strPath2Template
Dim strPath2File

Dim objTask


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWord = WScript.CreateObject("Word.Application")

strTemplateName = "Извещение.dotx"
strDocumentName = "Извещение.docx"
strPath2Save = objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), "Documents")

With objWord
strPath2Template = objFSO.BuildPath(.Options.DefaultFilePath(wdUserTemplatesPath), strTemplateName)

If objFSO.FileExists(strPath2Template) Then
If objFSO.FolderExists(strPath2Save) Then
strPath2File = objFSO.BuildPath(strPath2Save, strDocumentName)

With .Documents.Add(strPath2Template)
If objFSO.FileExists(strPath2File) Then
objFSO.DeleteFile strPath2File, True
End If

.SaveAs strPath2File
.Close wdDoNotSaveChanges
End With

.Documents.Open strPath2File
.Visible = True

For Each objTask In .Tasks
If objTask.Name = strDocumentName & " - " & .Name Then
objTask.Activate
End If
Next

'MsgBox strDocumentName & " - " & .Name
Else
WScript.Echo "Folder [" & strPath2Save & "] not found"
.Quit
End If
Else
WScript.Echo "Template [" & strPath2Template & "] not found"
.Quit
End If
End With

Set objWord = Nothing
Set objWshShell = Nothing
Set objFSO = Nothing

WScript.Quit 0

Если не сработает — раскомментируйте: Код: 'MsgBox strDocumentName & " - " & .Name »

а это я не понял,что имелось ввиду и каким образом) ,скрипт то у меня срабатывает