[MaGoth]

sawe, Установил вашу версию сборки Resource Hacker'а, установщик малось наглючило от плагина скина. После завершения процесса установки вывело пустое окно инсталляции без какой либо инфы, с еррором скина. Закрывал инсталлер через убиение процесса в диспетчере задач.
Собственно вопрос, чем вам не угодил стандартный скин Нсис?!

[sawe]

Собственно вопрос, чем вам не угодил стандартный скин Нсис? »

Это прошлый век, серые унылые окна.....

[MaGoth]

Народ, встрял с одной проблемой, и не могу ее разрешить.
Есть задача: при установке определить существует ли один из определенных файлов (этих файлов может быть много) в каталоге назначения, и если файл например А1. есть, то осуществить определенное дествие, если файла А1. нет, то проверить существует ли файл Б1, и т.д, как и в случае с файлом А1.
Т.е. в зависимости от наличия того или иного файла выполнить определенное действие.
Перепробовал кучу разных решений, ни одно толком не работает. Сейчас нашел одно, но при этом копируется сразу все, а не в зависимости от условия.

Вот пример этого кода:

Код:

[...]
;-------------------------------------------------------------------------------
Section one
[...]
IfFileExists "$G2ChPath\Speech_Wegelagerer_english.vdf" 0 Done
  Call A1
IfFileExists "$G2ChPath\Data\Speech_Wegelagerer_deutsch.vdf" 0 Done
  Call B1
Done:
SectionEnd
;-------------------------------------------------------------------------------
Section -two
  SectionIn RO
  SetOverwrite on
.NextP1:
 файлы для установки
[...]
SectionEnd
;-------------------------------------------------------------------------------
Section -three
  SectionIn RO
  SetOverwrite on
.NextA1:
 файлы для установки
[...]
SectionEnd
;-------------------------------------------------------------------------------
Function A1
  Goto .NextA1
FunctionEnd
;-------------------------------------------------------------------------------
Function P1
  Goto .NextP1
FunctionEnd
;-------------------------------------------------------------------------------
[...]

И так далее...

Кто что об этом думает ?!

[kotkovets]

MaGoth
Ты забыл о последовательности исполнения команд в NSIS, а это очень важно!
Если, к примеру перейдем по каким-то причинам к глобальной метке .NextP1, то исполнение кода начнется с этой метки,
дальше по скрипту, следовательно будет исполняться весь код начиная с метки .NextP1

Кто что об этом думает ?! »

А че тут думать, если есть общие файлы, группируем в одной секции

Код:

Section "share"
   ;общие файлы для установки
  ;[...]
SectionEnd

Далее в секции one, делаем определение файлов и в зависимости
нахождения файла: копируем группу файлов - все делается последовательно!

Код:

Section "one"
  IfFileExists "$G2ChPath\Speech_Wegelagerer_english.vdf" 0 NextA1
   ;файлы для установки
  ;[...]
  NextA1:
  IfFileExists "$G2ChPath\Data\Speech_Wegelagerer_deutsch.vdf" 0 NextB1
   ;файлы для установки
  ;[...]
  NextB1:
  ;---
SectionEnd

А вот аналог на логической конструкции, для меня так удобнее...

Код:

Section "one"
  ${If} ${FileExists} "$G2ChPath\Speech_Wegelagerer_english.vdf"
   ;файлы для установки
  ;[...]
  ${ElseIf} ${FileExists} "$G2ChPath\Data\Speech_Wegelagerer_deutsch.vdf"
   ;файлы для установки
  ;[...]
  ${EndIf}
SectionEnd

На примере логической конструкции выше работает принцип: если найден один из указанных файлов - копируем группу файлов, остальные группы будут игнорироваться в любом случае.
Если нужно копировать несколько групп файлов (при нахождении указанных файлов) можно делать так:

Код:

Section "one"
  ${If} ${FileExists} "$G2ChPath\Speech_Wegelagerer_english.vdf"
   ;файлы для установки
  ;[...]
  ${EndIf}
  ${If} ${FileExists} "$G2ChPath\Data\Speech_Wegelagerer_deutsch.vdf"
   ;файлы для установки
  ;[...]
  ${EndIf}
SectionEnd

[MaGoth]

kotkovets, Нет, это не прокатывает перепробовал разные варианты, вот пример:

Есть файл Ридми.тхт на диске, в зависимости от локализации в нем седьмая строка меняет значения:
1. Системные требования
1. Hardwarevoraussetzungen

Код:

Name "Cls Test"
OutFile "ClsTest.exe"
;-------------------------------------------------------------------------------
!include "TextFunc.nsh"
;-------------------------------------------------------------------------------
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "RUSSIAN" ;Russian
;-------------------------------------------------------------------------------
!insertmacro MUI_RESERVEFILE_LANGDLL
;-------------------------------------------------------------------------------
Var Lokalize
;-------------------------------------------------------------------------------
Section
${LineRead} "C:\ReadMe.txt" "7" $Lokalize
   MessageBox MB_ICONINFORMATION|MB_OK $Lokalize IDOK
  ${If} $Lokalize == "1. Системные требования"
   MessageBox MB_ICONINFORMATION|MB_OK $Lokalize IDOK
   Call LokA
  ${ElseIf} $Lokalize == "1. Hardwarevoraussetzungen"
   MessageBox MB_ICONINFORMATION|MB_OK $Lokalize IDOK
   Call LokB
  ${EndIf}
SectionEnd
;-------------------------------------------------------------------------------
Function LokA
  Goto .NextAk
FunctionEnd
;-------------------------------------------------------------------------------
Function LokB
  Goto .NextPb
FunctionEnd
;-------------------------------------------------------------------------------
Section -"one1"
.NextAk:
   MessageBox MB_ICONINFORMATION|MB_OK "Русификация" IDOK
SectionEnd
;-------------------------------------------------------------------------------
Section -"one2"
.NextPb:
   MessageBox MB_ICONINFORMATION|MB_OK "Немка" IDOK
SectionEnd

Причем, не зависимо от того как реализованы последние две секции, первый пример выше, а второй так:

Код:

Section -"one"
.NextAk:
   MessageBox MB_ICONINFORMATION|MB_OK "Русификация" IDOK
.NextPb:
   MessageBox MB_ICONINFORMATION|MB_OK "Немка" IDOK
SectionEnd

Выводятся сообщения обеих команд, тоже самое и с определением файлов, если файл есть, или его нет, выполняются оба условия. Это ппц какой-то.

[kotkovets]

kotkovets, Нет, это не прокатывает перепробовал разные варианты, вот пример: »

Я вообще не пишу скрипты по принципу "прокатывания" и тебе не советую.

Причем, не зависимо от того как реализованы последние две секции, первый пример выше, а второй так: »

А где последовательность действий, не вижу...Оно будет так работать!
секции всегда будут срабатывать, это очевидно! Во что за извращения с глобальными метками в функции с переходом в секции??????????
Пиши сразу код в вызываемой в функции, или под конструкцией.
И ты забыл очевидное, про непечатываемые символы(мессага их не показывает) - переходы на новую строку и т.д
По этому и логика твоя и не работала, а если бы логика работала и прыжок был
на метку .NextAk:, то секции one1 и one2 выполнялись в любом случае.
Пример на логике И-ИЛИ который прекрасно работает

Код:

Section ""
  ClearErrors
  ${LineRead} "C:\Files.txt" "1" $Lokalize
  ${Unless} ${Errors}
      ${If} `$Lokalize` == "1. Системные требования$\r$\n"
      ${OrIf} `$Lokalize` == "1. Системные требования$\n"
      ${OrIf} `$Lokalize` == "1. Системные требования"
         Call LokA
      ${EndIf}
      ${If} `$Lokalize` == "1. Hardwarevoraussetzungen$\r$\n"
      ${OrIf} `$Lokalize` == "1. Hardwarevoraussetzungen$\n"
      ${OrIf} `$Lokalize` == "1. Hardwarevoraussetzungen"
       Call LokB
      ${EndIf}
  ${Else}
      MessageBox MB_ICONINFORMATION|MB_OK "Файл не найден!" IDOK
  ${EndUnless}
SectionEnd

Function LokA
  MessageBox MB_ICONINFORMATION|MB_OK $Lokalize IDOK
FunctionEnd

Function LokB
  MessageBox MB_ICONINFORMATION|MB_OK $Lokalize IDOK
FunctionEnd

[vahe-91]

не могу найти плагины для расаковки 7z и arc архивов, можете подсказать или отправить по пм ?

[vahe-91]

kotkovets, спасибо

[kotkovets]

vahe-91,
для аrc во вложении

[sawe]

Поигрался с CallGetUserSID и обнаружил интересные положительные свойства этого макроса, ещё раз спасибо!