[gora]

Нужно написать код для проверки большого количества файлов в разных директориях, и в случае отсутствия хотя-бы одного, вывести окошко с текстом об отсутствии файлов. Главное, чтобы эту команду не перечислять после указания каждого файла, она одинакова для всех отсутствующих файлов, должно быть красиво. »

Попробуйте так:

Код:

@Echo off
For %%I In (
 "Директория\файл.exe"
 "Директория\файл2.exe"
 "Директория\файл3.exe"
 "Директория\файл4.exe"
 "Директория\файл5.exe"
 "Директория 1\файл.exe"
 "Директория 1\файл2.exe"
 "Директория 1\файл3.exe"
 "Директория 1\файл4.exe"
 "Директория 1\файл5.exe"
) Do If Not Exist "%%~I" msg * /w /TIME:2 File '%%I' is absent.
exit

If Not Exist %Директория%\файл.exe »

Не делайте переменных содержащих кирилицу.

Если у Вас в каждой директории ищутся одни и те же файлы, то можно сделать еще короче применив вложенный цикл.

[amel27]

NBA

нужно в указаное время - с 9AM до 12 AM а то он будет бесконечно так лобудеть »

тогда без планировщика не обойтись

Rostlv

1. Нужно написать код для проверки большого количества файлов в разных директориях »

вроде уже спрашивал, чем не устраивает п.2 ?

2. Как с помощью CMD создать реально работающий прогрессбар? »

Progress Meter by Roy Holt, пример использования:

Код:

@ECHO OFF

CALL :ProgressMeter 0
For %%i In (10 20 30 40 50 60 70 80 90 100) Do (
	Ping -n 2 127.0.0.1 >Nul
	CALL :ProgressMeter %%i
)

[Rostlv]

Ещё 2 вопроса:
1. Какой ключ применить для старта и отображения текстового документа (.txt, .rtf, .doc) в режиме "поверх всех окон"?
2. Можно ли с помощью CMD проверить свободное место на системном и (или) загрузочном дисках, и в случае нехватки последнего выйти из CMD-файла?
Спасибо.

[Creat0R]

amel27,

Progress Meter by Roy Holt, пример использования:»

Никогда бы не подумал что в батнике можно это сделать .

Пример с отображением в самой консоли...

Код:

@ECHO OFF

CALL :ProgressMeter 0

For %%i In (10 20 30 40 50 60 70 80 90 100) Do (
	Ping -n 2 LocalHost > Nul
	CALL :ProgressMeter %%i
)

Ping -n 3 LocalHost > Nul

:: ******************************************************************
:ProgressMeter
:: 2007_01_10 by rholt
:: core2quad@rogers.com
:: This subroutine displays a progress meter in the titlebar of
:: the current CMD shell window.
::
:: Input: %1 must contain the current progress (0-100)
:: Return: None
:: ******************************************************************
:: Calculate the number of vertical bars then spaces based on the percentage value passed
SETLOCAL ENABLEDELAYEDEXPANSION

SET ProgressChar=I
SET ProgressPercent=%1
SET /A NumBars=%ProgressPercent%/2
SET /A NumSpaces=50-%NumBars%

:: Clear the progress meter image
SET Meter=
CLS

COLOR 0A

:: Build the meter image using vertical bars followed by trailing spaces
:: Note there is a trailing space at the end of the second line below
FOR /L %%A IN (%NumBars%,-1,1) DO SET Meter=!Meter!%ProgressChar%
FOR /L %%A IN (%NumSpaces%,-1,1) DO SET Meter=!Meter! 

:: Display the progress meter in the title bar and return to the main program
TITLE Progress: [%Meter%] %ProgressPercent%%%...
ECHO Progress: [%Meter%] %ProgressPercent%%%...

ENDLOCAL

GOTO :EOF

Rostlv,

Какой ключ применить для старта и отображения текстового документа (.txt, .rtf, .doc) в режиме "поверх всех окон"?

Можно так:

Код:

Start "SomFile.txt" && Start Cmdow "Title" /Top

[amel27]

Creat0R,

Пример с отображением в самой консоли

в твоем примере зачищается хистори... давно хотел такое же, но без затирания, вроде нашел:

Код:

@Echo Off
Setlocal EnableDelayedExpansion

Echo. Процесс запущен
For /L %%i In (1,1,100) Do (
  Call :SHOW %%i Тестирование...
   Ping -n 1 127.0.0.1 >Nul
)
Echo.
Echo.
Echo. Процесс завершен
Echo.
Pause

Exit

:SHOW
Set $COLS=70

If Not Defined $P (
  Set /A $P=0
  Set $X=[
  For /L %%a In (1,1,%$COLS%) Do Set $X=!$X!.
  Set $X=!$X!]
  For /L %%a In (1,1,%$COLS%) Do Set $X=!$X!
  Set $X=!$X!
  Echo.
  <Nul Set /P $X=!$X!
)
Set $X=
Set /A $D = (%$COLS%*%1)/100 - (%$COLS%*%$P%)/100
If %$D% GTR 0 For /L %%a In (1,1,%$D%) Do Set $X=!$X!#
If %1 EQU 100 Set $X=!$X!]
<Nul Set /P $X=!$X!
Title %2%1%% Done
Set $P=%1

GoTo :EOF

[Creat0R]

amel27,

давно хотел такое же, но без затирания, вроде нашел »

Привосходно! я пробовал, но очень быстро опустил руки, видимо думал что нереально .

Подскажите плиз, как можно реализовать небольшой мониторинг времени:
к примеру, есть определенный промежуток времени - с 23:00 до 09:00. Надо сделать так, чтобы в батник проверял время, и, если текущее время соответствует заданному промежутку, то выполняет какие-либо действия.
Всё, на что хватило моих познаний, это на мониторинг определенного времени (не промежутка):

Код:

@echo off
:monitor
set stoptime=23:00
for /F %%t in ('time/T') do set T=%%t
if %T%==%stoptime% (
call :stop 
) else (
call :monitor

:stop
start stop.exe
exit

[Creat0R]

D_Master,

Надо сделать так, чтобы в батник проверял время, и, если текущее время соответствует заданному промежутку, то выполняет какие-либо действия. »

Примерно так:

Код:

@Echo Off

Set StopTime1=23:00
Set StopTime2=09:00

:Monitor
For /F %%i In ('Time/T') Do Set CurrentTime=%%i

If %CurrentTime% GTR %StopTime2% If %CurrentTime% GEQ %StopTime1% Call :Stop
If %CurrentTime% LSS %StopTime1% If %CurrentTime% LEQ %StopTime2% Call :Stop

Ping -n 2 LocalHost > Nul
GoTo :Monitor

:Stop
Start Stop.exe
Exit

Creat0R, спасибо, всё работает!

[censored]

echo Off
cls
echo Нажмите:
echo "1" , если nForce2
echo "2" , если nForce4
echo "3" , если другое.
Set /P Ch=Сделайте Ваш выбор:
If "%Ch%"=="1"
Echo Устанавливаем драйвера для NForce2 ....
start \Program files\ASV\nforce2\setup.exe
goto :1
If "%Ch%"=="2"
Echo Устанавливаем драйвера для nForce4.....
start \Program Files\ASV\nForce4\setup.exe
goto :1
If "%Ch%"=="3"
goto :1

Подскажите где ошибка.