[megaloman]

Вот скрипт, который открывает заданное количество (здесь 3: Set /A NLink=3) случайно выбранных ссылок случайно выбранным браузером. Можно, конечно пооткрывать хоть все ссылки, тогда уберите rem в rem Set /A NLink=%LMax% Одна и та же ссылка дважды открыта не будет.

Код:

@Echo Off
cls
	Call :Brow "BMax"
	Call :Link "LMax"

	Set /A NLink=3	
rem	Set /A NLink=%LMax%	

	Set /A N=0
	:Begin
		Set /A "RB=1+%BMax%*%random%/32768"
		Set /A "RL=1+%LMax%*%random%/32768"
		Call :LStart %RB% %RL% "N"
	If %N% LSS %NLink% If %N% LSS %LMax% GoTo :Begin
Pause
Exit /B 0

:LStart
	Call Set "LL=%%@@L%2%%"
	If "%LL%"=="" Exit /B 0
	rem	Echo %LL%
	Set /A %~3+=1
	Call Start " " "%%@@B%1%%" %LL%
	Call Set "@@L%2="
Exit /B

:Link
	Set "@@L1=https://vz.ru/"
	Set "@@L2=https://lenta.ru/"
	Set "@@L3=http://forum.oszone.net/forum-102.html"
	Set "@@L4=https://www.gismeteo.by/weather-gomel-4918/"
	Set "@@L5=https://www.onliner.by/"
	Set "@@L6=https://youtube.com/"

	Set /A %~1=0
	FOR /F "usebackq delims=" %%i IN (`2^>nul Set "@@L"`) Do Call Set /A %~1+=1 &>nul Call Echo %%Random%%
Exit /B 0

:Brow
	Set "@@B1=C:\Users\HRuban\AppData\Local\Yandex\YandexBrowser\Application\browser.exe"
	Set "@@B2=C:\Program Files\Google\Chrome\Application\chrome.exe"
	Set "@@B3=C:\Program Files\Internet Explorer\iexplore.exe"

	Set /A %~1=0
	FOR /F "usebackq delims=" %%i IN (`2^>nul Set "@@B"`) Do Call Set /A %~1+=1 &>nul Call Echo %%Random%%
Exit /B

В принципе, можно сделать, что будет открыт один случайный линк одним случайным браузером, причем все браузеры будут разными, но тогда количество открытых ссылок должно быть не более количества браузеров.
Полезнее было бы полностью изложить постановку задачи

[wasp14]

Полезнее было бы полностью изложить постановку задачи »

Бггг..., классика. уже лет 20 не меняется Основной Вопрос о вселенной, жизни в вообще...