[El Sanchez]

CyberMaster,

Вариант CMD/BAT:

Код:

@Echo Off
Setlocal ENABLEDELAYEDEXPANSION

Set "PathIniFile=C:\temp\test"
Set "IniFile=test.ini"
Set Count=1

Set /P "IP=Enter IP-address: "
Set /P "Port=Enter number of port: "

For /F "Tokens=1,2* Delims=:=" %%A In ('Findstr /IN . "%PathIniFile%\%IniFile%"') Do (
	Call :Func "%%A"
	
	If Not "%%C"=="" (
		If /I "%%B"=="Server_address" (
			Echo %%B=%IP%>>"%PathIniFile%\tmp"
		) Else (
			If /I "%%B"=="Server_port" (
				Echo %%B=%Port%>>"%PathIniFile%\tmp"
			) Else (
				Echo %%B=%%C>>"%PathIniFile%\tmp"
			)
		)
	) Else (
		Echo %%B>>"%PathIniFile%\tmp"
	)
)
Move /Y "%PathIniFile%\tmp" %IniFile% 2>nul
GoTo :EOF

:Func
	Set /A Diff=%~1-!Count!
	If %Diff% GTR 0 For /L %%A In (1,1,%Diff%) Do (Set /A Count+=1 & Echo.>>"%PathIniFile%"\tmp)
	Set /A Count+=1

[megaloman]

Еще вариант батника (недостаток - съедает все пустые строки, как побороть пока не знаю)
Мне показалась привлекательной идея цикла в цикле: сначала из файла берём строку, потом выделяем из неё кусок с помощью оператора For

Код:

Echo Off
rem --------------------------------------------------
rem Преобразуем файл, определённый в переменной InFile
rem Пример использования в командной строке
rem
rem Z_My.bat 123.456.789.012 3456
rem
rem --------------------------------------------------

If '%1%2==' GoTo :End

Set InFile="H:\Delete\kuku.txt"
Set Str1=Server_address
Set Str2=Server_port

rem --------------------------------------------------
Call :Replace %1 %2 %InFile%
GoTo :End 

:Replace

Set InFileBak="%~3.bak"
Move %InFile% %InFileBak% 

FOR /F "usebackq  delims=" %%i IN (%InFileBak%) DO (
   FOR /F "usebackq  delims==" %%j IN ('%%i') DO (
   If Not %%j==%Str1% (
      If Not %%j==%Str2% (
         Echo %%i>>%3
      ) Else (
         Echo %%j=%2>>%3
      )
   ) Else (
      Echo %%j=%1>>%3
   )
   )
) 

:End

[amel27]

Вариант CMD/BAT »

коль пошла такая пьянка, до кучи еще вариант:

Код:

@Echo Off

CALL :REPLINE "file.ini" "Server_address=" "Server_address=192.1.1.1"
CALL :REPLINE "file.ini" "Server_port=" "Server_port=8080"

:REPLINE
 If Not Exist "%~1" Exit /B 1
 If Exist "%~dpn1.tmp" DEL /F/Q "%~dpn1.tmp"

 Set $N=0& For /F "Delims=:" %%i In ('FindStr /BINRC:" *%~2" "%~1"') Do Set $N=%%i
 If %$N% NEQ 0 For /F "Tokens=1* Delims=:" %%i In ('FindStr /ENRC:"$" "%~1"') Do If "%%i"=="%$N%" (
 Echo %~3>>"%~dpn1.tmp" ) ELSE Echo.%%j>>"%~dpn1.tmp"

 If Exist "%~dpn1.tmp" If Exist "%~1" DEL /F/Q "%~1"
 If Exist "%~dpn1.tmp" REN "%~dpn1.tmp" "%~nx1"
Exit /B 0

[El Sanchez]

amel27, здОрово! Отличное решение с использованием регулярных выражений. Взял на заметку.

[volk1234]

amel27
Интересно, что если задать
"Server_address=1"
то в ини файле будет вот так
Server_address=

А если уже 2 символа написать в сначении, то работает...

[SendMessage]

Интересно, что если задать "Server_address=1" то в ини файле будет вот так Server_address= А если уже 2 символа написать в сначении, то работает... »

А если значение 0 или от 2 до 9, то параметр Server_address вообще исчезает. Ну и с Server_port, конечно, то же самое.
Глюки обработки в cmd. Решается взятием в дополнительные скобки:

Код:

If "%%i"=="%$N%" ((Echo %~3)>>"%~dpn1.tmp")

[sLiDeR-X]

CyberMaster, можно через chgstr сделать довольно легко

[volk1234]

SendMessage
Дополнительные скобки не помогли...

[SendMessage]

Дополнительные скобки не помогли... »

Странно. у меня работает. Как и простой пробел перед направлением в файл.

Код:

If "%%i"=="%$N%" (Echo %~3 >>"%~dpn1.tmp")

А батник идентичен батнику amel27?

[Foreigner]

А если значение 0 или от 2 до 9 »

Просто %3 определяется как дескриптор перенаправления выходного потока. Пример:

Код:

@echo off

for /l %%i in (0,1,9) do call:echo %%i
goto:eof

:echo
echo %1>>test-1.txt
echo.%1>>test-2.txt

Именно по этому в файле test-1.txt только одна запись об ошибке. Запись когда передавался параметр со значением 2, т.е. STDERR.