[Архив

Sanja Alone · Конфигурация компьютера

Меня по мылу уже неоднократно спаршивали как предотвратить множественный запуск одного и того же скрипта. Ответ вроде бы где-то на форуме встречался, но приведу его здесь еще раз. Все очень просто - в начало скрипта нужно добавить такую конструкцию:

Код:

If WinExists(@ScriptName) Then Exit
AutoItWinSetTitle(@ScriptName)

EgOrus · Отправлено: **08:39, 26-10-2005** | #**182**

Sanja Alone
да, ты прав WinWaitActive("Окно","Текст" там абсолютно не нужен, видимо сказалось позднее время и нежелание писать что-то свое, когда есть готовое, отсюда и невнимательность, конечно же везде должно быть просто WinActivate.

По поводу скрипта для Sateira CDDVD Burner, можно нескромный вопрос?

а почему скрипт сделан через работу с окнами, а не ключами установки?
/SILENT
/DIR="path"
/GROUP="folder name"
/TASKS="desktop,quicklaunch" (или /NOICONS)

Sanja Alone · Конфигурация компьютера

EgOrus

Цитата:

а почему скрипт сделан через работу с окнами, а не ключами установки?

Я уже ранее писал о своем отношении к Inno Setup - он не всегда корректно отрабатывает эти самые ключи... А так все ОК.

EgOrus · Отправлено: **10:32, 26-10-2005** | #**184**

Sanja Alone

Цитата:

он не всегда корректно отрабатывает эти самые ключи...

Это из личного опыта? в каких условиях не отрабатывает?
Странно, очень давно пользуюсь этой программой, сам постоянно делаю свои инстоляторы, ниразу не было чтобы что-то некоректно установилось. Единственный случай когда такое возможно, это если в скрипте жестко заданы пременные, и то отрабатывается все нормально просто поменять нельзя.
АвтоИт же наоборот только расширяет возможности InnoSetup, добавляя возможность использования переменных окружения при указании путей установки (при установке из комстроки требуется указание полновесных путей).

Спасибо за скрипт Gknot, я с тоской думал о том моменте когда придется его автоматизировать, жутко не люблю выписывать заголовки с окон, особенно когда их много

bogomolv · Отправлено: **15:22, 26-10-2005** | #**185**

Sanja Alone

Цитата:

Как это блокирует? Вот у меня на автоустановочном диске лежит файлик drweb-432b-win-ru.exe. Ставится этим скриптом без всяких блокировок... Ес-но, для silent-установки нужно предварительно получить еще и файлик setup.iss (см. в том же архиве) установив один раз прогу командой drweb-432b-win-ru.exe -R.

Обнаружив, что DrWeb в 432 версии лишился старых ключей автоустановки (кажется, это делалось через ini-файл), в первую очередь опробовал именно комбинацию setup.exe -R + setup.exe -s -f1"путь\setup.iss". Файл setup.iss создавался нормально. Но обрабатываться он у меня никак не хотел (и не хочет!). В форуме на drweb.ru нашел подтверждение своим смутным подозрениям - кто-то из приближенных к разработчикам авторитетно утверждал, что такая возможность заблокирована, и автоматическая установка поддерживается только в Enterprise Suite.
Если это не так, то это здорово!
Но у меня установка не проходит ни с моими, ни с твоими файлами. Чтобы проверить твой скрипт, разыскал drweb-432b-win-ru.exe. Результат тот же. Только в моем случае в setup.log значится ResultCode=-3, в твоем - ResultCode=-5.
Кстати, а почему в твоем скрипте в строке запуска drweb-432b-win-ru.exe нет ключа -f1"путь\setup.iss"? Что, если не указывать на setup.iss явно, он должен "подхватится" автоматом?

Давай разбираться!

CTEPBA · Отправлено: **21:46, 26-10-2005** | #**186**

Я сделал такой скрипт для Dr.Web 4,33 который работает по действиям, но у меня были проблемы с появление блокнота в конце, вроде я их решил, но еще проверял.

Код:

Run("setup.exe")
WinWaitActive("Dr.Web - InstallShield Wizard")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Программа InstallShield® Wizard установит Dr.Web (4.33.0.09290) на компьютер")
Send("{ENTER}")
WinWaitActive("Внимание!!!")
Send("{Space}")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "ЛИЦЕНЗИОННЫЙ ДОГОВОР ОБ ИСПОЛЬЗОВАНИИ")
Send("{UP}")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Программа установки установит Dr.Web в следующую папку")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Выберите вид установки")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Программа установки добавит значки программ в папку, указанную ниже")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Программа установки располагает всеми данными для начала копирования программных файлов")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Если Вы не используете прокси сервер, нажмите")
Send("{Tab}") 
Send("{Tab}")
Send("{Tab}")
Send("{ENTER}")
WinWaitActive("Вопрос")
Send("{Tab}")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Сейчас будет проведена экспресс-проверка Вашей системы")
Send("{ENTER}")
WinWaitActive("Вопрос")
Send("{Tab}")
Send("{ENTER}")
WinWaitActive("Установка Dr.Web", "Да, перезагрузить компьютер сейчас")
Send("{DOWN}")
Send("{ENTER}")
ProcessWait("notepad")
ProcessClose("notepad")

Sanja Alone · Конфигурация компьютера

Я написал скрипт для Dr.Web 4.33 через клацанье по окнам, добавил в zip-ку к скрипту для 4.32b. Пока можно юзать и такой вариант.

EgOrus

Цитата:

Это из личного опыта? в каких условиях не отрабатывает?

Да, больше всего трабл вызывают /SAVEINF и /LOADINF - проще сразу написать скрипт, чем думать почему настройки не сохранились или не загрузились.

Цитата:

жутко не люблю выписывать заголовки с окон, особенно когда их много

А вот тут упомянутый мной выше ScriptWriter будет весьма кстати.

bogomolv

Цитата:

автоматическая установка поддерживается только в Enterprise Suite

Вот Пик... пик... пик... редиски. И чего они хотят этим способом добиться? Бабок? - ничего не выйдет, народ у нас закаленный

Цитата:

разыскал drweb-432b-win-ru.exe. Результат тот же. Только в моем случае в setup.log значится ResultCode=-3, в твоем - ResultCode=-5

А у меня как раз для версии 4.33 в логе значится ResultCode=-5, а 4.32b ставится как миленькая.

Цитата:

Что, если не указывать на setup.iss явно, он должен "подхватится" автоматом?

Угу, конечно, если он будет лежать в том же каталоге, где и установщик.

Цитата:

Давай разбираться!

Я обнаружил, что при запуске файла drweb-433-win-ru.exe в память загружается 2 процесса - один "правильный" (с указанными мной ключами -s -f2c:\drweb.log), а второй с теми же ключами, но перед ними стоит еще ключ -deleter. Вот если бы убить этот паразитный процесс не затронув полезного, то, возможно, проблема и решилась бы... Но вот как это сделать?

EgOrus · Отправлено: **08:53, 27-10-2005** | #**188**

Sanja Alone
/SAVEINF и /LOADINF очень ограничены по использованию переменных окружения, все строчки из него дублируются обычными ключами.
Слегка видоизменил скрипт на Gknot, отменил установку AviSynth если есть более новый в этой же папке, добавил копирование плагинов к нему (к слову сказать - плаги ависинта работают на порядок быстрее VirtualDub'овских). В версии 2.56 появилась русская справка. Людям с толстыми каналами будет проще скачать новую версию GknotRipPack'a чем качать отдельно новый ависинт, тогда из скрипта нужно будет вырезать лишнее и переместить скрипт на установку ависинта.

Код:

If WinExists(@ScriptName) Then
   MsgBox(0, "Warning!", "Закрой предыдущую копию скрипта")
   Exit
EndIf
AutoItWinSetTitle(@ScriptName)

Opt('TrayIconDebug',1)
Opt('SendKeyDownDelay', 50)

ToolTip("Installing in progress. Please wait.", 1, 1)

#cs
----------------------
объявление переменных
----------------------
$file - имя инсталляционного файла
$avsfile - новая версия AviSynth
$AviSynthFolder - в какой подкаталог GKnot-а установить AviSynth
$VobSubFolder - в какой подкаталог GKnot-а установить VobSub
$vdubmodplug - rarsfx-архив с плагинами к VirtualDubMod
команды SFX-сценария (положите каталог PLUGINS целиком внутрь архива, в противном сл. задайте Path=GordianKnot\VirtualDubMod\Plugins):
	Path=GordianKnot\VirtualDubMod
	SavePath
	Silent=1
	Overwrite=1
----------------------
#ce
Global $file='GordianKnot.RipPack.0.35.0.Setup.exe', $avsfile='AviSynth\AviSynth_256_040905.exe', $AviSynthFolder='\AviSynth', $VobSubFolder='\Vobsub', $vdubmodplug='vdubmod_plugins.exe'
Run ( $file )
WinWaitActive ( 'Gordian Knot', 'License Agreement' )
Send ( '{ENTER}' )
WinWaitActive ( 'Gordian Knot', 'Choose Components' )
Send ( '{ENTER}' )
WinWaitActive ( 'Gordian Knot', 'Choose Install Location' )
$InstPath = ControlGetText ( 'Gordian Knot', 'Choose Install Location', 'Edit1')
Send ( '{ENTER}' )
WinWaitActive ( 'Installer Language' )
Send ( '{ENTER}' )
AutoItSetOption("WinTitleMatchMode", 2)
WinWaitActive ( 'VobSub', 'Welcome to the VobSub Setup Wizard' )
Send ( '{ENTER}' )
WinWaitActive ( 'Installation Options' )
Send ( '{ENTER}' )
WinWaitActive ( 'Installation Folder' )
ControlSetText( 'Installation Folder', '', 'Edit1', $InstPath & $VobSubFolder )
Send ( '{ENTER}' )
WinWaitActive ( 'Completed' )
Send ( '{ENTER}' )

AutoItSetOption("WinTitleMatchMode", 1)
If FileExists ( @ScriptDir & '\' & $avsfile ) Then
   ; Отказ от установки AviSynth 2.5.5
   WinWaitActive ( 'AviSynth', 'License Agreement' )
   ControlClick( 'AviSynth', 'License Agreement', 'Button3')
   Send ( '{ENTER}' )
Else
   ; Установка AviSynth из пакета Gknot
   WinWaitActive ( 'AviSynth', 'License Agreement' )
   Send ( '{ENTER}' )
   WinWaitActive ( 'AviSynth', 'Choose Components' )
   Send ( '{ENTER}' )
   WinWaitActive ( 'AviSynth', 'Choose Install Location' )
   ControlSetText( 'AviSynth', 'Choose Install Location', 'Edit1', $InstPath & $AviSynthFolder )
   Send ( '{ENTER}' )
   WinWaitActive ( 'AviSynth', 'Completing the AviSynth Setup Wizard' )
   Send ( '{ENTER}' )
EndIf

WinWait ( 'Gordian Knot', 'Installation Complete' )
WinClose ( 'Gordian Knot', 'Installation Complete' )
WinWaitClose ( 'Gordian Knot', 'Installation Complete' )

If FileExists ( @ScriptDir & '\' & $avsfile ) Then
   ; Установка новой версии AviSynth
   Run ( $avsfile )
   WinWaitActive ( 'AviSynth', 'License Agreement' )
   Send ( '{ENTER}' )
   WinWaitActive ( 'AviSynth', 'Choose Components' )
   ; Отметка русской справки
   Send ('{TAB}{DOWN}{RIGHT}r{SPACE}')
   ControlClick( 'AviSynth', '', 'Button2')
   WinWaitActive ( 'AviSynth', 'Choose Install Location' )
   ControlSetText( 'AviSynth', 'Choose Install Location', 'Edit1', $InstPath & $AviSynthFolder )
   Send ( '{ENTER}' )
   WinWaitActive ( 'AviSynth', 'Completing the AviSynth Setup Wizard' )
   Send ( '{ENTER}' )
EndIf

;запуск программы для внесения в реестр базовых настроек
Run ( $InstPath & '\GordianKnot.exe' )
WinWait ( 'Choose Language' )
WinActivate ( 'Choose Language' )
Send ( '{ENTER}' )
AutoItSetOption("WinTitleMatchMode", 2)
WinWait ( '(gordianknot.sourceforge.net)' )
WinClose ( '(gordianknot.sourceforge.net)' )
WinWaitClose ( '(gordianknot.sourceforge.net)' )
Sleep ( 50 )
;путь к DVDDecrypter почему-то не вносится в реестр в отличие от других (глюк наблюдается в версии GKnot 0.35.0)
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot',"DvdDecrypterExe","REG_SZ",FileGetShortName($InstPath)&'\DVDDecrypter\dvddecrypter.exe')
;н-рые настройки
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot',"DvdDecrypterNotUsed","REG_DWORD","00000000")
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot',"ActivePage","REG_DWORD","00000000")
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot',"Language","REG_SZ",'Russian')
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot\Slot0',"Bitrate","REG_DWORD","00000421")
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot\Slot0',"DivXMode","REG_DWORD","00000005")
RegWrite('HKEY_CURRENT_USER\Software\GordianKnot\Slot0',"CalculateAVIOverhead","REG_DWORD","00000001")
Sleep ( 50 )

;Распаковка дополнительных плагинов к VirtualDubMod
If FileExists ( @ScriptDir & '\' & $vdubmodplug ) Then RunWait ( @ScriptDir & '\' & $vdubmodplug )
;Копирование дополнительных плагинов AviSynth
DirCopy ( @ScriptDir & '\AviSynth\plugins', $InstPath & '\AviSynthPlugins', 1 )

;перенос ярлыков
;DirCopy ( @ProgramsCommonDir & '\Gordian Knot', @ProgramsCommonDir & '\CD и DVD утилиты\Gordian Knot', 1 )
DirCopy ( @ProgramsCommonDir & '\AviSynth 2.5', @ProgramsCommonDir & '\Gordian Knot\AviSynth', 1 )
DirCopy ( @ProgramsDir & '\AviSynth 2.5', @ProgramsCommonDir & '\Gordian Knot\AviSynth', 1 )
DirCopy ( @ProgramsDir & '\VobSub', @ProgramsCommonDir & '\Gordian Knot\VobSub', 1 )
;DirRemove ( @ProgramsCommonDir & '\Gordian Knot', 1 )
DirRemove ( @ProgramsCommonDir & '\AviSynth 2.5', 1 )
DirRemove ( @ProgramsDir & '\AviSynth 2.5', 1 )
DirRemove ( @ProgramsDir & '\VobSub', 1 )

bogomolv · Отправлено: **20:21, 27-10-2005** | #**189**

Sanja Alone

Цитата:

Вот если бы убить этот паразитный процесс не затронув полезного, то, возможно, проблема и решилась бы... Но вот как это сделать?

С помощью ProcessWait(), ProcessList(), ProcessClose(). Но не помогает!

Sanja Alone · Конфигурация компьютера

EgOrus
1. Ошибка

Код:

...
If FileExists ( @ScriptDir & '\' & $avsfile ) Then
   ; Отказ от установки AviSynth 2.5.5
   WinWaitActive ( 'AviSynth', 'License Agreement' )
   ControlClick( 'AviSynth', 'License Agreement', 'Button3')
   Send ( '{ENTER}' )
ElseIf
...

Здесь должно быть просто Else. Советую юзать редактор SciTe ( Ctrl+F5 - проверка синтаксиса ) - помогает при отлове подобных опечаток.

2. А зачем Opt('SendKeyDownDelay', 50) если в моем скрипте и так все работало?

bogomolv

Цитата:

С помощью ProcessWait(), ProcessList(), ProcessClose(). Но не помогает!

Я уже успел попробовать. Тестовый код:

Код:

Global $file='drweb-433-win-ru.exe'
Run ( $file & ' -s -f2' & EnvGet("SYSTEMDRIVE") & '\drweb.log' )
Sleep ( 200 )
$list = ProcessList($file)
If $list[1][1] > $list[2][1] Then
ProcessClose ( $list[1][1] )
msgbox(64, 'Процесс с PID = '&$list[1][1]&' был закрыт', 'Процессы drweb в памяти:'&@LF&@LF&$list[1][0] &'  '& $list[1][1] &@LF& $list[2][0] &'  '& $list[2][1],8)
Else
ProcessClose ( $list[2][1] )
msgbox(64, 'Процесс с PID = '&$list[2][1]&' был закрыт', 'Процессы drweb в памяти:'&@LF&@LF&$list[1][0] &'  '& $list[1][1] &@LF& $list[2][0] &'  '& $list[2][1],8)
EndIf

Причем независимо от того, какой процесс убивается - с большим или меньшим PID (это определяется знаком "<" или ">" в If-е) в памяти все равно остается тот, у к-рого есть паскудный ключ -deleter. Вот такая кака