[Creat0R]

amel27

чего-то у меня в последнее время ихний сайт в дауне

У меня тоже... прокси не юзаю.

пытаясь преобразовать его в юникод

А нельзя на входе перекодировать в Ansi?

все жду пока они поправят этот баг

а они знают о нём?

катастрофически уменьшающий скорость в циклах

Неужели это уменьшает скорость? тогда придётся переписывать много UDF'ов...

Хм, видимо и вправду быстрее, этот тест свидетильствует этому:

Код:

;Example 1
$sResult = ""
$sString = "test"

$Timer = TimerInit()
For $iCount = 1 To 100
    $sResult = $sResult & $sString
Next
ConsoleWrite("- First Time: " & TimerDiff($Timer) & @LF)

Sleep(500)

;Example 2
$sResult = ""
$sString = "test"

$Timer = TimerInit()
For $iCount = 1 To 100
    $sResult &= $sString
Next
ConsoleWrite("- Second Time: " & TimerDiff($Timer) & @LF)

[Creat0R]

Кто нибудь может мне плиз обьяснить, почему в новой версии AutoIt (v3.2.4.9) попортили половино функции? в смысле теперь все старые скрипты нужно чтательно переписывать...

На данный момент сталкнулся с непознанным - BassMod функция которую привёл тут в пример Diamond (спасибо ещё раз за неё), почему то выводит ошибку:



Что там нужно поменять? Diamond, не подскажешь плиз?

[amel27]

Creat0R

А нельзя на входе перекодировать в Ansi?

можно объединить сразу две функции в одну или передавать не данные, а ссылку на структуру... завтра соберу для UTF-8.

а они знают о нём?

к сожалению, я там плохо ориентируюсь - юзаю только через поиск

Неужели это уменьшает скорость? тогда придётся переписывать много UDF'ов...

это старый баг - чем длинней строки, тем существенней различие, особенно чувствительно при работе с большими файлами... видимо происходит "лишнее" копирование участков памяти между переменными

[Palych64]

To Sanja Alone
Да, Саня, inetwiz.exe это то, что нужно. Спасибо.

Вот,что у меня получилось:

Код:

WinMinimizeAll ( )
Run( @ProgramFilesDir & '\Internet Explorer\Connection Wizard\inetwiz.exe' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Установка подключения к Интернету', '1' )
Send ( '{DOWN}{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Параметры Интернета для локальной сети', '1' )
Send ( '{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Настройте учётную запись почты Интернета', '1' )
Send ( '{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Учётная запись почты Интернета', '1' )
Send ( '{UP}{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Введите имя', '5' )
Send ( 'Василий Пупкин' & '{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Адресс электронной почты Интернета', '1' )
Send ( 'vasilij_pupkin@itkm.ru' & '{ENTER}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Серверы электронной почты', '1' )
Send ( 'pop3.itkm.ru' & '{TAB}' & 'smtp.itkm.ru' & '{Enter}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Вход в почту интернета' , '1' )
Send ( '{Enter}' )
WinWaitActive ( 'Мастер подключения к Интернету', 'Завершение настройки', '1' )
Send ( '{Enter}' )
Exit

Посмотри, всё ли нормально? Может надо что-нибудь добавить или изменить? Мне бы хотелось знать твоё мнение.

[Diamond]

Creat0R
Да уж... я и раньше не разбирался во всём этом, а теперь они ещё больше всё усложнили...
В общем в некоторых местах нужно вместо "int" прописывать "int:cdecl" - спрашивается зачем такие сложности, ведь до этого всё прекрасно работало без всяких cdecl и библиотека всё понимала...
Я её переписал немного, убрал лишнее и использую как UDF.

Пример вызова:

Код:

#include <bassmod.au3>
$dll = DllOpen("bassmod.dll")
BassMod($dll, "Awesome - Dawn Main Theme.xm", 1024+4)

UDF:

Код:

#include-once
; Поддерживает: *.mod *.xm *.it *.s3m *.mtm
Func BassMod($BassModDll,$sPath,$flag=0)
	$init = DllCall($BassModDll, "int", "BASSMOD_Init", "int", -1, _  ;device
							"int", 44100, _  ;freq Hz
							"int", 0)       ;flag
	$fName = DllStructCreate("char[255]")
	DllStructSetData($fName, 1, $sPath)
	$load = DllCall($BassModDll, "int", "BASSMOD_MusicLoad", "int", False, _  ;loading from memory
							"ptr", DllStructGetPtr($fName), _ ;file
							"int", 0, _   ;offset
							"int", 0, _   ;length
							"int", $flag) ;flag
	$music_handle = $load[0]
	DllCall($BassModDll, "int:cdecl", "BASSMOD_MusicPlay", "int", $music_handle)
EndFunc

[amel27]

Creat0R
выполняю обещание:

Код:

Func _Utf8ToAnsi($utf8string)
    Local $len = StringLen($utf8string)
    Local $buf = DllStructCreate("byte[" & $len*2 & "];byte[2]")
    Local $ret = DllCall("Kernel32.dll", "int", "MultiByteToWideChar", _
        "int", 65001, "int", 0, _
        "str", $utf8string, "int", -1, _
        "ptr", DllStructGetPtr($buf), "int", $len*2+2)
    Local $out = DllStructCreate("char[" & $len & "];char")
    $ret = DllCall("kernel32.dll", "int", "WideCharToMultiByte", _
        "int", 0, "int", 0, _
        "ptr", DllStructGetPtr($buf), "int", -1, _
        "ptr", DllStructGetPtr($out), "int", $len+1, _
        "int", 0, "int", 0)
    Return DllStructGetData($out,1)
EndFunc

P.S. Кстати, у меня нормально прочитал "просигнатуренный" UTF-8 файл в режиме чтения (Mode 0), а с бинарными режимами (Mode 4, 16) такая же канитель, что и с DllStructGetData()...

[Creat0R]

Diamond

Я её переписал немного, убрал лишнее и использую как UDF.

Большое спасибо, работает как часики.

amel27

выполняю обещание

Привосходно! Спасибо! - Теперь не нужно таскать с собой три функции - Всё в одном!!!

Баг репорт я запостил по поводу _StringRepeat() - и ещё для некоторых функции (_StringProper(), _StringEncrypt(), _HexToString(), _StringToHex())... так что будем надеятся что пофиксят (чтобы самим каждый раз не фиксить).

А по поводу бага с DllStructGetData() - я могу им тоже маякнуть, вот только не уверен как запостить, т.е если бы кто-нить написал это на русском (запрос на поправку бага), я бы им это на англ. выложил... хотя у меня английский тоже не на высоте

[Dirk Diggler]

Palych64, используйте реестр. Аутлук хранит свои настройки там.

[amel27]

Creat0R

А по поводу бага с DllStructGetData() - я могу им тоже маякнуть, вот только не уверен как запостить

там уже вроде возмущались по этому поводу, только я не нашел обещанный автором баг-репорт, к примеру: FileOpen & FileRead, strange outcome, применительно к DllStructGetData() можно использовать этот пример, для файлов будет аналогично:

Код:

$sFile = @WindowsDir & '\setupact.log'
$hFile = FileOpen($sFile,4)

ConsoleWrite ("Размер файла: "& FileGetSize($sFile) &@CRLF)
ConsoleWrite ("Размер данных в файле: "& StringLen (FileRead ($hFile,FileGetSize($sFile))) &@CRLF)
FileClose($hFile)

З.Ы. в последней бэте ничего не поменялось

[Sanja Alone]

Palych64

Посмотри, всё ли нормально?

Все работает (проверил на вирт. машине WinXP SP2 eng). А для красивости и удобства правки можно заголовок окна и вводимую инфу задавать через переменные:

Код:

$Title='Мастер подключения к Интернету'
$Name='Василий Пупкин'
$EMail='vasilij_pupkin@itkm.ru'
$POP3='pop3.itkm.ru'
$SMTP='smtp.itkm.ru'

;а это фрагмент измененного в соотв. с вышесказанным кода:
WinWaitActive ( $Title, 'Серверы электронной почты', '1' )
Send ( $POP3 & '{TAB}' & $SMTP & '{Enter}' )