.: NSIS

MKN · Отправлено: **13:33, 17-12-2014** | #**1401**

Цитата Serg866:

Можно ли как-то добавить свой текст на странице прогресса установки (под прогресс баром)? »

Можно так :

Код:

OutFile "PAGE_INSTFILES_TXT_Test.exe"
InstallDir "$TEMP"
!include MUI2.nsh
!insertmacro MUI_PAGE_DIRECTORY
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ShowTxt
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"
; рамка вокруг области текста (если надо)
!define WS_BORDER 0x00800000

Function ShowTxt
; наш текст
StrCpy $R7 "Текст  Текст  Текст  Текст  Текст  Текст  Текст  Текст"

FindWindow $R0 "#32770" "" $HWNDPARENT

; создаём окно области текста
System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$R7",\
i${DEFAULT_STYLES}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_WANTRETURN}|${ES_AUTOVSCROLL}|${WS_BORDER},\
i5,i100,i445,i60,i$R0,i222,i0,i0) i.R2'

; цвет текста  &  цвет фона области текста
SetCtlColors $R2 `0x0000FF` `0x99FFFF`

; чтобы шрифт был, как и на странице (ессно можно назначить свой)
SendMessage $R0 ${WM_GETFONT} 0 0 $R9
SendMessage $R2 ${WM_SETFONT} $R9 0
FunctionEnd

Section 
Sleep 1000
SectionEnd

Варианты флагов для CreateWindowEx и координаты области текста - по вкусу.

Serg866 · Отправлено: **14:42, 17-12-2014** | #**1402**

MKN, благодарю за подробный пример! Всё сработало!
Очень полезная возможность.
А можно ли туда ещё небольшую картинку приделать? Что-то вроде баннера.

MKN · Отправлено: **17:10, 17-12-2014** | #**1403**

Цитата Serg866:

А можно ли туда ещё небольшую картинку приделать? »

Добавь в Function ShowTxt :

Код:

!define HWND_TOP            0 
!define SWP_NOSIZE          0x0001 
!define SWP_NOMOVE          0x0002 
!define IDC_BITMAP          1500 

; например поместим картинку mypict.bmp ( размер выбран 58x80 - для "вписывания"  в уже имеющееся на странице, "хозяйство" )
System::Call 'kernel32::GetModuleHandle(i 0) i.R3' 
System::Call 'user32::CreateWindowEx(i 0, t "STATIC", t "", i ${SS_BITMAP}|${WS_CHILD}|${WS_VISIBLE}, i 220, i 220, i R1, i R2, i $HWNDPARENT, i ${IDC_BITMAP}, i R3, i 0) i.R2' 
System::Call 'user32::SetWindowPos(i R1, i ${HWND_TOP}, i 0, i 0, i 00, i 0, i ${SWP_NOSIZE}|${SWP_NOMOVE})' 
System::Call `user32::LoadImage(i 0, t "mypict.bmp", i ${IMAGE_BITMAP}, i 0, i 0, i ${LR_CREATEDIBSECTION}|${LR_LOADFROMFILE}) i.s` 
Pop $R8
SendMessage $R2 ${STM_SETIMAGE} ${IMAGE_BITMAP} $R8
;  этот код обычно в Function .onGUIEnd )
System::Call 'gdi32:DeleteObject(i $R8)'

Ессно надо позаботиться о местонахождении mypict.bmp (обычно в $PLUGINSDIR через Function .onInit )

Serg866 · Отправлено: **19:11, 17-12-2014** | #**1404**

MKN, спасибо, выручаешь. И ещё один вопрос по этой теме.
Команда:
StrCpy $R7 "Текст Текст Текст Текст Текст Текст Текст Текст"

Как в ней делать перенос строки?
$\n не срабатывает(

+если можно, то подскажи, пожалуйста, как добавить ещё 2 строки с текстом над текстом, который в рамке? То есть нужен ещё просто текст над рамкой.

Ну и ещё один момент - текст почему-то редактируемый получается в рамке. Думал это из-за значения EDIT в команде System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$R7",\

Попробовал STATIC - текст вообще пропал) Короче у меня руки походу растут не откуда надо)

Serg866 · Отправлено: **00:42, 18-12-2014** | #**1405**

Пока сам поковырял и погуглил по теме. Вроде получилось то что задумал.

Могу и код выложить... Но просто он такой ужасный, что при его виде у профи по НСИСУ станет плохо с сердцем. Я даже не знаю как он скомпилировался.

И уточню вопрос в тексте. Хочу, чтоб текст можно было скопировать в буфер, но при этом чтоб нельзя его было изменять в области окна.

Begin2Fly · Отправлено: **01:02, 18-12-2014** | #**1406**

Serg866, добавьте эту строку к похожим:

Код:

SendMessage $R2 ${EM_SETREADONLY} 1 0

Serg866 · Отправлено: **01:10, 18-12-2014** | #**1407**

Begin2Fly, нее, что-то не срабатывает команда

Begin2Fly · Отправлено: **01:12, 18-12-2014** | #**1408**

Serg866, я добавлял к коду MKN, возможно, вы что-то переделывали.

Код:

OutFile "PAGE_INSTFILES_TXT_Test.exe"
InstallDir "$TEMP"

!include MUI2.nsh
!insertmacro MUI_PAGE_DIRECTORY
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ShowTxt
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

; рамка вокруг области текста
!define WS_BORDER 0x00800000

Function ShowTxt
; наш текст
StrCpy $R9 "Текст  Текст  Текст  Текст $\r$\n$\r$\n Текст  Текст  Текст  Текст"

FindWindow $R0 "#32770" "" $HWNDPARENT

System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$R9",\
i${DEFAULT_STYLES}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_WANTRETURN}|${ES_AUTOVSCROLL}|${WS_BORDER},\
i5,i100,i445,i60,i$R0,i222,i0,i0) i.R2'


; цвет текста  & цвет фона
SetCtlColors $R2 `0x0000FF` `0x99FFFF`

SendMessage $R0 ${WM_GETFONT} 0 0 $R9
SendMessage $R2 ${WM_SETFONT} $R9 0
SendMessage $R2 ${EM_SETREADONLY} 1 0
FunctionEnd

Section
Sleep 1000
SectionEnd

Serg866 · Отправлено: **01:17, 18-12-2014** | #**1409**

Begin2Fly , да я наворотил что-то там... Отправил Вам в личку код.
Надо его облагородить.

MKN · Отправлено: **11:40, 18-12-2014** | #**1410**

Цитата Serg866:

текст почему-то редактируемый получается в рамке. »

Потому что ~~гладиолус~~

флаг EDIT. Как уже было сказано - играй флагами по вкусу.
Как ты уже правильно хотел сделать, поменяй EDIT на STATIC. И, раз не нужно редактирование, удали не нужные флаги. Т.е. ,будет :

Код:

System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "$R7",i ${WS_CHILD}|${WS_VISIBLE},\
i5,i80,i445,i60,i$R0,i222,i0,i0) i.R2'

WS_CHILD - Дочернее окно.
WS_VISIBLE - Создается окно, которое сразу становится видимым.
По умолчанию окна создаются невидимыми, и для их отображения требуется вызывать функцию ShowWindow .

можно ещё короче :

Код:

System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "$R7",i${DEFAULT_STYLES},\
i5,i80,i445,i60,i$R0,i222,i0,i0) i.R2'

Если нужна прокрутка, оставь ${WS_VSCROLL} (для случая, когда весь текст не вмещается в область созданного окна)
(Если не хочется видеть полосу прокрутки, а текста много - расширь область окна, смести прогресс бар повыше и сделай уже его полоску. Вариантов много.)

ps про всё это уже говорилось в теме