[amel27]

Creat0R

чтобы разделитель определялся только после закрывающей кавычки »

например так, хотя и этот вариант далек от идеала - имя параметра может оказаться частью значения другого параметра (в кавычках), эти случаи не отслеживаются таким выражением:

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '/Param=1 ^File "C:\Program Files\Some App\File - Name.txt" /URL "http://google.com"'

MsgBox(64, "", _
    _GetCmdLine($CmdLineRaw, "/Param=") & @LF & _
    _GetCmdLine($CmdLineRaw, "/URL") & @LF & _
    _GetCmdLine($CmdLineRaw, "^File"))

Func _GetCmdLine($sCmdLine, $sArgument)
    If Not StringInStr($sCmdLine, $sArgument) Then Return SetError(1, 0, "")

    Local $sRegExp = '(?i)^.*?\Q'& $sArgument &'\E\s*(?:(?:"([^"]*)")|([^"\s]+)).*$'
    Local $sRetCmd = StringRegExpReplace($sCmdLine, $sRegExp, '\1\2')
    If $sRetCmd = $sCmdLine Then Return SetError(2, 0, "")

    Return StringStripWS($sRetCmd, 3)
EndFunc

З.Ы. Обрати внимание на теги \Q...\E, они блокируют спецсимволы на интервале выражения

[Creat0R]

amel27,

этот вариант далек от идеала - имя параметра может оказаться частью значения другого параметра (в кавычках) »

Можешь показать на примерной строке? у меня что-то то не удалось, твоя функция отлично отрабатывает в любом(?) случае

Хотя есть проблема с путями без кавычек, они обрубаются на перевом пробеле - Нужно либо до кавычки, либо до разделителя (/ или -).

Обрати внимание на теги \Q...\E, они блокируют спецсимволы на интервале выражения »

Интересно, оно даже в справке есть, а мы (я?) раньше делали отдельную RegExp обработку для замены:

Код:

$String = "test [or] example ;)"
$String = StringRegExpReplace($String, '([][{}()|.?+*\\^])', '\\\1')

MsgBox(64, "", "Теперь все служебные символы могут обрабатываться как обычные ;) :" & @LF & @LF & $String)

[Creat0R]

В принципе, можно было бы указать постоянный разделитель, но он должен быть опционально задан в параметре. Т.е вся строка может содержать параметры только одного характера, но нужно сделать так, чтобы функцию можно было применять на разные строки. Вот что у меня (не) получилось:

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '/Param="1" /File=C:\Program Files\Some App\File - Name.txt /URL="http://google.com"'

MsgBox(64, "", _
    _GetCmdLine($CmdLineRaw, "/Param=") & @LF & _
    _GetCmdLine($CmdLineRaw, "/URL=") & @LF & _
    _GetCmdLine($CmdLineRaw, "/File="))

Func _GetCmdLine($sCmdLine, $sArgument, $sCmd_Delim='/.*=')
    If Not StringInStr($sCmdLine, $sArgument) Then Return SetError(1, 0, "")

    Local $sRegExp = '(?i)^.*?\Q' & $sArgument & '\E\s*(?:(?:"([^"]*)")|([^"]+)' & $sCmd_Delim & ').*$'
    Local $sRetCmd = StringRegExpReplace($sCmdLine, $sRegExp, '\1\2')
    If $sRetCmd = $sCmdLine Then Return SetError(2, 0, "")

    Return StringStripWS($sRetCmd, 3)
EndFunc

Стоит только убрать кавычки у одного из значении, и возвращается неверное значение. Нужно чтобы при данном раскладе, возвращались все значения вне зависимости от присутствия кавычек у них.

P.S
$sCmd_Delim это и есть указатель на резделитель, т.е в одной строке могут быть только такие разделители: /Param=, или только такие: -Param=, или такие например: -Param:, но не смешанные (как я задумывал в начале).

[amel27]

Creat0R

Можешь показать на примерной строке? »

Код:

$CmdLineRaw = '/Param="/URL http://mail.ru" .File "C:\Program Files\Some App\File - Name.txt" /URL "http://google.com"'

есть проблема с путями без кавычек, они обрубаются на перевом пробеле »

AFAIK все программы используют пробелы для разделения параметров, либо кавычки для значений с пробелом... надо ли городить огород?

оно даже в справке есть

в справке есть, но там туманное описание и не все что в справке работает как написано

[kronic]

Может кто нибудь подсказать как можно взять из файла символы и отправить их в активное окно как нажатие их на клавиатуре

[Creat0R]

amel27,

AFAIK все программы используют пробелы для разделения параметров, либо кавычки для значений с пробелом »

Да, но из за этого юзеры (смышлённые, те которые указывают ком. строку ) лишний раз спрашивают разные вопросы, мол почему "так" работает, а "так" нет. Хочется перестраховаться, a.k.a “Защита от дурака”.

надо ли городить огород? Цитата: »

Желательно

kronic

как можно взять из файла символы и отправить их в активное окно как нажатие их на клавиатуре »

Код: $sChars = FileReadLine($sFile, 3) ;Считывает символы с третьей строки файла Send($sChars)

[amel27]

Creat0R

раньше делали отдельную RegExp обработку для замены »

ну как минимум одну замену сделать придется

Код:

$sArgument  = "\Q"& StringReplace($sArgument,"\E","\E\\E\Q") &"\E"

Хочется перестраховаться »

по стандарту - строка парсится на CMD-параметры пробелами/кавычками, далее прога своими средствами сканирует массив CMD-параметров и решает что является параметром, что значением, что параметром со значением ("/A:F") а что является нарушением синтаксиса... тут ИМХО все как раз прозрачно

насколько я понял, ты хочешь заменить стандартные спецсимволы кавычки и пробела на свои - символы начала/конца блока параметра ("/-"), внутри которого имя параметра от его значения разделяется другими спецсимволами ("=: "), не будет ли это сменой "шила на мыло" - указанные спецсимволы уже нельзя будет просто так указывать в значении параметров... например, придется брать в кавычки (вместо пробелов) ... заметь, что при этом пробел теряет свой статус и значение может включать несколько строк с экранирующими кавычками, т.е. обработку концевых символов придется проводить отдельно

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '/Param=1 /Fil\e "C:\Program Files\Some App\File" - "Name.txt" /URL:"http://google.com"'

MsgBox(64, "", _
    _GetCmdLine($CmdLineRaw, "Param") & @LF & _
    _GetCmdLine($CmdLineRaw, "URL") & @LF & _
    _GetCmdLine($CmdLineRaw, "Fil\e"))

Func _GetCmdLine($sCmdLine, $sArgument, $sParPrefix="/", $sValPrefix="=: ")
    ; Экранируем спецсимволы
    $sParPrefix = StringRegExpReplace($sParPrefix, "[-^\]", "\\1")
    $sValPrefix = StringRegExpReplace($sValPrefix, "[-^\]", "\\1")
    $sArgument  = "\Q"& StringReplace($sArgument,"\E","\E\\E\Q") &"\E"

        #Region Построение регулярного выражения
    Local $ExpandVarStrings = Opt("ExpandVarStrings", 1)

    Local $sParClassIn = '[$sParPrefix$]'   ; класс начала имени параметра
    Local $sValClassIn = '[$sValPrefix$]'   ; класс конца имени/начала значения
    Local $sAllClassEx = '[^$sParPrefix$"]' ; класс обычных символов

    Local $sRegExp = '(?i)^.*?$sParClassIn$$sArgument$(?:$sValClassIn$+((?:"[^"]*"|$sAllClassEx$+)+))?.*$'
    ConsoleWrite($sRegExp &@CRLF)

    Opt("ExpandVarStrings", $ExpandVarStrings)
    #EndRegion

    Local $sRetCmd = StringRegExpReplace($sCmdLine, $sRegExp, '\1')
    If @extended Then Return $sRetCmd
    Return SetError(1, 0, "NOT FOUND")
EndFunc

[Creat0R]

по стандарту - строка парсится на CMD-параметры пробелами/кавычками, далее прога своими средствами сканирует массив CMD-параметров и решает что является параметром, что значением, что параметром со значением ("/A:F") а что является нарушением синтаксиса... тут ИМХО все как раз прозрачно »

В том то и дело, что не все придерживаются стандартам. Например, в браузере Opera последних версии, параметры ком. строки (там можно запускать внешние приложения с меню) передаются немного криво. Кавычками обрамляются не только параметры с заглавной буквы (это типа стандарт самого браузера, %U будет в кавычках, а %u уже нет), но и вся ком. строка, т.е на выходе получается что-то типа "/Param="http://..." "some value"". Вобщем не всегда предсказуемый результат имеется, и, кроме того что от версии к версии это по разному, так ещё хотелось иметь универсальный вариант для других случаев, чтобы не нужно было переделывать функцию для каждой задачи отдельно (что я и делал до сих пор).

насколько я понял, ты хочешь заменить стандартные спецсимволы кавычки и пробела на свои

Не уверен что понял, но что я хочу сделать я описал в последнем посте на эту тему:

В принципе, можно было бы указать постоянный разделитель, но он должен быть опционально задан в параметре. Т.е вся строка может содержать параметры только одного характера »

....

Стоит только убрать кавычки у одного из значении, и возвращается неверное значение. Нужно чтобы при данном раскладе, возвращались все значения вне зависимости от присутствия кавычек у них. »

Осталось только доработать мой код в том посте.

P.S
Спасибо за пример, но там тоже есть проблемы, например если убрать кавычки у /URL, то возвращается только «http:». Также парамтеры должны разделяться не одним префиксом, а ещё и пробелом в начале, т.е чтобы значение считалось до того момента, пока не обнаружен пробел с префиксом (где «/Param1=Val1/Param2=Val2» уже неверная строка, тут значением считается Val1/Param2=Val2, вот если бы после Val1 был пробел, тогда второй параметр не входил в значение ).

[amel27]

Creat0R

так ещё хотелось иметь универсальный вариант для других случаев, чтобы не нужно было переделывать функцию для каждой задачи отдельно »

чтобы регулярное выражение работало надежно, оно должно отражать реальный синтаксис строки, у "универсального варианта" с нечеткими правилами формата всегда будут вылазить "дыры" то в одном месте, то в другом...

парамтеры должны разделяться не одним префиксом, а ещё и пробелом в начале, т.е чтобы значение считалось до того момента, пока не обнаружен пробел с префиксом »

хорошо, вот еще вариант реализации, но стоит заменить "-" на "/" чтобы выражение перестало работать, так как одного пробела с префиксом недостаточно для идентификации ожидаемого параметра:

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '/Param=12 /XXX /Fil\e "C:\Program Files\Some App\File" - "Name.txt" /URL:"http://google.com"'

MsgBox(64, "", _
    "Param: "&@TAB& _GetCmdLine($CmdLineRaw, "Param") & @LF & _
    "XXX: "  &@TAB& _GetCmdLine($CmdLineRaw, "XXX") & @LF & _
    "YYY: "  &@TAB& _GetCmdLine($CmdLineRaw, "YYY") & @LF & _
    "URL: "  &@TAB& _GetCmdLine($CmdLineRaw, "URL") & @LF & _
    "Fil\e: "&@TAB& _GetCmdLine($CmdLineRaw, "Fil\e"))

Func _GetCmdLine($sCmdLine, $sArgument, $sParPrefix="/", $sValPrefix="=:")
    $sPar = StringRegExpReplace ($sParPrefix, "[-^\]", "\\1")
    $sVal = StringRegExpReplace ($sValPrefix, "[-^\]", "\\1")
    $sArg  = "\Q"& StringReplace($sArgument,"\E","\E\\E\Q") &"\E"

    Local $sRegExp = '(?i)^(?:|.*?\s)['&$sPar&']'&$sArg&'['&$sVal&' ]+(?:$|['&$sPar&']|((?:"[^"]*"|[^"])+?)(?:$|\s['&$sPar&'])).*'
    ConsoleWrite($sRegExp &@CRLF)
    Local $sRetCmd = StringRegExpReplace($sCmdLine, $sRegExp, '\1')

    If @extended Then Return $sRetCmd
    Return SetError(1, 0, "NOT FOUND")
EndFunc

[Creat0R]

amel27,

вот еще вариант реализации »

Почти(!) идеален!

но стоит заменить "-" на "/" чтобы выражение перестало работать, так как одного пробела с префиксом недостаточно для идентификации ожидаемого параметра »

Странно, а чем отличается "-" от "/" ? А что если придерживаться условию, что все параметры будут иметь какой-то один разделитель?

Пример:

Код:

If $CmdLine[0] = 0 Then $CmdLineRaw = '-Param=1 -XXX=xVal -File=C:\Program Files\Some App\File - Name.txt -URL=http://google.com'

MsgBox(64, "", _
    "Param: " & @TAB & _GetCmdLine($CmdLineRaw, "Param") & @LF & _
    "XXX: "  & @TAB & _GetCmdLine($CmdLineRaw, "XXX") & @LF & _
    "YYY: "  & @TAB & _GetCmdLine($CmdLineRaw, "YYY") & @LF & _
    "URL: "  & @TAB & _GetCmdLine($CmdLineRaw, "URL") & @LF & _
    "File: " & @TAB & _GetCmdLine($CmdLineRaw, "File"))

$sParPrefix при этом равен "-". Но опять же, имя файл в таком случае обрубается

P.S
Теперь что получается, нужно почти при каждом использовании RegExp, применять метод отмены спец. символов (\Q...\E)?