[vserd]

а в самом cmd, если это возможно. »

в начале
if [%RUNNED%]==[1] goto :Eof
set RUNNED=1
..........
код батника
..........
rem в саммом конце основного блока.
set Runned=
goto :eof


RUNNED не должно использоваться в оригинальном cmd. В противном случае изменить на другое имя

[Liveofan]

amel27,
Ясн. может пригодится, токо начал читать про WSH интересно )
Сейчас хочу автоматизовать процесс ввода в домен, на микрософте наткнулся на вот этот скриптик:

Код:

Const JOIN_DOMAIN = 1
Const ACCT_CREATE = 2
Const ACCT_DELETE = 4
Const WIN9X_UPGRADE = 16
Const DOMAIN_JOIN_IF_JOINED = 32
Const JOIN_UNSECURE = 64
Const MACHINE_PASSWORD_PASSED = 128
Const DEFERRED_SPN_SET = 256
Const INSTALL_INVOCATION = 262144
 
strDomain = "domen"
strPassword = "123"	
strUser = "user"
 
Set objNetwork = CreateObject("WScript.Network")
strComputer = objNetwork.ComputerName
 
Set objComputer = GetObject("winmgmts:{impersonationLevel=Impersonate}!\\" & _
    strComputer & "\root\cimv2:Win32_ComputerSystem.Name='" & _
        strComputer & "'")
 
ReturnValue = objComputer.JoinDomainOrWorkGroup(strDomain, _
    strPassword, strDomain & "\" & strUser, NULL, _
        JOIN_DOMAIN + ACCT_CREATE)

Протестил, с задаными параметрами, человек запуская его, может добавить машину в домен, но только если изначально зайдет и введет имя машины ручками, все отлично работает.
Но хотелось бы еще в скриптик добавить обработчик ошибки. Т.е. если скрипт сработал и комп в домен попал, чтобы выскочила надпись, комп успешно добавлен в домен, если же комп не смог войти в домен, то выскочило окно ошибки.

И еще вопрос, возможно ли с помощью WSH заполнять сетевые настройки, а также имя компьютера?
Это чисто скриптовый язык? Т.е. графические элементы у него есть? Например когда нужно ввести имя компьютера, то вписывать его не в тело скрипта, а чтобы выскочила панель, куда ты добавишь имя и нажмешь, ок )

[Liveofan]

А еще такой вопрос, есть ли отладчик приложений для WSH, а то если ошибка в коде есть, он просто мне выбрасывает виндовскую табличку с номером строки, в которой ошибка и все (

[amel27]

Rostlv

Нужна cmd-команда, не позволяющая запустить одновременно 2 и более cmd-файлов, причём её нужно указать не в exe-файле, а в самом cmd »

вариант, предложенный vserd не подойдет - в каждой сессии свои переменные окружения,
вместо SET можно использовать SETX из ресурскита Win2K:

Код:

IF "%RUNNED%"=="1" EXIT
SETX RUNNED 1
:: ---
PAUSE
:: ---
SETX RUNNED 0

или через реестр - не так красиво, зато штатными средствами:

Код:

REG QUERY HKCU\Environment /v RUNNED
If "%ERRORLEVEL%"=="0" EXIT
REG ADD HKCU\Environment /v RUNNED /d 1 /f
:: --
PAUSE
:: --
REG DELETE HKCU\Environment /v RUNNED /f

ADD: или через временный файл:

Код:

IF EXIST "%~dpn0.run" EXIT
@Echo.>"%~dpn0.run"
:: --
PAUSE
:: --
DEL "%~dpn0.run"

[amel27]

Liveofan

есть ли отладчик приложений для WSH »

Script Debugger for Windows NT 4.0 and Later
официально больше не поддерживается, хотя работает (смотреть внизу "Additional Information")

если ошибка в коде есть, он просто мне выбрасывает виндовскую табличку с номером строки, в которой ошибка и все ( »

отлавливать ошибки с помощью объекта "Err", указав "On Error Resume Next", подробно и с примерами:

Doctor Scripto's Script Shop (To Err Is VBScript – Part 1)
Doctor Scripto's Script Shop (To Err Is VBScript – Part 2)

[Rostlv]

И ещё вопрос, как с помощью cmd-файла проверить наличие определённого файла в системе, вернее его версии и при не совпадении версии файла с заданной, запретить выполнение cmd.

[Babullika]

Всем доброго времени суток.

Прошу помочь с батником.
Подключаюсь к инету таким вот образом :

код

@echo off
rasdial "internet 1" "login" "pass"
if errorlevel 1 goto error
echo.
echo Программа завершила свою работу!
goto end
:error
echo.
echo Произошла ошибка при работе программы
sleep.exe 3
rasdial "internet 2" "login" "pass"
if errorlevel 1 goto error
echo.
echo Программа завершила свою работу!
goto end
:error
echo.
echo Произошла ошибка при работе программы
sleep.exe 3
rasdial "internet 3" "login" "pass"
if errorlevel 1 goto error
echo.
echo Программа завершила свою работу!
goto end
:error
echo.
echo Произошла ошибка при работе программы
:end

Подскажите как реализовать такую схему: если internet 1 выдал ошибку а инет 2 подключился то поменять их местами , а если второй тоже выдал ошибку а третий сработал то третий на место первого , сдвинув первый на место второго а второй на место третьего ...
( чтобы в следущий раз при запуске бат файла подключалось первым к тому который последний раз был успешно подключен )
Заранее спасибо

[Petya V4sechkin]

как с помощью cmd-файла проверить наличие определённого файла в системе, вернее его версии

[решено] как узнать “версию файла”?

и при не совпадении версии файла с заданной, запретить выполнение cmd

Примерно так:

Код:

@Echo Off
For /F "Tokens=5 Delims= " %%I In ('Filever.exe %windir%\explorer.exe') Do Set V=%%I

Echo %V%
If %V% NEQ 6.0.2900.5512 (
  Echo Версия Explorer.exe не равна 6.0.2900.5512
  Pause
  Exit
)

[amel27]

Babullika

как реализовать такую схему: если internet 1 выдал ошибку а инет 2 подключился то поменять их местами , а если второй тоже выдал ошибку а третий сработал то третий на место первого , сдвинув первый на место второго а второй на место третьего »

хранить порядок в файле, примерно так:

Код:

@Echo OFF

Set CONN_LIST=%~dpn0.ini
Set TEMP_LIST=%~dpn0.tmp

If Exist "%TEMP_LIST%" Del /Q "%TEMP_LIST%"
For /F "UseBackQ Delims=" %%i In ("%CONN_LIST%") Do Call :CONNECT %%i

If Defined CONN_PARM (
   Echo %CONN_PARM%>"%CONN_LIST%"
   Type "%TEMP_LIST%">>"%CONN_LIST%"
   Echo.
   Echo Подключение произведено успешно!
) Else (
   Echo.
   Echo Произошла ошибка при работе программы
)
Exit

:CONNECT
If Defined CONN_PARM GOTO :CONNECT_SKIP
>Nul RasDial %*
If NOT ERRORLEVEL 1 Set CONN_PARM=%*
If Defined CONN_PARM GoTo :EOF
:CONNECT_SKIP
Echo %*>>"%TEMP_LIST%"
GoTo :EOF

примерное содержимое файла "Имя батника".INI:

Код:

"Internet 1" "Login1" "Pass1"
"Internet 2" "Login2" "Pass2"
"Internet 3" "Login3" "Pass3"
"Internet 4" "Login4" "Pass4"
"Internet 5" "Login5" "Pass5"

[vserd]

вариант, предложенный vserd не подойдет - в каждой сессии свои переменные окружения, »

Вообще-то да (( я как-то не учел что запуск из под внешнего приложения. Для разных сесий нужно создавать и удалять файл.