[Архив - Часть 3] AutoIt скрипты .:[общие вопросы]:.

Senka11 · Отправлено: **16:56, 29-01-2008** | #61

#include <GUIConstants.au3>

GUICreate("Computer ID system created by Senka!", 320, 200)
GUICtrlCreateLabel("Input Computer ID", 10, 10)
$okbutton = GUICtrlCreateButton("Ready", 110, 120, 60)
$nEdit = GUICtrlCreateInput ("inventory no.", -1,3,175,20)
$aEdit = GUICtrlCreateInput ("Everest no.", -1,30,175,20)
GUISetState ()

While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
MsgBox(0, "GUI Event", "You clicked CLOSE! Exiting...")
exit

Case $msg = $okbutton
MsgBox(0, "11", "You pressed OK!")
filewrite(FileOpen("Data.txt",1),"Data from $nEdit: " & $nEdit &@CRLF& "Data from $aEdit: "& $NEdit & @CRLF)

EndSelect
WEnd

работает но не так как нужно!

filewrite(FileOpen("Data.txt",1),"Data from $nEdit: " & $nEdit &@CRLF& "Data from $aEdit: "& $NEdit & @CRLF)
записывает в файл:

Data from $nEdit: 6

что бы я не вводил в
$nEdit = GUICtrlCreateInput ("inventory no.", -1,3,175,20)
подскажите че исправить!!!!

HORRIBLE · Отправлено: **17:19, 29-01-2008** | #62

Creat0R,
ага, спасибо за FileClose(Handle)- эту команду воткнул в код и все получил ответ на свой вопрос который ты не понял)

Creat0R · Конфигурация компьютера

Senka11,
Во-первых код заключать нужно в тег [code] (#)... или использовать утилиту для раскраски

Цитата:

подскажите че исправить!

Код:

#include <GUIConstants.au3>

GUICreate("Computer ID system created by Senka!", 320, 200)

GUICtrlCreateLabel("Input Computer ID", 10, 10)

$OK_Button = GUICtrlCreateButton("Ready", 110, 120, 60)

$nEdit = GUICtrlCreateInput("inventory no.", -1, 3, 175, 20)
$aEdit = GUICtrlCreateInput("Everest no.", -1, 30, 175, 20)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            MsgBox(0, "GUI Event", "You clicked CLOSE! Exiting...")
            Exit
        Case $OK_Button
            MsgBox(0, "11", "You pressed OK!")

            Local $sDataFrom_nEdit = GUICtrlRead($nEdit)
            Local $sDataFrom_aEdit = GUICtrlRead($aEdit)

            Local $hOpenFile = FileOpen("Data.txt", 1)

            FileWriteLine($hOpenFile, _
                "Data from $nEdit: " & $sDataFrom_nEdit & @CRLF & _
                "Data from $aEdit: "& $sDataFrom_aEdit)

            FileClose($hOpenFile)
    EndSwitch
WEnd

HORRIBLE · Отправлено: **17:42, 29-01-2008** | #64

Creat0R, а почему в моем примере для Senka11, ересть какая то записывалась в файл,несмотря на то, что ты в водишь в поля ?

#include <GUIConstants.au3>

GUICreate("Computer ID system created by Senka!", 320, 200)
GUICtrlCreateLabel("Input Computer ID", 10, 10)
$okbutton = GUICtrlCreateButton("Ready", 110, 120, 60)
$nEdit = GUICtrlCreateInput ("inventory no.", -1,3,175,20)
$aEdit = GUICtrlCreateInput ("Everest no.", -1,30,175,20)
GUISetState ()

While 1
$msg = GUIGetMsg()
Select
Case $msg = $GUI_EVENT_CLOSE
MsgBox(0, "GUI Event", "You clicked CLOSE! Exiting...")
exit

Case $msg = $okbutton
MsgBox(0, "11", "You pressed OK!")
filewrite(FileOpen("Data.txt",1),"Data from $nEdit: " & $nEdit &@CRLF& "Data from $aEdit: "& $NEdit & @CRLF)
FileClose("Data.txt")

EndSelect
WEnd

Senka11 · Отправлено: **18:09, 29-01-2008** | #65

я вот переделал и упростил свою задачу!!!!!!

PHP код:


$nEdit = InputBox("Input inventory ID", "Input inventory ID", "", "", -1,3,175,20)
$aEdit = InputBox("Input Everest ID", "Input Everest ID", "", "", -1,30,175,20)
FileWrite(FileOpen("Data.txt",1),"inventory ID:" &$nEdit&@CRLF& "Everest ID:"& $NEdit & @CRLF)

работает все супер !!!!
теперь вопрос в след. я хочу создать меседж бокс который выводил бы на екран IP тачки !!!!!!!!
и дописывал его вместе с мак адресом в txt файлик!!!!!!Help если ктото знает!!!!!!!!

P.S
Огромное спасибо CREATOR-e за неоценимую помощь!!!!!!!!!!

Creat0R · Конфигурация компьютера

HORRIBLE,

Цитата:

почему в моем примере для Senka11, ересть какая то записывалась в файл,несмотря на то, что ты в водишь в поля ?

Записываются идентификаторы контролов, чтобы получить данные введённые в эти элементы, нужно использовать GUICtrlRead()

(см. мой пример выше).

Senka11,

Цитата:

создать меседж бокс который выводил бы на екран IP тачки

Для этого есть макрос @IPAddress2.

Цитата:

Огромное спасибо CREATOR-e за неоценимую помощь!

Для этого есть ссылочка внизу у каждого сообщения -

Полезное сообщение

Maza Faka · Отправлено: **08:06, 30-01-2008** | #67

Senka11
Мдааа...ты хоть сам понял, что написал?
Функция InputBox() не является создаваемым элементом пользовательского GUI, это встроенное стандартное окно диалога. Пример создания пользовательского GUI:

Код:

#include <GUIConstants.au3>

GUICreate("Computer ID system created by Senka!", 260, 160)

GUICtrlCreateLabel("Input Computer ID", 15, 30, 90, 15)
GUICtrlCreateLabel("Input Everest ID", 160, 30, 90, 15)

$nEdit = GUICtrlCreateInput("", 10, 50, 100, 17)
$aEdit = GUICtrlCreateInput("", 150, 50, 100, 17)

$OK_Button = GUICtrlCreateButton("Ready", 10, 130, 60, 20)
GUICtrlSetCursor(-1, 0)
$Close_Button = GUICtrlCreateButton("Close", 190, 130, 60, 20)
GUICtrlSetCursor(-1, 0)

GUISetState()

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
    Case $GUI_EVENT_CLOSE, $Close_Button
        Exit
    Case $OK_Button
        $sDataFrom_nEdit = GUICtrlRead($nEdit)
        $sDataFrom_aEdit = GUICtrlRead($aEdit)

        If $sDataFrom_nEdit = '' Or $sDataFrom_aEdit = '' Then
            MsgBox(16, "Error", "Please fill in the forms")
            ContinueCase
        EndIf

        $DataFile = FileOpen(@ScriptDir & "\Data.txt", 1)
        FileWriteLine($DataFile, _
        "Data from $nEdit: " & $sDataFrom_nEdit & @CRLF & _
        "Data from $aEdit: "& $sDataFrom_aEdit)
        FileClose($DataFile)
    EndSwitch
WEnd

Цитата:

я хочу создать меседж бокс который выводил бы на екран IP тачки!
и дописывал его вместе с мак адресом в txt файлик!

Какой тачки? Локальной или удалённой? Для получения IP-адреса используй макро @IPAddress1 или @IPAddress2, а ещё лучше брать его из реестра. Для получения MAC-адреса используй утилиту getmac.exe есть по умолчанию в WindowsXP, для справки вбей в консоль getmac /?.

HORRIBLE · Отправлено: **11:52, 30-01-2008** | #68

Creat0R, мда, тупим по маленьку (это я про себя) , спасибо.

А вот у меня вопрос, интернет страничка игрушки, на ней 2 поля ввода и кнопочка, AutoIt Window Info не показывает ни координат, ни id этих полей, а как можно к чему нить привязаться, чтобы вводить в поле информацию и кнопку жать ?? Конечно, самое простое это tab понажимать, а еще как нить можно?
Когда ввели данные, нажимаем кнопку войти, вошли, другой вопрос, слева наверху есть картинка персонажа, над картинкой его ХП, как в автоите сказать ждать пока не наберется определенное кол-во ХП ждать ?? опять таки привязаться не к чему.

amel27 · Отправлено: **11:59, 30-01-2008** | #69

Цитата Maza Faka:

Для получения IP-адреса используй макро @IPAddress1 или @IPAddress2, а ещё лучше брать его из реестра. Для получения MAC-адреса используй утилиту getmac.exe »

ИМХО лучше без вызова внешних прог - через WMI:

Код:

#include <array.au3>

$a = _NetAdapterGetProp()
_ArrayDisplay($a)

Func _NetAdapterGetProp($sHostName = "localhost")
    Local $objItem, $objWMIService = ObjGet( "winmgmts:\\"& $sHostName &"\root\CIMV2")
    Local $sQuery = 'SELECT Index, Caption, MACAddress, IPAddress FROM Win32_NetworkAdapterConfiguration Where IPEnabled = True'
    Local $colItems = $objWMIService.ExecQuery($sQuery, "WQL", 0x30)
    If IsObj($colItems) Then
        Local $aRes[1][3], $i=0
        For $colItem In $colItems
            ReDim $aRes[$i+1][3]
            $aRes[$i][0] = $colItem.Caption
            $aRes[$i][1] = $colItem.IPAddress(0)
            $aRes[$i][2] = $colItem.MACAddress
            $i+=1
        Next
        Return $aRes
    EndIf
    Return SetError(1)
EndFunc  ;==> _NetAdapterGetProp

Maza Faka · Отправлено: **12:13, 30-01-2008** | #70

amel27
Привет! Ты как всегда на высоте! Отличный пример!