[okshef]

А можно узнать цель? Вы потом собираетесь что-то дописывать после номера или номер будет относиться к тексту под ним?

[seman]

А можно узнать цель? Вы потом собираетесь что-то дописывать после номера или номер будет относиться к тексту под ним? »

У меня есть текстовый файл с субтитрами, он составлен некорректно, поэтому не отображаются во многих плеерах. В оригинальном шаблоне перед каждой строчкой установлена цифра - нумерация.
В ручную это делать нереально долго

[okshef]

На мой взгляд, самым простым способом будет включить отображение непечатных знаков, тогда будут видны абзацы. Затем встать на пустой абзац, применить к нему нумерацию, выделить этот абзац, а после этого выбрать "метелку" (копировать форматирование) двойным щелчком и применить ко всем пустым абзацам.
Вполне возможно, что для большого количества строк этот процесс можно автоматизировать макросом, но в этом я вам не помогу.

[Iska]

По-хорошему, надо поглядеть на этот файл:

Имеется файл с текстом »

[seman]

Вполне возможно, что для большого количества строк этот процесс можно автоматизировать макросом »

да, в ручную долго очень

По-хорошему, надо поглядеть на этот файл: »

[Iska]

На WSH:

Скрытый текст

Код:

Option Explicit

Dim strSourceFile

Dim objFSO
Dim strContent

Dim iCount


If WScript.Arguments.Count = 1 Then
	strSourceFile = WScript.Arguments.Item(0)
	
	Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
	
	If objFSO.FileExists(strSourceFile) Then
		If StrComp(objFSO.GetExtensionName(strSourceFile), "srt", vbTextCompare) = 0 Then
			With objFSO.OpenTextFile(strSourceFile)
				strContent = .ReadAll()
				.Close
			End With
			
			With WScript.CreateObject("VBScript.RegExp")
				.Pattern = "\n(\n\d{2}:\d{2}\.\d{3} --> \d{2}:\d{2}\.\d{3}\n)"
				
				If .Test(strContent) Then
					iCount = 0
					
					Do
						iCount = iCount + 1
						strContent = .Replace(strContent, vbLf & vbLf & CStr(iCount) & "$1")
					Loop While .Test(strContent)
					
					With objFSO.CreateTextFile(strSourceFile, True)
						.Write strContent
						.Close
					End With
				Else
					WScript.Echo "Not found pattern in text."
					WScript.Quit 4
				End if
			End With
		Else
			WScript.Echo "Need .srt file."
			WScript.Quit 3
		End If
	Else
		WScript.Echo "Can't find source file [" & strSourceFile & "]."
		WScript.Quit 2
	End If
	
	Set objFSO = Nothing
Else
	WScript.Echo "Usage: cscript.exe //nologo """ & WScript.ScriptName & """ <Source file>"
	WScript.Quit 1
End If

WScript.Quit 0

Путь к исходному файлу задаётся параметром скрипта (также можно просто перетянуть .srt файл на скрипт в Проводнике).

[seman]

Путь к исходному файлу задаётся параметром скрипта (также можно просто перетянуть .srt файл на скрипт в Проводнике) »

Спасибо, у меня с программированием плохо, мне нужно сохранить этот текст в блокноте?

[Iska]

seman, сохраните приведённый код в файл с расширением .vbs. Затем используйте:

также можно просто перетянуть .srt файл на скрипт в Проводнике »