CMD/BAT

megaloman · Отправлено: **12:54, 27-09-2011** | #11

Цитата:

... например сейчас сентябрь, батник бы заархивировал и удалил бы потом все файлы которые были созданы до июня

Смотрим справку WinRar

Код:

@Echo Off
rem Если дата в системе в формате дд.мм.гггг
rem Delta - сколько месяцев не трогать (здесь не более 12)

Set Delta=3

Set Otkuda=D:\Tmp
Set Kuda=D:\TmpRar

Set Rar="C:\Program files\Winrar\Winrar.exe"

Set /A YYYYMM=%Date:~6,4%%Date:~3,2%-%Delta%
If %YYYYMM% LSS %Date:~6,4%01 Set /A YYYYMM=%YYYYMM%-88

Set DPack=%YYYYMM%01000000
%Rar% a -r -df -ep1 -tb%DPack% "%Kuda%\%DPack%" "%Otkuda%\"

Fen1kc16 · Отправлено: **23:20, 18-12-2011** | #12

А как сделать так чтобы структура папок оставалась, а удалялись(архивировались) только файлы в папках и подпапках. удаление ключа -tb это же не выход.

Dragokas · Отправлено: **23:59, 18-12-2011** | #13

К вопросу о ключах WinRAR: архивирую офис. документы обновлением для быстроты

Код:

rar.exe u -m0 -r -ri15 -n*.doc -n*.xls -n*.txt c:\docs.rar *.*

но потом заметил, что файлы, удаляемые на рабочем столе, остаются в архиве. Как исправить?
(в принципе можно и 7z)

megaloman · Отправлено: **20:17, 19-12-2011** | #14

Fen1kc16, если модернизировать мой предыдущий код, то, чтобы структура папок оставалась (при условии, что у папок нет каких-то особых доступов и параметров безопасности)

Код:

@Echo Off
rem Если дата в системе в формате дд.мм.гггг
rem Delta - сколько месяцев не трогать (здесь не более 12)

Set Delta=3

Set Otkuda=D:\Tmp
Set Kuda=D:\TmpRar
Set Rar="C:\Program files\Winrar\Winrar.exe"

SETLOCAL ENABLEEXTENSIONS 
SETLOCAL ENABLEDELAYEDEXPANSION

del "~%0.bat" >Nul 1>nul 2>Nul

FOR /R "%Otkuda%" %%d IN (.) DO  (
   Set dDir=%%d
   Echo md "!dDir:~0,-1!" >>"~%0.bat" 
)

Set /A YYYYMM=%Date:~6,4%%Date:~3,2%-%Delta%
If %YYYYMM% LSS %Date:~6,4%01 Set /A YYYYMM=%YYYYMM%-88

Set DPack=%YYYYMM%01000000
%Rar% a -r -df -ep1 -tb%DPack% "%Kuda%\%DPack%" "%Otkuda%\"

Call "~%0.bat"
del "~%0.bat" >Nul 1>nul 2>Nul

То есть я создаю подпапки заново, если в процессе архивации они были удалены. Либо вариант, создать во всех папках какой-нибудь файл. Так как его время создания сегодня, архивироваться он не будет, и папка раром не удалится, так как не пустая. После архивации служебные файлы можно поудалять. Здесь папки не пересоздаются - удаления нет.

Код:

@Echo Off
rem Если дата в системе в формате дд.мм.гггг
rem Delta - сколько месяцев не трогать (здесь не более 12)

Set Delta=3

Set Otkuda=D:\Tmp
Set Kuda=D:\TmpRar
Set Rar="C:\Program files\Winrar\Winrar.exe"

SETLOCAL ENABLEEXTENSIONS 
SETLOCAL ENABLEDELAYEDEXPANSION

FOR /R "%Otkuda%" %%d IN (.) DO  (
   Set dDir=%%d
   Echo 1 >"!dDir:~0,-1!~%0.bat" 
)

Set /A YYYYMM=%Date:~6,4%%Date:~3,2%-%Delta%
If %YYYYMM% LSS %Date:~6,4%01 Set /A YYYYMM=%YYYYMM%-88

Set DPack=%YYYYMM%01000000
%Rar% a -r -df -ep1 -tb%DPack% "%Kuda%\%DPack%" "%Otkuda%\"

del "%Otkuda%\~%0.bat" /S

Fen1kc16 · Отправлено: **08:05, 20-12-2011** | #15

Я немного по другому решил эту проблему просто добавил в твой предыдущий скрипт одну строку.

Код:

Set Gde=F:\Desktop\obmen
Set Kuda=F:\Desktop\obmenarh

Set TDate=%date:~6,4%%date:~3,2%%date:~0,2%

If Exist %Kuda%\%TDate%.rar GoTo End

MD %Kuda%

"%programfiles%\WinRar\Winrar.exe" a -r -ed  -tb%TDate%0001 %Kuda%\%TDate%.rar %Gde%\*.*

forfiles /P %Gde% /s /d -1 /c "cmd /c del @file /q

:End

ТАк можно или есть какие то подводные камни?

В 2003 server дата выводится как dd/mm/yy, из-за этого винрар не может создать архив, как с этим бороться?

megaloman · Отправлено: **13:10, 20-12-2011** | #16

Fen1kc16,
1. У меня в XP forfiles нет, поэтому для совместимости я им не пользуюсь.

2. Если у вас дата dd/mm/yy то можно сделать (строку взял вашу и изменил)

Set TDate=20%date:~6,2%%date:~3,2%%date:~0,2%

То есть я добавил 20 чтобы вместо Вашего 11 получилось 2011. По идее, рар должен такое взять (я не проверял, это почти очевидно). Вам за 88 лет работы менять ничего не придётся.

То же, но будет работать и для формата дд.мм.гггг

Set TDate=20%date:~-2%%date:~3,2%%date:~0,2%

То есть вырезаю два последних символа в дате

3. В 2003 форматы отображения, в частности, даты, настраивается: Региональные параметры - Настройка - Дата - Там можно выставить формат даты как Вам нравится. Я предпочитаю дд.мм.гггг

Iska · Отправлено: **14:26, 20-12-2011** | #17

Цитата megaloman:

1. У меня в XP forfiles нет, поэтому для совместимости я им не пользуюсь. »

В Resource Kit'е есть.

6umer · Отправлено: **17:42, 23-05-2013** | #18

Добрый вечер. прочитал эту тему. но сообразить не могу все же...
необходим батник стартующий из автозапуска, и архивирующий папу расположенную в корне диска C:\
в каталог лежащий в том же диске.
архиватор бесплатный 7zip.
помогите пожалуйста кодом.

Iska · Отправлено: **17:50, 23-05-2013** | #19

Код:

@ "%ProgramFiles%\7-Zip\7z.exe" a "C:\Куда архивировать\Архив.7z" "C:\Некая папка\"

6umer · Отправлено: **17:58, 23-05-2013** | #20

спасибо.
не думал что настолько простой батник ..
здесь же помоему не хватает ключевых команд ...