[mustafar]

спасибо!!!

[SyDr]

Имеется массив строк. Как обратиться к определённому символу определённой строки?
$Array[$i][$n] не подходит...

[Creat0R]

Как обратиться к определённому символу определённой строки? »

Что значит обратиться? StringMid($aArray[$i], 2, 1) ?

[mustafar]

Ещё два вопроса: Как сделать чтобы этот скрипт искал эти пиксели в определённом окне? и как сделать что бы он ждал их появления (пикселей) и не выключался, а то он у меня проверяет координаты прямоугольника, не находит нужного цвета и выключается.

[Creat0R]

Как сделать чтобы этот скрипт искал эти пиксели в определённом окне? и как сделать что бы он ждал их появления (пикселей) и не выключался »

Код:

HotKeySet("{ESC}", "_Quit")

$hWindow = WinGetHandle("[CLASS:SciTEWindow]")

While 1
    $nColor = PixelSearch(200, 150, 220, 170, 0xFFFFFF, 0, 1, $hWindow)
    If Not @error Then _MyFunc($nColor)

    Sleep(100)
WEnd

Func _MyFunc($nColor)
    MsgBox(64, '', 'Hello from MyFunc(' & $nColor[0] & ', ' & $nColor[1] & ') :)')

    _Quit()
EndFunc

Func _Quit()
    Exit
EndFunc

[BonD 007]

Хочу, чтобы в Новом 2009-м году при нажатии на какую-нибудь горячую клавишу создавалась новая папка в активном окне, а то надоело постоянно клацать правой кнопой мыши, целиться в создать, потом в папку... долго это. Да и названия "Новая папка", "Новая папка (2)" поднадоели; хочется, чтоб их можно было поменять (к примеру, чтоб было "0", "1", "2" и т. д.). Прога для назначения горячей клавиши на приложение у меня есть, да и в Windows есть такая функция, а вот скриптик хотелось бы поиметь. Может можно это на AutoIt сделать? Или при помощи командной строки. Может есть проги, которые позволяют это делать? Помогите пожалуйста.

[Creat0R]

можно и так: »

Вообще-то эта тема по AutoIt ...

BonD 007,

при нажатии на какую-нибудь горячую клавишу создавалась новая папка в активном окне »

Пример:

Код:

#NoTrayIcon

Opt("WinWaitDelay", 1)

Global $sFileNameFormat = "New_%i"

HotKeySet("^+n", "_CreateFolder_Proc")
HotKeySet("^+w", "_Quit")

While 1
    Sleep(1000)
WEnd

Func _CreateFolder_Proc()
    Local $sExplorer_Title = "[CLASS:CabinetWClass]"
    If Not WinActive($sExplorer_Title) Then Return

    Local $sPath = ControlGetText($sExplorer_Title, "", "Edit1")
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return

    Local $iFolder_Num = 1
    Local $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)

    While StringInStr(FileGetAttrib($sPath & "\" & $sNewFolderName), "D")
        $iFolder_Num += 1
        $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)
    WEnd

    DirCreate($sPath & "\" & $sNewFolderName)
EndFunc

Func _Quit()
    Exit
EndFunc

[Maza Faka]

Пример: »

Неплохо было бы добавить проверку на класс ExploreWClass, вдруг пользователь запускает Explorer вместо "Мой компьютер":

Код:

#NoTrayIcon

Opt("WinWaitDelay", 1)

Global $sFileNameFormat = "New_%i"

HotKeySet("^+n", "_CreateFolder_Proc") ;Ctrl + Shift + n
HotKeySet("^+w", "_Quit") ;Ctrl + Shift + w

While 1
    Sleep(1000)
WEnd

Func _CreateFolder_Proc()
    Local $sExplorer_Title = "[CLASS:CabinetWClass]"

    If Not WinActive($sExplorer_Title) Then $sExplorer_Title = "[CLASS:ExploreWClass]"
    If Not WinActive($sExplorer_Title) Then Return

    Local $sPath = ControlGetText($sExplorer_Title, "", "Edit1")
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return

    Local $iFolder_Num = 1
    Local $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)

    While StringInStr(FileGetAttrib($sPath & "\" & $sNewFolderName), "D")
        $iFolder_Num += 1
        $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)
    WEnd

    DirCreate($sPath & "\" & $sNewFolderName)
EndFunc   ;==>_CreateFolder_Proc

Func _Quit()
    Exit
EndFunc   ;==>_Quit

[BonD 007]

Просто поместить код из предыдущего сообщения в файл с расширением ".au3", запустить, нажать Ctrl + Shift + n и появится папка? Что-то не получается. И ещё. Когда я писал "в активном окне", я имел ввиду чтобы, к примеру, при нажатии тех же Ctrl + Shift + n создавалась папка в любом окне Explorer'а, которое в данный момент активно (или на рабочем столе) независимо от того, где лежит скрипт.

[Creat0R]

Когда я писал "в активном окне", я имел ввиду чтобы, к примеру, при нажатии тех же Ctrl + Shift + n создавалась папка в любом окне Explorer'а, которое в данный момент активно (или на рабочем столе) независимо от того, где лежит скрипт. »

Рабочий стол не предусматривался, тогда так:

Код:

#NoTrayIcon

Opt("WinWaitDelay", 1)

Global $sFileNameFormat = "New_%i"

HotKeySet("^+n", "_CreateFolder_Proc") ;Ctrl + Shift + n
HotKeySet("^+w", "_Quit") ;Ctrl + Shift + w

While 1
    Sleep(1000)
WEnd

Func _CreateFolder_Proc()
    Local $sExplorer_Title = "[CLASS:CabinetWClass]"
    Local $sPath

    If Not WinActive($sExplorer_Title) Then $sExplorer_Title = "[CLASS:ExploreWClass]"
    If Not WinActive($sExplorer_Title) Then $sExplorer_Title = "[CLASS:Progman]"
    If Not WinActive($sExplorer_Title) Then Return

    Switch $sExplorer_Title
        Case "[CLASS:CabinetWClass]", "[CLASS:ExploreWClass]"
            Local $sWin_Title = WinGetTitle($sExplorer_Title)
            Local $sWin_Text = WinGetText($sExplorer_Title)

            $sPath = StringRegExpReplace($sWin_Text, "(?s).*(\r\n|)(\w+:\\.*" & $sWin_Title & ")(\r\n|.*)", "\2")
        Case "[CLASS:Progman]"
            $sPath = @DesktopDir
    EndSwitch

    If Not StringInStr(FileGetAttrib($sPath), "D") Then $sPath = ControlGetText($sExplorer_Title, "", "Edit1")
    If Not StringInStr(FileGetAttrib($sPath), "D") Then Return

    Local $iFolder_Num = 1
    Local $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)

    While StringInStr(FileGetAttrib($sPath & "\" & $sNewFolderName), "D")
        $iFolder_Num += 1
        $sNewFolderName = StringFormat($sFileNameFormat, $iFolder_Num)
    WEnd

    DirCreate($sPath & "\" & $sNewFolderName)
EndFunc   ;==>_CreateFolder_Proc

Func _Quit()
    Exit
EndFunc   ;==>_Quit