|
|
|
|
| Компьютерный форум OSzone.net » Программирование, базы данных и автоматизация действий » Скриптовые языки администрирования Windows » CMD/BAT - автоматическое обновление справочников Биков ПО 01RKC#.exe |
|
|
CMD/BAT - автоматическое обновление справочников Биков ПО 01RKC#.exe
|
|
Пользователь Сообщения: 102 |
добрый день!
необходимо создать батник, который делает такое 1. по пути "C:\INFO\" имеется файл вида "readDDMM.001" (пример файла во вложении, кодировка DOS) где DD и MM день и месяц соответственно, в нем необходимо найти текст (имя файла) "*.arj" (* - постоянно меняется) 2. создать текстовый файл "get.txt" по пути "C:\БИКИ\get\" стекстом "get mfo *.arj" 3. из "C:\INFO\" файл "readDDMM.001" переместить в папку "C:\INFO\сегодняшняя дата в формате «год.месяц.число» (пример 2012.05.21)" (для того что бы повторно не прочитался файл) 4. сканировать папку "C:\BNK\IZM\" на появление архива "*.arj", его необходимо распаковать в туже папку 5. необходимо запустить досовское ПО по пути "C:\BNK\01RKC#.exe" 6.появится ошибка, необходимо кликнуть как то на «ignore» 7. закрыть ПО двойным нажатием "ESC" 8. на сетевом диске "Z:\" изменить имя папки "DAT" на нынешнюю дату в формате год.месяц.число (пример 2012.04.18) 9. скопировать папку "DAT" из "C:\BNK\" на сетевой диск "Z:\" 10. P.s. было бы не плохо сделать что бы он постоянно сканировал папку "C:\INFO\" на появление файла "readDDMM.001" и только когда появился файлик он начал те действия что описаны выше 11. отправить сообщение о завершении обновлений получился очень хороший батник: Код:
 @Echo Off
rem Пути
Set ReadPath=C:\INFO
Set GetPath=C:\biki\get
Set ARJPath=C:\BNK\IZM
rem Таймаут проверки файлов, в секундах
Set Timeout=10
Set /A Timeout+=1
If Not Exist "%ReadPath%" Echo Error - Directory not found&Exit /B 1
rem Подготавливаем структуру директорий
If Not Exist "%GetPath%" MD "%GetPath%"
:Loop
Set ARJName=&Set NFOName=
rem Поиск файла
For /F "delims=" %%F In ('Dir "%ReadPath%\read*.*" /B') Do (
Set NFOName=%%F
rem Поиск в найденном строки с архивом
For /F "delims=" %%S In ('Findstr /R /I /C:"\<*.arj\>" "%ReadPath%\%%F"') Do (
rem Разбор строки на составляющие, вычленение имени архива
For %%A In (%%S) Do (
Echo %%A|Find /I "arj">nul&&Set ARJName=%%A
)
)
)
If Defined ARJName (
Echo Found %NFOName%, processing...
rem Создаем get-файл
Echo get mfo %ARJName%>"%GetPath%\get.txt"
rem Перемещаем обработанный файл, чтобы исключить повторное прочтение
rem Если в системе установлен другой формат даты - исправить.
For /F "tokens=1,2,3 delims=." %%A In ("%Date%") Do (
If Not Exist "%ReadPath%\%%C.%%B.%%A" MD "%ReadPath%\%%C.%%B.%%A"
Move "%ReadPath%\%NFOName%" "%ReadPath%\%%C.%%B.%%A\%NFOName%"
)
:WaitForARJ
rem Распаковка архива, или ожидание, если он ещё не появился
If Exist "%ARJPath%\%ARJName%" (
c:\arj\ARJ32.EXE e C:\BNK\IZM\*.arj C:\BNK\IZM\
Echo Archive %ARJName% successfuly extracted
rem Запускаем программу
Start "" "C:\BNK\01RKC#.EXE"
Ping -n 10 127.0.0.1>nul
taskkill /IM ntvdm.exe
rem Делаем бэкап баз
For /F "tokens=1,2,3 delims=." %%A In ("%Date%") Do (
If Not Exist "D:\%%C.%%B.%%A" (
Ren "y:\DAT" "%%C.%%B.%%A" 2>nul||MD "D:\%%C.%%B.%%A"
Xcopy "C:\BNK\DAT" "y:\DAT" /E /I /Y /Q
msg console /server:*.*.*.* "обновление завершено"
)
)
) Else (
Echo Waiting for ARJ in %ARJPath%
Ping -n %Timeout% 127.0.0.1>nul
GoTo WaitForARJ
)
)
rem Уход на новую итерацию после таймаута
Cls&Echo Scanning %ReadPath%...
Ping -n %Timeout% 127.0.0.1>nul
GoTo Loop
Цитата:
|
||
|
Отправлено: 15:07, 21-05-2012 |
|
Старожил Сообщения: 415
|
Профиль | Отправить PM | Цитировать "Справочник БИК" у меня не установлен, поэтому проверить код не на чем, так что попробуйте у себя вот это:
Код:
@Echo Off :: Запускаем программу Start "" "C:\BNK\01RKC#.EXE" :: Ждём две секунды Ping -n 3 127.0.0.1>nul :: Делаем окно программы активным (по заголовку окна, поменяйте на реальный заголовок) Nircmdc win focus ititle "Заголовок" :: Посылаем нажатие 'I' Nircmdc sendkeypress I :: Ещё раз ждём две секунды Ping -n 3 127.0.0.1>nul :: Посылаем двойное нажатие 'ESC' Nircmdc sendkeypress esc esc |
|
Отправлено: 08:11, 23-05-2012 | #11 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать Anonymоus, а почему не ждёте самим NirCmd? Там аж целых две возможности, как «wait», так и более удобная в нашем случае «cmdwait».
|
|
Отправлено: 09:21, 23-05-2012 | #12 |
|
Пользователь Сообщения: 102
|
Профиль | Отправить PM | Цитировать судя по всему, должно с вот этим заголовком "ntvdm*" все работать, сейчас на скриншоте заголовок "ntvdm-ed8.444.35c" где ntvdm - постоянная, -ed8.444.35c - постоянно меняется, но почему то не работает
 |
|
Отправлено: 09:24, 23-05-2012 | #13 |
|
Старожил Сообщения: 415
|
Профиль | Отправить PM | Цитировать Iska, как-то из головы вылетела такая возможность. Вы правы, раз уж nircmd используется, глупо не сделать паузу через него.
Anufriev, немного поправил, проверьте вот этот скрипт Код:
@Echo Off :: Запускаем программу Start "" "C:\BNK\01RKC#.EXE" :: Ждём две секунды и делаем окно программы активным Nircmdc cmdwait 2000 win activate stitle "ntvdm" :: Посылаем нажатие 'I' Nircmdc sendkeypress I :: Ещё раз ждём две секунды и посылаем двойное нажатие 'ESC' Nircmdc cmdwait 2000 sendkeypress esc esc |
|
Отправлено: 09:44, 23-05-2012 | #14 |
|
Пользователь Сообщения: 102
|
Профиль | Отправить PM | Цитировать так, активным окно делается, а вот нажатие клавиш не передается
|
|
Отправлено: 09:58, 23-05-2012 | #15 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать «Too many fies open» — не проще ли настроить количество доступных для подсистемы файлов? Anufriev, дайте прямую ссылку на «01RKC#.EXE», откуда его можно загрузить.
|
|
Отправлено: 10:01, 23-05-2012 | #16 |
|
Пользователь Сообщения: 102
|
Профиль | Отправить PM | Цитировать |
|
Отправлено: 10:08, 23-05-2012 | #17 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать Anufriev, сделайте копии файла «config.nt», расположенного в папке «system32» Вашей папки «Windows», и файла «config.fp», расположенного в папке с приложением.
Затем поменяйте в обоих вышеупомянутых файлах строку: Код:
FILES=40 Код:
FILES=200 |
|
Отправлено: 12:58, 23-05-2012 | #18 |
|
Пользователь Сообщения: 102
|
Профиль | Отправить PM | Цитировать прекрасно, ошибка больше не выскакивает
осталась теперь последняя проблемка, это необходимость закрыть программу, а для этого необходимо двойное нажатие "esc" p.s. перезагрузка не потребовалась! можно сделать вод так Код:
taskkill /IM ntvdm.exe |
|
Последний раз редактировалось Anufriev, 23-05-2012 в 14:00. Причина: ответил сам себе! Отправлено: 13:42, 23-05-2012 | #19 |
|
Ветеран Сообщения: 27449
|
Профиль | Отправить PM | Цитировать Цитата Anufriev:
|
|
|
Отправлено: 14:00, 23-05-2012 | #20 |
|
Участник сейчас на форуме |
 |
Участник вне форума |
 |
Автор темы |
 |
Сообщение прикреплено |
| |||||
| Название темы | Автор | Информация о форуме | Ответов | Последнее сообщение | |
| VBS/WSH/JS - [решено] Добавление параметра в текстовый файл равный названию файла | XXXp | Скриптовые языки администрирования Windows | 14 | 31-03-2012 23:56 | |
| CMD/BAT - [решено] Вставить имя файла в текстовый файл (UTF-8 without BOM) | Jahnhoy | Скриптовые языки администрирования Windows | 11 | 19-09-2011 17:39 | |
| CMD/BAT - [решено] как из bat файла дописать символ в текстовый файл? | idzs | Скриптовые языки администрирования Windows | 6 | 22-02-2011 03:49 | |
| [решено] Можно ли создать текстовый файл внутри самой программы автоайти? | R.M.L | AutoIt | 7 | 03-10-2009 00:34 | |
| Интерфейс - изменение стандартного предложения создать текстовый файл | Irekson | Microsoft Windows 2000/XP | 3 | 25-02-2008 10:26 | |
|
|
Время: 00:21. | © OSzone.net 2001-
|
|
Powered by: vBulletin Copyright ©2000 - 2025, Jelsoft Enterprises Ltd. |
