CMD/BAT - [решено] Удалить у всех файлов в папке первые 4 символа в имени

mwz · Отправлено: **22:05, 06-04-2019** | #2

habib2302, тут где-то рядышком сегодня один уже удаляли...

habib2302 · Конфигурация компьютера

mwz, скорей всего это http://forum.oszone.net/thread-335923.html

mwz · Отправлено: **22:13, 06-04-2019** | #4

habib2302, ну и замените количество хоть на два (как у вас в тексте), хоть на четыре (как у вас в заголовке темы).

habib2302 · Конфигурация компьютера

mwz, пробовал. не работает. Ошибка в синтаксисе команды.

Код:

@echo off 
setlocal enabledelayedexpansion 
for %%i in ( *.* ) do ( 
set "name=%%~ni" 
set "name=!name:~4!" 
rename "%%~i" !name!%%~xi 
echo !name!%%~xi 
) 
pause

alpap · Конфигурация компьютера

habib2302,
когда копипастите откуда-то следите за пробелами в конце строк - очень распространенная ~~ошибка~~ причина и имя файла и путь когда в переменной надо обязательно брать в парные кавычки

Код:

@echo off
setlocal enabledelayedexpansion

for %%i in (*.*) do (
 set "name=%%~ni"
 set "name=!name:~4!"
 ren "%%~i" "!name!%%~xi"
)
pause

Iska · Отправлено: **23:03, 06-04-2019** | #7

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for %%i in (*.*) do (
	set "name=%%~ni"
	rename "%%~i" "!name:~4!%%~xi"
) 

endlocal
exit /b 0

habib2302, в любом случае — делать rename файлов внутри цикла перебора тех же самых файлов по for — не есть правильно. Делайте разбор по for /f для команды dir /b — и вот тогда смело переименовывайте: сначала выполнится dir /b, и только потом произойдёт первое переименование.

Update: припоздал.

mwz · Отправлено: **23:04, 06-04-2019** | #8

Цитата habib2302:

Ошибка в синтаксисе команды »

На время отладки строку @echo off надо убирать. И смотреть, где ошибка (ошибки).
Да, и у вас заодно от имени батника отрежутся символы.

Кстати... А что вы будете делать, если получите одинаковые имена переименованных файлов?

megaloman · Отправлено: **15:37, 08-04-2019** | #9

habib2302,

Цитата Жванецкий (?):

Одно неверное движение, и ты отец ...

ИМХО, указывать имена файлов *.* опрометчиво. При повторном возможно случайном запуске батника тупо повторно отрежутся символы. Подозреваю, можно указать маску, чтобы повторно файлы не обрабатывались.

Цитата mwz:

Да, и у вас заодно от имени батника отрежутся символы. »

ИМХО, скверная политика запускать батник из той же папки, где обрабатываемые файлы. Поэтому, для обрабатываемых файлов лучше указывать полный путь с маской, и, (но это не нужно, если не располагать батник вместе с файлами) можно приделать батнику атрибут "скрытый".
До кучи (число отрезаемых символов тоже задаётся, а то завтра кто-то захочет отрезать 2 или 5 символов)

Код:

@Echo Off
	Set "FileIn=Z:\Box_In\я*.txt"
	Set /A N=4

	Attrib +H "%~dpnx0"
	FOR %%i IN ("%FileIn%") DO (Set "NN=%%~ni" &Call Ren "%%i" "%%NN:~%N%%%%%~xi")
Exit /B 0

Или, как вариант, перед обрезанием контролировать длину, чтобы не отрезать повторно: возможно, обрабатываемые файлы имеют некое стандартное по длине имя. Или всё-таки на каждое переименование организовать запрос. Но это слегка другая песТня, излагайте!

megaloman · Отправлено: **16:32, 08-04-2019** | #10

Цитата Iska:

в любом случае — делать rename файлов внутри цикла перебора тех же самых файлов по for — не есть правильно »

Вы, наверное, правы

Код:

@Echo Off
	Set "FileIn=Z:\Box_In\я*.txt"
	Set /A N=4
	
	>"%~dpn0.tmp%~x0" (FOR %%i IN ("%FileIn%") DO (
		Set "NN=%%~ni"
		Call Echo Ren "%%i" "%%NN:~%N%%%%%~xi"
	))
	Attrib +H "%~dpnx0"
	Attrib +H "%~dpn0.tmp%~x0"
	Call "%~dpn0.tmp%~x0"
	Attrib -H "%~dpnx0"
	Attrib -H "%~dpn0.tmp%~x0"
	Del "%~dpn0.tmp%~x0"
Exit /B 0