[архив].: NSIS

kotkovets · Конфигурация компьютера

Цитата sawe:

но при выборе другой папки или диска терялась \XXX , переписал заново вроде всё работает, но я не уверен полностью. »

Код:

Function .onInit
 ${If} ${AtLeastWinVista} ;начиная от WinVista и выше
    Var /global SysDrive ; иницилизируем здесь, в ниже версиях Windows SysDrive - не используется
    StrCpy $SysDrive $WINDIR 2
    StrCpy $INSTDIR "$SysDrive\Games\XXX"
 ${Else}
    StrCpy $INSTDIR "$PROGRAMFILES\XXX"
 ${EndIf}
FunctionEnd

InstallDir "$INSTDIR\XXX"

Цитата wolkow70:

Запускается генератор и все, что дальше делать не понятно.... »

и мне не понятно, что вы дальше хотите сделать

wolkow70 · Отправлено: **15:09, 07-05-2011** | #**1162**

Цитата kotkovets:

и мне не понятно, что вы дальше хотите сделать »

Создать INI файл со сценарием установки... И разобраться в процессе его создания.

kotkovets · Конфигурация компьютера

Цитата wolkow70:

Создать INI файл со сценарием установки... И разобраться в процессе его создания »

Вот накидал небольшой примерчик, с описанием на основе фейса MUI2, генератор файла ответов через ключ /G

Читать внимательно комменты в скрипте

Код:

!include "MUI2.nsh"

!include "TextFunc.nsh"
!include "WordFunc.nsh"
!include "LogicLib.nsh"

OutFile "setup.exe"

 !define MUI_PAGE_CUSTOMFUNCTION_SHOW SHOWWELCOME ;функция при открытии стр. приветствия
!insertmacro MUI_PAGE_WELCOME
 !define MUI_PAGE_CUSTOMFUNCTION_SHOW SHOWDIRECTORY ;функция при открытии стр. приветствия
!insertmacro MUI_PAGE_DIRECTORY
 !define MUI_PAGE_CUSTOMFUNCTION_SHOW SHOWCOMPONENTS ;функция при открытии стр. компонентов
!insertmacro MUI_PAGE_COMPONENTS
 !define MUI_PAGE_CUSTOMFUNCTION_PRE PREINSTFILES ;функция перед открытием стр. установки
!insertmacro MUI_PAGE_INSTFILES
 !define MUI_PAGE_CUSTOMFUNCTION_SHOW SHOWFINISH
!insertmacro MUI_PAGE_FINISH
!insertmacro MUI_LANGUAGE "Russian"

Var GMODE
Var CAPTION
Var INIFILE
Var SysDrive
Var SUCCES_SECTION

InstallDir "$PROGRAMFILES\SOFT"

Function .OnInit
  StrCpy $SysDrive $WINDIR 2
  StrCpy $GMODE 0 ;если обычный режим, то $GMODE = 0
  StrCpy $CAPTION "Обычный режим"
  ${WordReplace} "$EXEFILE" ".exe" ".ini" "+" "$INIFILE" ;подменяем расширение на ini c тем же именем, что и установщик
  StrCpy $INIFILE "$EXEDIR\$INIFILE" ;$INIFILE - путь, где будет создан файл конфигурации
  ${GetOptions} $CMDLINE "/G" $0
  ${IfNot} ${Silent} ; условие работы генератора, если не тихий режим
  ${AndIfNot} ${Errors} ; И не установлен флаг ошибки
  ;здесь команды выполняться будут в режиме генератора, до конца конструкции ${EndIf}
    StrCpy $GMODE 1 ;с ключом /G, $GMODE = 1, режим генератора
    StrCpy $CAPTION "Генератор ответов" ;меняем название заголовка
    ;------bla..bla
    ;------bla..bla
    IfFileExists "$INIFILE" 0 +2
    Delete "$INIFILE" ;удаляем предыдущий файл конфигурации
  ${EndIf}
FunctionEnd

Caption "$CAPTION"

;==========================================================================================
Function SHOWWELCOME
  ${If} $GMODE = 1 ;режим генератора
     ${NSD_SetText} $mui.WelcomePage.Title "Добро пожаловать! Это генератор ответов."
     ${NSD_SetText} $mui.WelcomePage.Text "Описание возможностей генератора:$\nbla..bla$\nbla..bla"
  ${EndIf}
FunctionEnd
;==========================================================================================
Function SHOWDIRECTORY
 ${If} $GMODE = 1 ;режим генератора
    ${NSD_SetText} $mui.DirectoryPage.Text \
   "Программа запишет в файл конфигурации путь установки программы.$\r\
    Этот путь подхватится в тихом режиме запуска установщика.$\r\
    Файл конфигурации создатся с таким же именем, как и установщик.$\r\
    Вы можете изменить путь выбора папки установки кнопкой  «Обзор...»"
 ${EndIf}
FunctionEnd
;==========================================================================================
Function SHOWCOMPONENTS
 ${If} $GMODE = 1 ;режим генератора
   ${NSD_SetText} $mui.ComponentsPage.Text \
   "Выберите компоненты которые вы хотите устанавливать в тихом режиме$\n\
   Нажмите кнопку «Создать» , что бы создать файл конфигурации установки"
   GetDlgItem $0 $HWNDPARENT 1
   ${NSD_SetText} $0 "Создать"
 ${EndIf}
FunctionEnd
;=========================================================================================
Function SHOWFINISH
 ${If} $GMODE = 1 ;режим генератора
    ${NSD_SetText} $mui.FinishPage.Title "Завершение работы Мастера создания файла ответов."
    ${NSD_SetText} $mui.FinishPage.Text "Файл ответов готов!"
 ${EndIf}
FunctionEnd
;=========================================================================================
Function PREINSTFILES ;это функция будет выполнена только в режиме генератора
 ${If} $GMODE = 1 ;режим генератора
     WriteINIStr "$INIFILE" "DIRECTORY" "ISTALLDIR" "$INSTDIR" ;создаем файл конфигурации
 ${EndIf}
FunctionEnd

;===========================================================================================
;  УСЛОВИЕ ВЫПОЛНЕНИЯ ВСЕХ КОМАНД В СЕКЦИИ ТОЛЬКО, ЕСЛИ ПЕРЕМЕННАЯ $SUCCES_SECTION = 1     !
;===========================================================================================
/* МАКРОС ЗАПИСИ ОТМЕЧЕННЫХ СЕКЦИЙ В ФАЙЛ КОНФИГУРАЦИИ
 ${GetSecWriteSucces} индетификатор_секции
   пример:
     [Sections]
     Test=1 - секция отмечена
     Test=0 - секция не отмечена
 Если не отмечена секция, то записи в файле конфигурации не будет, т.е равносильно тому,
 что переменная $SUCCES_SECTION = 0
*/
;==========================================================================================
!define GetSecWriteSucces "!insertmacro _WriteSection"
!macro _WriteSection secID
    StrCpy $SUCCES_SECTION 1 ;по умолчанию ставим $SUCCES_SECTION = 1
    StrCmp $GMODE 1 WriteMode ;проверяем режим установки, если $GMODE = 1, режим генератора
    IfSilent 0 EndMarco ;проверяем тихий режим, если не тихий режим - выход из макроса
    IfFileExists "$INIFILE" 0 EndMarco ;проверяем наличие файла конфигурации
    ClearErrors ;очищаем флаг ошибки прунудительно, перед чтением файла конфигурации
    ReadINIStr $SUCCES_SECTION "$INIFILE" "Sections" "${secID}" ;состояние секкций помещаем в $SUCCES_SECTION
    IfErrors 0 +2 ;проверка на ошибки в чтении файла конфигурации
    StrCpy $SUCCES_SECTION 0 ;в случае ошибки $SUCCES_SECTION = 0
    Goto EndMarco
    WriteMode:
    StrCpy $SUCCES_SECTION 0 ; в режиме генератора $SUCCES_SECTION = 0
    WriteINIStr $INIFILE Sections ${secID} 1
    EndMarco:
!macroend
;==========================================================================================
; УСЛОВИЕ ВЫПОЛНЕНИЯ ВСЕХ КОМАНД В СЕКЦИИ ТОЛЬКО, ЕСЛИ ПЕРЕМЕННАЯ $SUCCES_SECTION = 1     !
;==========================================================================================
Section "-Install"
;чтение из файла ответов путь установки и перезапись значения $INSTDIR
;Условие чтения и перезаписи:
;         ТОЛЬКО НЕ В РЕЖИМЕ ГЕНЕРАТОРА И ТОЛЬКО В ТИХОМ РЕЖИМЕ И ПРИ НАЛИЧИИ ФАЙЛА ОТВЕТОВ
  ${If} $GMODE = 0
  ${AndIf} ${Silent}
  ${AndIf} ${FileExists} "$INIFILE"
     ClearErrors
     ReadINIStr "$R0" "$INIFILE" "DIRECTORY" "ISTALLDIR"
     ${WordReplace} $R0 "%programfiles%" "$PROGRAMFILES" "+" $R1
     ${WordReplace} $R1 "%windir%" "$WINDIR" "+" $R0
     ${WordReplace} $R0 "%appdata%" "$APPDATA" "+" $R1
     ${WordReplace} $R1 "%systemdrive%" "$SysDrive" "+" $R0
     StrCpy $INSTDIR $R0
 ${EndIf} 
  ${If} $GMODE = 0 ;выполнение всегда, только не в режиме генератора
      ;--------
     /*
         тут ваш код!,  эта секция всегда должна выполняться
         команды пишем до конца конструкции ${EndIf}
    */
    ;--------
  ${EndIf}
SectionEnd

Section "Test" Test ; Test - индетификатор секции
 ${GetSecWriteSucces} Test
 ${If} $SUCCES_SECTION = 1
     ;MessageBox MB_OK "Test = $SUCCES_SECTION" IDOK
    ;--------
    /*
    здесь пишите свои команды
    до конца конструкции ${EndIf}
   */
   ;--------
 ${EndIf}
SectionEnd

Section "Test1" Test1 ; Test1 - индетификатор секции
 ${GetSecWriteSucces} Test1
 ${If} $SUCCES_SECTION = 1
    ;MessageBox MB_OK "Test1 = $SUCCES_SECTION" IDOK
    ;--------
    /*
    здесь пишите свои команды
    до конца конструкции ${EndIf}
   */
   ;--------
 ${EndIf}
SectionEnd
 
Section "Test2" Test2 ; Test2 - индетификатор секции
 ${GetSecWriteSucces} Test2
 ${If} $SUCCES_SECTION = 1
   ;MessageBox MB_OK "Test2 = $SUCCES_SECTION" IDOK
   ;--------
   /*
   здесь пишите свои команды
   до конца конструкции ${EndIf}
  */
  ;--------
 ${EndIf}
SectionEnd

wolkow70 · Отправлено: **12:05, 08-05-2011** | #**1164**

Цитата kotkovets:

Спасибо ВСЕМ за то, что тратите свое время, что бы ПОМОЧЬ МНЕ »

Получается, что это нам надо сказать:
Спасибо Вам, за то, что тратите свое время, что бы ПОМОЧЬ НАМ!

wolkow70 · Отправлено: **12:30, 11-05-2011** | #**1165**

kotkovets,

Делаю установщик на программу FlylinkDC++.
В общем на XP она и в Program Files хорошо ставится и работает.
А на Windows 7 рекомендуют ставить папку с программой в корень диска.
Я так понимаю, что вышеприведенный пример:

Function .onInit
${If} ${AtLeastWinVista} ;начиная от WinVista и выше
Var /global SysDrive ; иницилизируем здесь, в ниже версиях Windows SysDrive - не используется
StrCpy $SysDrive $WINDIR 2
StrCpy $INSTDIR "$SysDrive\Games\XXX"
${Else}
StrCpy $INSTDIR "$PROGRAMFILES\XXX"
${EndIf}
FunctionEnd

InstallDir "$INSTDIR\XXX"

можно попробовать????

kotkovets · Конфигурация компьютера

Цитата wolkow70:

можно попробовать???? »

Попробовать можно все, если религия позволяет...

Цитата wolkow70:

А на Windows 7 рекомендуют ставить папку с программой в корень диска »

Рекомендуют из-за прав(привелегий) пользователя в Vista/Win7
http://forum.oszone.net/post-1459797-559.html и здесь продолжение http://forum.oszone.net/post-1460492-563.html
К тому же пример определения права пользователя и сколько прав у пользователя (а значит меняем папку распаковки) есть в справочнике по NSIS.

wolkow70 · Отправлено: **18:39, 11-05-2011** | #**1167**

Цитата kotkovets:

К тому же пример определения права пользователя и сколько прав у пользователя (а значит меняем папку распаковки) есть в справочнике по NSIS. »

Пробовал я так сделать, на семерке дает добро в Программы.. Почему-то....

kotkovets · Конфигурация компьютера

Цитата wolkow70:

Пробовал я так сделать, на семерке дает добро в Программы.. Почему-то.... »

потому что, пользователь с правами админа, а если пользователь без прав админа(и его наследников), то винда вам не даст установить в папку %PROGRAMFILES% ничего и недаст добро в реестре запись (изменение) на корневую ветку HKEY_LOCAL_MACHINE
Определить какими правами обладает пользователь поможет стандартный плагин в составе NSIS

Код:

UserInfo::GetOriginalAccountType
Pop $0
MessageBox MB_OK "$0"

wolkow70 · Отправлено: **08:22, 12-05-2011** | #**1169**

Товарищи, подскажите, что поправить :

WriteIniStr "$INSTDIR\${PRODUCT_NAME}.url" "InternetShortcut" "URL" "${PRODUCT_WEB_SITE}"
CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\Веб-сайт ${PRODUCT_NAME}.lnk" "$INSTDIR\${PRODUCT_NAME}.url"

Ярлык интернета создается и работает, но характерная интернет-иконка в меню Пуск отсутствует. Просто никакой значок. Мне надо, чтобы иконку интернета подключить к ссылке.

kotkovets · Конфигурация компьютера

Цитата wolkow70:

Просто никакой значок. Мне надо, чтобы иконку интернета подключить к ссылке »

А чем плох ОБЫЧНЫЙ ярлык?

Код:

CreateShortCut  "$SMPROGRAMS\${PRODUCT_NAME}\Сайт ${PRODUCT_NAME}.lnk" "http://wwww.aimp.ru"  "" "$PROGRAMFILES\Internet Explorer\iexplore.exe" 1