Разное

censored · Отправлено: **21:16, 13-05-2008** | #11

Спасибо вам огромное, помогли очень сильно!

Если кому-то нужен батник который получился, напишите вышлю

Цитата:

@echo off
SET /P PCNAME=Enter computer number :
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d computer_%PCNAME% /f
REG ADD HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d computer_%PCNAME% /f
SET COMPUTERNAME=computer_%PCNAME%

netsh interface ip set address name = "Подключение по локальной сети" source = static addr = 172.20.1.%PCNAME% mask = 255.255.255.0 gateway = 172.20.1.254 gwmetric = 1
netsh interface ip set dns name="Подключение по локальной сети" static 192.168.100.1
netsh interface ip add dns name="Подключение по локальной сети" 192.168.100.4 index=2

Вот собственно то что у нас получилось, но почему-то когда вводим числа с 078 до 099 не отрабатывает изменение IP адреса ... Как-то непонятно,может вы что-то подскажете..

Например когда вводишь 085 выскакивает вот это:
172.20.1.085 является неприемлимым значением для addr

Admiral · Отправлено: **22:06, 13-05-2008** | #12

Трудно сказать. Сначала думал сказать что он занят. Но вижу что команда даже не хочет его принимать.

А если плату отключать, вбивать настройки, а потом снова включать? Стоит проверить в ручном режиме, перед тем как вбивать новые команды в текст скрипта.

Понадобится The DevCon command-line utility functions as an alternative to Device Manager команды следующие

Цитата Script to automate the flushing of the Windows DNS cache:

Код:

REM To list all adapters of any system run the following command:
REM devcon listclass net

REM Disable/enable LAN adapter
devcon disable "PCI\VEN_8086&DEV_101E&SUBSYS_05491014&REV_03"
devcon enable "PCI\VEN_8086&DEV_101E&SUBSYS_05491014&REV_03"

>>

censored · Отправлено: **11:21, 14-05-2008** | #13

Пробовали ещё вчера, увы это не помогает. Самое интересное что не вбивает именно IP адресса, а DNS ставит как положено... Мистика вообщем

Ждем подсказок ..

Petya V4sechkin · Конфигурация компьютера

Цитата censored:

Например когда вводишь 085 выскакивает вот это:
172.20.1.085 является неприемлимым значением для addr

Если нолик убрать перед 85, все ок.
Убираем:

Код:

If "%PCNAME:~0,2%"=="00" (
  Set IP_Addr=%PCNAME:~2%
) Else (
  If "%PCNAME:~0,1%"=="0" (
    Set IP_Addr=%PCNAME:~1%
  ) Else (
    Set IP_Addr=%PCNAME%
  )
)
netsh interface ip set address name = "Подключение по локальной сети" source = static addr = 172.20.1.%IP_Addr% mask = 255.255.255.0 gateway = 172.20.1.254 gwmetric = 1

censored · Отправлено: **13:00, 14-05-2008** | #15

Нашлась ещё 1 проблема с этим, после установки всё нормально, но после перезагрузки компьютер не пингуется

С чем это может быть связано ?

Petya V4sechkin · Конфигурация компьютера

Цитата censored:

компьютер не пингуется

По имени или IP-адресу?

censored · Отправлено: **13:15, 14-05-2008** | #17

Он пишет "Сеть недоступна".

Petya V4sechkin · Конфигурация компьютера

censored, может быть, не все в реестр прописали:

Код:

REG ADD HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d computer_%PCNAME% /f
REG ADD HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ActiveComputerName /v ComputerName /t REG_SZ /d computer_%PCNAME% /f

REG ADD HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v Hostname /t REG_SZ /d computer_%PCNAME% /f
REG ADD HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d computer_%PCNAME% /f

А метрика gwmetric = 1 надо?
Попробуйте gwmetric = 0 (чтобы автоматически).

censored · Отправлено: **11:57, 15-05-2008** | #19

Все получилось после того как добавили.

Цитата:

If "%PCNAME:~0,2%"=="00" (
Set IP_Addr=%PCNAME:~2%
) Else (
If "%PCNAME:~0,1%"=="0" (
Set IP_Addr=%PCNAME:~1%
) Else (
Set IP_Addr=%PCNAME%
)
)
netsh interface ip set address name = "Подключение по локальной сети" source = static addr = 172.20.1.%IP_Addr% mask = 255.255.255.0 gateway = 172.20.1.254 gwmetric = 1