CMD/BAT - Нужен bat-ник для поиска и удаления файлов и папок по части названия файла

oniava · Отправлено: **02:17, 07-10-2017** | #11

Подправил первую строку вашего кода:

Код:

@Echo Off
SetLocal EnableExtensions

rem cd /d "%~dp0"

Set "Exclude=*ru-RU* *en-GB* *en-US* *de-DE*"

Set "BoxIn=%~dp0"
rem Set "BoxIn=%userprofile%\Desktop\ElsaWin"

Set "Mask=*.??-??.cab"
Set "Log=%userprofile%\Desktop\%~nx0.log"

>"%Log%" (FOR %%f IN ("%BoxIn%\%Mask%") DO Call :DelLan "%%f"  "%%~nf")
GoTo :Eof

:DelLan
	FOR %%e IN (%Exclude%) DO If /I "%~x2"==".%%e" GoTo :Eof
	Echo Del %1
	Del %1
GoTo :Eof

Батник отработал теперь, но по маске файлы не различает.
Удалил все файлы почему то...

megaloman · Отправлено: **14:48, 07-10-2017** | #12

Цитата oniava:

Батник отработал теперь, но по маске файлы не различает.
Удалил все файлы почему то... »

Вы извратили исключения при удалении. В Exclude записаны не маски, а строгое соответствие в имени файлов и подстановочные знаки * там не умесны.

Цитата oniava:

Он ничего не удалил но лог выдал такой:
Del "C:\Users\Oleg\Desktop\ElsaWin\au.N.cs-CZ.cab"
Del "C:\Users\Oleg\Desktop\ElsaWin\au.N.da-DK.cab" »

То есть, что видим: в лог пишется копия команды на удаление файла. Файл найден. И, если при исполнении батника ошибочных сообщений не было, значит удаление прошло нормально.

Цитата oniava:

Второй код в батнике, вообще ничего не сделал и лог выдал пустой. »

То есть файлы уже удалены, и удалять больше нечего.
Для большего контроля команду del в моих вариантах кода измените
Del /F %1 2>&1

oniava · Отправлено: **16:02, 07-10-2017** | #13

Здравствуйте megaloman.
После замены на

Цитата megaloman:

Del /F %1 2>&1 »

Ваш код заработал, вот только по маске работает не корректно, не до конца чистит почему то...
(Вся проблема кода, была в команде на удаление)
Код скрипта который использовал:

Код:

@Echo Off
SetLocal EnableExtensions

Set "Exclude=ru-RU en-GB en-US de-DE"

Set "BoxIn=%~dp0"
rem Set "BoxIn=%userprofile%\Desktop\ElsaWin"

Set "Mask=*.??-??.cab"
Set "Log=%userprofile%\Desktop\%~nx0.log"

>"%Log%" (FOR %%f IN ("%BoxIn%\%Mask%") DO Call :DelLan "%%f"  "%%~nf")
GoTo :Eof

:DelLan
	FOR %%e IN (%Exclude%) DO If /I "%~x2"==".%%e" GoTo :Eof
	Echo Del %1
	Del /F %1 2>&1
GoTo :Eof

В логе 255 записей о удалении.
Но удаление не полное, куча лишних файлов.

Вот скрины оставшихся файлов.

Скрытый текст

http://s018.radikal.ru/i518/1710/05/205b43901427.png

В других папах, файлы могут быть другие, но языки оставить надо именно эти как в скрипте.

oniava · Отправлено: **16:22, 07-10-2017** | #14

Цитата megaloman:

что не удалилось? Надо четко представлять вид имён файлов, чтобы корректно написать код »

Я на скринах обвел файлы которые должны были то же удалиться.

Файлы в папке могут быть разного вида, примерно:
saz.N.sv-SE.2CA.cab
slp.V.sv-SE#graphics.cab
slp.V.nl-NL.cab
help..et-EE.cab
hs2.N.fi-FI.cab
saz.V.es-ES.7P5.cab
saz..da-DK.2EE.5P3.cab
saz.saz.da-DK.2EE.5P3.cab.da-DK.2EE.5P3.cab
saz.saz..da-DK.2EE.5P3.cab.da-DK.2EE.5P3.cab
saz.da-DK.cab
и т.д.

Перед языковыми символами, что спереди что сзади символов может быть ЧТО УГОДНО!

{лабуда всякая}et-EE{лабуда всякая}.cab

Я даже не знаю что именно, это как сервер мне пришлет...

megaloman · Отправлено: **17:38, 07-10-2017** | #15

По маске {лабуда всякая}.??-??.{лабуда всякая}.cab удаляются все файлы, кроме исключений

Код:

@Echo Off

Set "Mask=*.??-??.*cab"
Set "Exclude=.ru-RU. .en-GB. .en-US. .de-DE."

Set "BoxIn=%~dp0"
rem Set "BoxIn=%userprofile%\Desktop\ElsaWin"

Set "Log=%userprofile%\Desktop\%~nx0.log"

If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%"

Call :PushdLog "%Log%"
>~Exclude.tmp (For %%e IN (%Exclude%) DO Echo %%e)

>"%Log%" (FOR /F "usebackq delims=" %%f IN (`Xcopy "%BoxIn%\%Mask%" "%Tmp%" /Exclude:~Exclude.tmp /S /L`) DO (
	If Exist "%%f" Echo    Del "%%f" &Del /F "%%f" 2>&1 
))
Del ~Exclude.tmp
Popd
GoTo :Eof

:PushdLog
	Pushd "%~dp1"
GoTo :Eof

Удаляет всё по маске в указанной папке и подпапках. Если надо удалить только в папке, уберите ключ /S в Xcopy

oniava · Отправлено: **17:40, 07-10-2017** | #16

А примерно такие то же удалит?
control#51.xml
delConfigItem.js
elfi.cab
slp.V.#graphics.17.cab

megaloman · Отправлено: **17:43, 07-10-2017** | #17

oniava, Мы разговаривали о файлах типа {лабуда всякая}.??-??.{лабуда всякая}.cab
Файлы с иными масками команды удалять не поступало.
Что Вам точно надо?
Если надо угрохать все файлы, кроме исключений, укажите маску
Set "Mask=*.*"
Опишите при этом в батнике корректно путь к папке и, не дай бог, не ставьте батник внутрь этой папки - батник убьет сам себя.
И, если можно, окружите скрины в Ваших постах тегом Spoiler /Spoiler, тяжело читать тему.

oniava · Отправлено: **17:52, 07-10-2017** | #18

Цитата megaloman:

Мы разговаривали о файлах типа {лабуда всякая}.??-??.{лабуда всякая}.cab
Файлы с иными масками команды удалять не поступало. »

Примерно так и надо.

Сейчас опробую Ваш скрипт.
На копирование Папки для "опробования скрипта", много времени уходит...

oniava · Отправлено: **20:07, 07-10-2017** | #19

Цитата megaloman:

@Echo Off
Set "Mask=*.??-??.*cab"
Set "Exclude=.ru-RU. .en-GB. .en-US. .de-DE."
Set "BoxIn=%~dp0"
rem Set "BoxIn=%userprofile%\Desktop\ElsaWin"
Set "Log=%userprofile%\Desktop\%~nx0.log"
If "%BoxIn:~-1%"=="\" Set "BoxIn=%BoxIn:~0,-1%"
Call :PushdLog "%Log%"
>~Exclude.tmp (For %%e IN (%Exclude%) DO Echo %%e)
>"%Log%" (FOR /F "usebackq delims=" %%f IN (`Xcopy "%BoxIn%\%Mask%" "%Tmp%" /Exclude:~Exclude.tmp /S /L`) DO (
If Exist "%%f" Echo Del "%%f" &Del /F "%%f" 2>&1
))
Del ~Exclude.tmp
Popd
GoTo :Eof
:PushdLog
Pushd "%~dp1"
GoTo :Eof »

Ваш новый скрипт удаляет, но всё равно не все файлы.

Некоторые остаются.

Маска поиска не подходит похоже.

slp.N.es-ES#graphics.cab
www..hr-HR#llf.cab
и т.п.

Скоро докачается новый архив у меня, попробую такой вот код:

Код:

Set "BoxIn=%~dp0"
Set "Ext=*.??-*.cab"
Set "Exclude=*ru-RU* *en-GB* *en-US* *de-DE*"
Set "Log=%userprofile%\Desktop\%~nx0.log"

pushd "%BoxIn%" || (pause & exit /b)
del "%Log%" 2>NUL

set nS=0& set /a nF=0
FOR /f "delims=" %%f IN ('dir /b /a-d %Exclude%') DO set ""%%~nxf"=1"
FOR %%f IN ("%BoxIn%\%Ext%") DO if not Defined "%%~nxf" (
  del /f /a "%BoxIn%\%%~nxf" &&(>>"%Log%" echo Удалено: "%%~nxf"& set /a nS+=1) ||(>>"%Log%" Не удалено: "%%~nxf" & set /a nF+=1)
)
(echo Результат выполнения:
echo Удалено файлов: %nS%
echo Не удалено файлов: %nF%
popd) >> "%Log%"
type "%Log%"
pause

Потом отпишу.

Iska · Отправлено: **21:30, 07-10-2017** | #20

oniava, как Вам уже сказали выше — убирайте большие скриншоты или их большое количество под тэг «spoiler».

Цитата oniava:

На копирование Папки для "опробования скрипта", много времени уходит... »

Используйте Robocopy для создания структуры папок и нулевого размера файлов:

Цитата robocopy.exe /?:

/CREATE :: Создать только дерево папок и файлы нулевой длины.

— будет быстро.