[Creat0R]

amel27,
Спасибо огромное!

Получилось и то и другое:

Код:

$hWnd = WinGetHandle("")
$sFilter = "Text File (*.txt)|*.txt|AutoIt v3 Script (*.au3)|*.au3|All (*.*)|*.*"

$Ret = _FileSaveDialog("Save as", "C:\", $sFilter, 18, "New Script", 2, $hWnd)

If Not @error Then MsgBox(64, "Results", StringFormat("Saved as: %s\n\nSelected Filter Index: %d", $Ret, @extended))

Func _FileSaveDialog($sTitle, $sInitDir, $sFilter='All (*.*)', $iOpt=0, $sDefFile='', $iDefFilter=1, $hWnd=0)
    Local $iFileLen = 65536 ; Max chars in returned string

    ; API flags prepare
    Local $iFlag = BitOR(BitShift(BitAND($iOpt, 2), -10), BitShift(BitAND($iOpt, 16), 3))

    ; Filter string to array convertion
    Local $asFLines = StringSplit($sFilter, '|')
    Local $i, $suFilter = ''

    For $i = 1 To $asFLines[0] Step 2
        If $i < UBound($asFLines) Then _
            $suFilter &= 'byte[' & StringLen($asFLines[$i]) + 1 & '];char[' & StringLen($asFLines[$i+1]) + 1 & '];'
    Next

    ; Create API structures
    Local $uOFN = DllStructCreate('dword;int;int;ptr;ptr;dword;dword;ptr;dword' & _
            ';ptr;int;ptr;ptr;dword;short;short;ptr;ptr;ptr;ptr;ptr;dword;dword')
    Local $usTitle = DllStructCreate('char[' & StringLen($sTitle) + 1 & ']')
    Local $usInitDir = DllStructCreate('char[' & StringLen($sInitDir) + 1 & ']')
    Local $usFilter = DllStructCreate($suFilter & 'byte')
    Local $usFile = DllStructCreate('char[' & $iFileLen & ']')
    Local $usExtn = DllStructCreate('char[1]')

    For $i = 1 To $asFLines[0]
        DllStructSetData($usFilter, $i, $asFLines[$i])
    Next

    ; Set Data of API structures
    DllStructSetData($usTitle, 1, $sTitle)
    DllStructSetData($usInitDir, 1, $sInitDir)
    DllStructSetData($usFile, 1, $sDefFile)
    DllStructSetData($usExtn, 1, "")
    DllStructSetData($uOFN, 1, DllStructGetSize($uOFN))
    DllStructSetData($uOFN, 2, $hWnd)
    DllStructSetData($uOFN, 4, DllStructGetPtr($usFilter))
    DllStructSetData($uOFN, 7, $iDefFilter)
    DllStructSetData($uOFN, 8, DllStructGetPtr($usFile))
    DllStructSetData($uOFN, 9, $iFileLen)
    DllStructSetData($uOFN, 12, DllStructGetPtr($usInitDir))
    DllStructSetData($uOFN, 13, DllStructGetPtr($usTitle))
    DllStructSetData($uOFN, 14, $iFlag)
    DllStructSetData($uOFN, 17, DllStructGetPtr($usExtn))
    DllStructSetData($uOFN, 23, BitShift(BitAND($iOpt, 32), 5))

    ; Call API function
    Local $aRet = DllCall('comdlg32.dll', 'int', 'GetSaveFileName', 'ptr', DllStructGetPtr($uOFN))
    If Not IsArray($aRet) Or Not $aRet[0] Then Return SetError(1, 0, "")

    ;Return Results
    Local $sRet = StringStripWS(DllStructGetData($usFile, 1), 3)
    Return SetExtended(DllStructGetData($uOFN, 7), $sRet) ;@extended is the 1-based index of selected filer
EndFunc

Я убрал параметр $sDefaultExt, в функции он установлен как пустое значение, чтобы если не присвоено расширение, подставлялось именно то, которое указано в выбранном фильтре.
Вместо этого параметра добавлен параметр $iDefFilter, указывает умолчальный фильтр (по индексу).

[amel27]

предотвращение ручного ввода фильтра? »

нет, просто при желании можно посмотреть что вбил пользователь ...опять же надо куда-то это выводить

[Creat0R]

amel27,

опять же надо куда-то это выводить »

В массив уже тогда - если оно не сложно, покажи приминение.

У меня тут появилась другая хотелка, возможо она окажется не такой уж простой для реализации ...

Чтобы к имени файла (если оно введено), добавлялось расширение при переключении фильтра (и если расширения ещё нет ). Полагаю тут придётся CallBack подключать, чтобы проверять действия, т.к вызов функции останавливается на момент показа дилога сохранения. Или даже с CallBack это трудно реализовать? я такое в некоторых программах видел, например в любимой Opera .

[amel27]

если оно не сложно, покажи приминение »

только для демонстрации - пример изменений в UDF для получения строки фильтра:

Код:

;   Объявление в начале UDF
    Local $sUserFiler = ""
    Local $usUsrFilter = DllStructCreate('byte[254]') ; структура для сохранения фильтра
    Local $usUsrFilter1 = DllStructCreate('char[253]', DllStructGetPtr($usUsrFilter)+1) ; пропускаем CHR(0)
;   ...
    DllStructSetData($uOFN, 5, DllStructGetPtr($usUsrFilter))
    DllStructSetData($uOFN, 6, 254)
;   ...
    Local $sRet = DllCall('comdlg32.dll', 'int', 'GetSaveFileName', 'ptr', DllStructGetPtr($uOFN))
;   ...
    If DllStructGetData($uOFN, 7) =0 Then
        $sUserFiler = DllStructGetData($usUsrFilter1, 1) ; строка фильтра
    EndIf

Полагаю тут придётся CallBack подключать, чтобы проверять действия »

честно говоря не вижу доступных сообщений, которые могли бы быть полезными в решении этой хотелки

[Creat0R]

amel27,

пример изменений в UDF для получения строки фильтра

Странно, ввожу свой фильтр, но DllStructGetData($uOFN, 7) возвращает тот, который указан в списке

честно говоря не вижу доступных сообщений, которые могли бы быть полезными в решении этой хотелки

Жалко... но я вот думал больше в сторону постоянной проверки как бы из вне (по таймеру), вот так примерно:

Код:

$hWnd = WinGetHandle("")
$sFilter = "Text File (*.txt)|*.txt|AutoIt v3 Script (*.au3)|*.au3|All (*.*)|*.*"

$Ret = _FileSaveDialog("Save as", "C:\", $sFilter, 18, "New Script", 2, $hWnd)

If Not @error Then MsgBox(64, "Results", StringFormat("Saved as: %s\n\nSelected Filter Index: %d", $Ret, @extended))

Func _FileSaveDialog($sTitle, $sInitDir, $sFilter = 'All (*.*)', $iOpt = 0, $sDefFile = '', $iDefFilter = 1, $hWnd = 0)
    Local $iFileLen = 65536 ; Max chars in returned string

    ; API flags prepare
    Local $iFlag = BitOR(BitShift(BitAND($iOpt, 2), -10), BitShift(BitAND($iOpt, 16), 3))

    ; Filter string to array convertion
    Local $asFLines = StringSplit($sFilter, '|')
    Local $i, $suFilter = ''

    For $i = 1 To $asFLines[0] Step 2
        If $i < UBound($asFLines) Then _
                $suFilter &= 'byte[' & StringLen($asFLines[$i]) + 1 & '];char[' & StringLen($asFLines[$i + 1]) + 1 & '];'
    Next

    ; Create API structures
    Local $uOFN = DllStructCreate('dword;int;int;ptr;ptr;dword;dword;ptr;dword' & _
            ';ptr;int;ptr;ptr;dword;short;short;ptr;ptr;ptr;ptr;ptr;dword;dword')
    Local $usTitle = DllStructCreate('char[' & StringLen($sTitle) + 1 & ']')
    Local $usInitDir = DllStructCreate('char[' & StringLen($sInitDir) + 1 & ']')
    Local $usFilter = DllStructCreate($suFilter & 'byte')
    Local $usFile = DllStructCreate('char[' & $iFileLen & ']')
    Local $usExtn = DllStructCreate('char[1]')

    For $i = 1 To $asFLines[0]
        DllStructSetData($usFilter, $i, $asFLines[$i])
    Next

    ; Set Data of API structures
    DllStructSetData($usTitle, 1, $sTitle)
    DllStructSetData($usInitDir, 1, $sInitDir)
    DllStructSetData($usFile, 1, $sDefFile)
    DllStructSetData($usExtn, 1, "")
    DllStructSetData($uOFN, 1, DllStructGetSize($uOFN))
    DllStructSetData($uOFN, 2, $hWnd)
    DllStructSetData($uOFN, 4, DllStructGetPtr($usFilter))
    DllStructSetData($uOFN, 7, $iDefFilter)
    DllStructSetData($uOFN, 8, DllStructGetPtr($usFile))
    DllStructSetData($uOFN, 9, $iFileLen)
    DllStructSetData($uOFN, 12, DllStructGetPtr($usInitDir))
    DllStructSetData($uOFN, 13, DllStructGetPtr($usTitle))
    DllStructSetData($uOFN, 14, $iFlag)
    DllStructSetData($uOFN, 17, DllStructGetPtr($usExtn))
    DllStructSetData($uOFN, 23, BitShift(BitAND($iOpt, 32), 5))

    ;Set Timer to check FileName Input for file extention
    Local $hCallBack = DllCallbackRegister ("_Check_FSD_Input", "none", "hwnd;int;int;dword")
    Local $ahTimer = DllCall("user32.dll", "int", "SetTimer", "hwnd", 0, _
            "int", TimerInit(), "int", 200, "ptr", DllCallbackGetPtr ($hCallBack))

    ; Call API function
    Local $aRet = DllCall('comdlg32.dll', 'int', 'GetSaveFileName', 'ptr', DllStructGetPtr($uOFN))
    If Not IsArray($aRet) Or Not $aRet[0] Then Return SetError(1, 0, "")

    ;Fre CallBack and kill the timer
    DllCallBackFree ($hCallBack)
    DllCall("user32.dll", "int", "KillTimer", "hwnd", 0, "int", $ahTimer)

    ;Return Results
    Local $sRet = StringStripWS(DllStructGetData($usFile, 1), 3)
    Return SetExtended(DllStructGetData($uOFN, 7), $sRet) ;@extended is the 1-based index of selected filer
EndFunc   ;==>_FileSaveDialog

Func _Check_FSD_Input($hWndGUI, $MsgID, $WParam, $LParam)
    Local $sSaveAs_Title = "[CLASS:#32770;TITLE:Save as]"

    If ControlGetFocus($sSaveAs_Title, "FolderView") = "Edit1" Then Return

    Local $sEdit_Data = ControlGetText($sSaveAs_Title, "FolderView", "Edit1")
    Local $sFilter_Ext = ControlCommand($sSaveAs_Title, "FolderView", "ComboBox3", "GetCurrentSelection")
    $sFilter_Ext = StringRegExpReplace($sFilter_Ext, ".*\(\*(.*?)\)$", "\1")

    If $sFilter_Ext = ".*" Then $sFilter_Ext = ""

    Local $sEdit_Ext = StringRegExpReplace($sEdit_Data, "^.*\.", ".")

    If $sEdit_Ext <> $sFilter_Ext And ($sEdit_Ext <> $sEdit_Data Or $sFilter_Ext <> "") Then
        $sEdit_Data = StringRegExpReplace($sEdit_Data, "\.[^.]*$", "")
        ControlSetText("[CLASS:#32770;TITLE:Save as]", "FolderView", "Edit1", $sEdit_Data & $sFilter_Ext)
    EndIf
EndFunc   ;==>_Check_FSD_Input

[Dmurr]

Всем доброго времени суток! Не могли бы вы разъяснить, как выдрать из виндов букву cd-romа... т.к. буквы у на многих компах разные нужно точное выдирание буквы диска... ибо хочется сделать диск полностью самоустанавливающийся.... просмотрев справку и архив форума не нашел ни одной справки по решению данной проблемы... может кто поможет...

[Creat0R]

Dmurr,

как выдрать из виндов букву cd-romа

Использовать функцию DriveGetDrive...

Код:

$aDrives = DriveGetDrive("CDROM")
$sDrives = ""

For $i = 1 To UBound($aDrives)-1
    $sDrives &= StringUpper($aDrives[$i]) & "\" & @CRLF
Next

If $sDrives <> "" Then MsgBox(64, "Найденные CD-ROM'ы", StringFormat("Найдено <%d> CD-ROM('а):\n\n%s", $aDrives[0], $sDrives))

[Dmurr]

Спасибо, большое... ^_^

[Creat0R]

amel27,
На оф. форуме выложили подобные функии, там можно указать имя CallBack функции, которая будет вызываться при поступлении сообщении.
Сами UDF'ы немного запутаны для разбора, но мне удалось выявить, что при смене фильтра, поступает сообщение 49263 (его константа мне не известна конечно). Я правда не уверен что оно касается фильтра, возможно это просто сообщение связанное с перерисовкой диалога.

Кстати, в одной из следующих версии, планируют уже встроенные функции переделать, как я понял будут поддерживать дополнитеьный параметр hWnd. Видимо мои просьбы повлияли

---

У меня тут есть проблема немного поважнее, нужно проверять нажатие левой кнопки мышки, но при этом предотвратить клик мышки.
Т.е пока запущена определённая функция (в цикле), нажатие мышки (левую кнопку) нужно отключить, но чтобы можно было отследить, нажал ли юзер на эту кнопку (_IsPressed("01")).

Это вообще реально на AutoIt? я такое поведение видел в программах для захвата изображении, когда юзер выбирает определённую часть окна, и затем кликает там для захвата, в том месте где он кликнул, ничего не происходит, т.е клиентская часть окна по которой он кликнул, не берёт на себя фокус.
Я тоже делаю (точнее почти закончил) нечто похожее, утилитку для захвата изображении, как с этим вопросом решусь, выложу тут

[amel27]

Странно, ввожу свой фильтр, но DllStructGetData($uOFN, 7) возвращает тот, который указан в списке »

хм... действительно, хотя сам текст фильтра обновляет нормально

вот так примерно »

впечатляет... Имхо идентификации окна по одному заголовку маловато, надо проверять на его принадлежность текущему процессу, вдруг другие приложения/скрипты тоже запустят запрос на открытие/сохранение?.. Типа такого:

Код:

Func _WinIsMy($hwnd)
    Local $uPID = DllStructCreate("dword")
    Local $aRet = DllCall("user32.dll", 'int', 'GetWindowThreadProcessId', _
        'hwnd', $hwnd, _
        'ptr', DllStructGetPtr($uPID))
    $aRet = DllCall("kernel32.dll", 'int', 'GetCurrentProcessId')
    Return $aRet=DllStructGetData($uPID,1)
EndFunc

как я понял будут поддерживать дополнитеьный параметр hWnd »

давно пора, хотя "хотелки" растут быстрее чем их релизы