[VanUliK]

В понедельник буду на работе, попробую, а что означает в формуле "--" логический оператор "Если"?

[okshef]

Нет. Это =-1*(-1) - служит для преобразования логических 0 и 1 в цифры (двойное отрицание)

[VanUliK]

=СУММПРОИЗВ(--((J9:U9)="ТО"))*(ЗНАЧЕН(ПСТР(D9;ПОИСК("/";D9)+1;ДЛСТР(D9)-ПОИСК("/";D9))))+(СУММПРОИЗВ(--((J9:U9)="ТР")))*(ЗНАЧЕН(ПСТР(E9;ПОИСК("/";E9)+1;ДЛСТР(E9)-ПОИСК("/";E9))))+(СУММПРОИЗВ(--((J9:U9)="К")))*(ЗНАЧЕН(ПСТР(F9;ПОИСК("/";F9)+1;ДЛСТР(F9)-ПОИСК("/";F9)))) »

Спасибо, всё работает, вот так формула выглядит после перевода в опенофис:

Код:

=SUMPRODUCT(--((J9:U9)="ТО"))*(VALUE(MID(D9;SEARCH("/";D9)+1;LEN(D9)-SEARCH("/";D9))))+(SUMPRODUCT(--((J9:U9)="ТР")))*(VALUE(MID(E9;SEARCH("/";E9)+1;LEN(E9)-SEARCH("/";E9))))+(SUMPRODUCT(--((J9:U9)="К")))*(VALUE(MID(F9;SEARCH("/";F9)+1;LEN(F9)-SEARCH("/";F9))))

[okshef]

VanUliK, немножко формулу оптимизировал

Код:

=СУММПРОИЗВ(((J9:U9)="ТО")*ПСТР(D9;ПОИСК("/";D9)+1;10)
+((J9:U9)="ТР")*ПСТР(E9;ПОИСК("/";E9)+1;10))+((J9:U9)="К")*ПСТР(F9;ПОИСК("/";F9)+1;10))

в ней функция СУММПРОИЗВ используется только один раз, максимальное количество возвращаемых символов принимается разным 10, не выполняется преобразование текста в число - преобразование происходит при перемножении. Убрал "--" - справляется без него.

Кстати, интересный способ записи формул в ячейку с использованием переноса строк, и в скобках проще разобраться:

Код:

=СУММПРОИЗВ(
((J9:U9)="ТО")*ПСТР(D9;ПОИСК("/";D9)+1;10)
+((J9:U9)="ТР")*ПСТР(E9;ПОИСК("/";E9)+1;10)
+((J9:U9)="К")*ПСТР(F9;ПОИСК("/";F9)+1;10)
)

Как вы понимаете, для дальнейшей оптимизации своего ума не хватило, обратился к планетянам
из решений:
1. Вводится как формула массива (Ctrl+Shift+Enter - CSE), фигурные скобки "рисовать" не нужно, они появляются после нажатия CSE:

Код:

=СУММ(ЕСЛИ(D$7:F$7=ТРАНСП(J9:U9);--(ЗАМЕНИТЬ(D9:F9;1;ПОИСК("/";D9:F9);))))

протягивается по диапазону
2. Не массивная формула:

Код:

=СУММПРОИЗВ(СЧЁТЕСЛИ($J9:$U9;$D$7:$F$7);--ЗАМЕНИТЬ($D9:$F9;1;ПОИСК("/";$D9:$F9);))

3. Массивная (CSE), но очень быстрая

Код:

=СУММ(ПСТР(D9:F9;ПОИСК("/";D9:F9)+1;9)*СЧЁТЕСЛИ(J9:U9;$D$7:$F$7))

P.S. Ценность последних трех формул в их универсальности. Если будут добавлены новые параметры в первые столбцы (например, между А и В), формулу не нужно менять - она учтет добавленный диапазон.

[DjArtas]

как в OpenOffice Calc подсчитать количество буквы X со всех ячеек A2:E4?

http://forum.oszone.net/attachment.p...2&d=1447325511

[okshef]

DjArtas, в Excel эта задача решается с помощью функции СЧЁТЕСЛИ(диапазон;условие).
Соответственно в OOc c помощью COUNTIF