[решено] FileSetAttrib: Проблема с рекурсией

kaster · Конфигурация компьютера

ну опять же можно просто заходить скриптом во все папки и проверять наличие нужного файла и выставления нужного атрибута при нахождении

Creat0R · Конфигурация компьютера

Цитата kaster:

Нужно пройтись по всем папкам и подпапкам, найти нужный файл и если он удовлетворяет шаблону (farmenu.ini) ставить ему атрибут »

Тогда уже проще вызвать attrib из ком. строки:

Код:

If Not _FileSetAttribEx("c:\farmenu.ini", "+HS", 1) Then
    MsgBox(4096, "Error", "Problem setting attributes.")
EndIf

;Флаг = 1 -> Обработка файлов с указанными именами в текущей папке и во всех ее подпапках.
;Флаг = 2 -> Обработка и файлов, и папок.
;Флаги можно совмещать (BitOR(1, 2)).
Func _FileSetAttribEx($sFilePattern, $sAttributes, $iFlag=0)
    Local $sFlags = ""

    $sAttributes = StringRegExpReplace( _
        StringStripWS($sAttributes, 8), _
        "[-+]?([^-+])(?<=([-+])[^-+]|([-+])[^-+]{2}|([-+])[^-+]{3}|([-+])[^-+]{4}|([-+])[^-+]{5}|([-+])[^-+]{6}|([-+])[^-+]{7})", _
        " \2\3\4\5\6\7\8\1")

    If BitAND($iFlag, 1) = 1 Then $sFlags &= " /S "
    If BitAND($iFlag, 2) = 2 Then $sFlags &= " /D "

    Local $iPID = Run(@ComSpec & ' /C Attrib ' & $sAttributes & $sFlags & '"' & $sFilePattern & '"', '', @SW_HIDE, 2)
    Local $iError = @error, $sStdRead = ""

    While ProcessExists($iPID)
        Sleep(10)

        $sStdRead &= StdoutRead($iPID)
        If @error Then ExitLoop
    WEnd

    Return (Number($iError = 0) + Number(StringRegExp($sStdRead, ": \w:\\") = 0) = 2)
EndFunc

Creat0R · Конфигурация компьютера

Цитата kaster:

можно просто заходить скриптом во все папки и проверять наличие нужного файла »

Это долго.

kaster · Конфигурация компьютера

Цитата Creat0R:

Это долго. »

да, вот такой скрипт

Код:

#include <File.au3>
$j = 0
$start = TimerInit()
_Setter('c:')
$time = TimerDiff($start) / 1000
MsgBox(0, 'Time', $time & ' seconds elapsed' & @CRLF & $j & ' files scanned')
Func _Setter($sPath)
	Local $aAll = _FileListToArray($sPath)
	If Not IsArray($aAll) Then Return
	For $i = 1 To $aAll[0]
		If _PathIsFolder($sPath & '\' & $aAll[$i]) Then
			$sNew_Path = $sPath & '\' & $aAll[$i]
			;$iTotal_Folders += 1
			_Setter($sNew_Path)
		Else
			$j += 1
			If $aAll[$i] = 'farmenu.ini' Then FileSetAttrib($sPath & '\' & $aAll[$i], '+SH')
		EndIf
	Next
	Return
EndFunc

Func _PathIsFolder($sPath)
	Return StringInStr(FileGetAttrib($sPath), "D")
EndFunc

выполнялся 15 секунд против 5 секунд с этим примером

Код:

$start = TimerInit()
RunWait(@ComSpec & ' /C attrib +h +s farmenu.url /s', 'c:\', @SW_HIDE)
$time = TimerDiff($start) / 1000
MsgBox(0, 'Time', $time & ' seconds elapsed')

PS: кол-во файлов на диске С у меня ~175 тыс.