[Vasyutin]

Добрый денечек. Много лет читаю эту замечательную темку. Образования в этом деле не имею. Но с темы по мелочам все понятненько. Несколько раз делал шутки в виде сообщений в несколько ходов с вопросами и подсовывал их жене вместо ее браузера. Во смеху было. А сейчас совсем я в непонятках с этими RequestExecutionLevel. Такой вопросик. Какая получается разница если установщик позначен RequestExecutionLevel highest или RequestExecutionLevel admin. Интересует чтобы мой файлик смог сделать то что делает администратор. Для этого нужно только обязательно RequestExecutionLevel admin? Или подойдет RequestExecutionLevel highest? Как я понял в установщика с RequestExecutionLevel admin самые высокие права. Тогда какие функции теряет установщик с RequestExecutionLevel highest в сравнении с RequestExecutionLevel admin? Совсем не понятно. Если не тяжело, пожалуйста объясните простенько. Спасибочки.

[MKN]

Простая (казалось бы...) задача : Нужно определить наличие ключей в реестре.
ОС Windows 10 (20h2) x64, ключи :

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Defender\Spynet

Не тут то было... Права доступа похоже не при чём (да и вроде как не нужны для этого...).

Пример, который нормально работает (проверял в W7) с "крутым" владельцем другого ключа ( с TrustedInstaller) :

Код:

!addplugindir .
!include "LogicLib.nsh"
!include "Registry.nsh"
OutFile "IfKeyExists-test.exe"
RequestExecutionLevel admin
Var NameKey

Section
StrCpy $NameKey "HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\AGP"  
ClearErrors
${registry::KeyExists} "$NameKey" $R0
${If} $R0 = -1
MessageBox MB_OK "NO Key"
${ElseIf} $R0 = 0
MessageBox MB_OK "OK!"
${EndIf}
${registry::unload}
SectionEnd

Этот же пример (и с EnumRegKey тоже) не работает в W10 с вышеназванными ключами...
В чём дело ? Кто "охраняет" конкретно эти ключи ? У кого какие соображения ?

ps к слову сказать, эти ключи не находятся при получении ACL, и при использовании команд PowerShell, и при работе с subinacl.exe...

[iglezz]

В чём дело ? »

Элементарно, Ватсон! Ключи эти существуют только для 64бит приложений

Примерно таким макросом можно оформить проверку:

Код:

# macro + def
!define RegKeyExists '!insertmacro RegKeyExists'
!macro RegKeyExists RETURN ROOTKEY SUBKEY
    Push $0
    
    ClearErrors
    EnumRegValue $0 ${ROOTKEY} "${SUBKEY}" 0
    IfErrors 0 +5
    EnumRegKey $0 ${ROOTKEY} "${SUBKEY}" 0
    IfErrors 0 +3
    StrCpy ${RETURN} 0
    Goto +2
    StrCpy ${RETURN} 1
    
    Pop $0
!macroend

# Example
${RegKeyExists} $R0  HKLM64 "SOFTWARE\Microsoft\WindowsSelfHost\UI\Visibility"

[MKN]

Ключи эти существуют только для 64бит приложений »

А в 32 битных их разве нет ?
И я вроде как "выудил" эти ключи из реестра, в том же виде, какими они и были в x64... Или в рег-плагине необходимо конкретно указывать на разрядность ОС ? (в доке этого не видел...) Вероятно забыл про SetRegView 64...
и как быть с репликой из ps ?

[iglezz]

MKN,
Да, в 32 битных их нет. Это легко увидеть, если открыть 32-битный %WINDIR%\SysWOW64\regedit.exe
Ключей WindowsSelfHost и Windows Defender там не будет.

Что до плагина, то он староват и не в курсе про реестр в x64.
"В крации", реестр в x64 состоит из трёх загончиков (общий, 32бит, 64 бит), и для доступа во чужой загончик надо использовать волшебное слово при использовании функций WinAPI. Плагин таким фокусам не обучен, add: но на него действует SetRegView 64

и как быть с репликой из ps ? »

это про что?

[MKN]

Что до плагина, то он староват и не в курсе про реестр в x64. »

Как же всё-таки определять подобные ключи в x64 ? Что то я туплю под вечер...

это про что? »

Это я про работу subinacl. Собственно от неё у меня всё и пляшет... Но закрадывается смутное сомнение , что и эта утилитка тоже устарела и с x64 ключами не дружит...

[iglezz]

Как же всё-таки определять подобные ключи в x64 ? »

Часть ключей задокументирована - Redirected, Shared, and Reflected Keys Under WOW
Для остального можно дёрнуть ключ отдельно в 32 и 64 бит режиме и сравнить выхлоп. Даже батничком на `reg query %REGPATH% /ve` можно реализовать.

Это я про работу subinacl. »

На замену subinacl вроде должен setacl подойти.

[MKN]

даже батничком на `reg query %REGPATH% /ve` можно реализовать »

Как то не эстетично для NSIS... А по иному разве нельзя ? (или хотя бы на "командной базе" сделать .nsh, для короткой строки детекта в скрипте... )

На замену subinacl вроде должен setacl подойти. »

Нужно получить данные о правах ключей... setacl не умеет, а subinacl похоже не умеет работать с x64 ключами... Засада...
Хотя AccessControl plug-in с большим трудом всё же упросил доработать, но нужный инфо-вывод в SDDL формате... Надо как то парсить-расшифровывать. Одна морока...

[iglezz]

MKN, Вот такой макрос получился

nsis RegKeyExists

Код:

# RETURN value:
#  0 : not exists
# >0 : exists
!define RegKeyExists '!insertmacro RegKeyExists'
!macro RegKeyExists RETURN ROOTKEY SUBKEY
    Push $0
    Push $1
    
    StrCpy $0 0
    
    SetRegView 32
    
    ClearErrors
    EnumRegKey $1 ${ROOTKEY} "${SUBKEY}" 0
    IfErrors +2
    IntOp $0 $0 + 1
    
    SetRegView lastused
    
    ${If} ${RunningX64} 
    SetRegView 64
    
    ClearErrors
    EnumRegKey $1 ${ROOTKEY} "${SUBKEY}" 0
    IfErrors +2
    IntOp $0 $0 + 1
    
    SetRegView lastused
    ${EndIf}
    
    Pop $1
    Exch $0
    Pop ${RETURN}
!macroend

Если есть необходимость знать точно, существует ключ для 32 или 64 бит процесса, то чуть сложнее будет

Внезапно оказалось, что SetRegView 64 благотворно влияет на плагин registry.

Код:

${registry::KeyExists} "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Defender\Scan" $1

возвращает 0, т.е. ключ найден

но нужный инфо-вывод в SDDL формате... Надо как то парсить-расшифровывать. »

С виду парсится должно без хлопот даже в nsis...

[MKN]

Внезапно оказалось, что SetRegView 64 благотворно влияет на плагин registry. »

Я это тоже осознал .

С виду парсится должно без хлопот »

Не подскажешь соотв. утилитку ком строки (если существует...) ?

ps А что делает SetRegView lastused, если популярно разъяснить ? Возвращает в исходное состояние чтение\запись из\в реестре ? Т.е. всё равно это эквивалентно записи SetRegView32(64) в нужном месте кода ?