CMD/BAT - CMD-шник с внешним конфиг-файлом

Профиль · Отправлено: **00:03, 30-01-2019** | #21

Вот что дали (захвачу соседний код, чтобы нагляднее было):

Код:

:: Перемещение папок и\или файлов
cls
xcopy %AutoUpdateMoveFoldersAndFiles% /e /y /c /i
rd /s /q %AutoUpdateMoveFoldersAndFilesForDelete%

:: Читаем конфиг-файл и тут же пишем его вызывая из write_autoupdate_config, так, вроде?
<"%AutoUpdateConfig%" (for /f "delims=" %%a in ('more') do @set "%%a"& call :write_autoupdate_config "%%a")
>nul move $ "%AutoUpdateConfig%"
goto autoupdate_end

:: Пишем изменившиеся значения
:write_autoupdate_config
 >>$ (<nul set /p="%~1"|>nul find "UpdateInstalled=" && (
   echo %UpdateInstalled%|>nul find "true" && (echo UpdateInstalled=false& echo:)
  ) || (
   echo %~1& echo:
  )
 )
exit /b

:autoupdate_end
color f2
@echo.
@echo  ╔══════════════════════════════════════════╗
@echo  ║ Панель управления Silver Raven mods pack ║
@echo  ║             РЕЖИМ ОБНОВЛЕНИЯ             ║
@echo  ╚══════════════════════════════════════════╝
@echo.
@echo.
@echo ■ Операции с файлами сборки успешно завершены.
@echo.
@echo.
@echo Для корректной работы сборки, рекомендуется заново скопировать отсортированный список загрузки модов и файлы настроек игры. Если у вас уже установлены какие-либо дополнительные плагины, потребуется провести их повторную сортировку вручную.
@echo.
@echo.
pause
goto main_menu

Только не могу понять что в данном случае делют символы: < и >, >>. Ну и не очень нравиться прыжки туда сюда через goto и exit. Я бы в один код все засунул. Мне так удобнее.

Anonymоus, я придержу ваш вариант на будущее, прикрутить то не проблема. Просто пока вышло, что его функционал избыточен. У меня и так уже 3676 строк. Читать эту портянку то еще занятие. Ну сам виноват, надо было остановиться, пока стало не поздно...

alpap · Конфигурация компьютера

Цитата Stalker_AleX333:

что в данном случае делют символы: < и >, >> »

<"%AutoUpdateConfig%" - чтение из файла (в переменной), равносильно: for /f "usebackq delims=" %%a in ("%AutoUpdateConfig%") do ...

Цитата Stalker_AleX333:

>>$ »

- запись во временный файл $ с дозаписью, поэтому >>, равносильно: echo stroka>>$

Цитата Stalker_AleX333:

не очень нравиться прыжки туда сюда через goto и exit »

ну это как кому, если правильно и наглядно организовано, то гораздо лучше наваленных строк

Цитата Stalker_AleX333:

Я бы в один код все засунул »

это надо пояснить, код в данном случае один, что имелось ввиду?

Цитата Stalker_AleX333:

У меня и так уже 3676 строк »

вот поэтому и удобнее подпрограммы с наглядными переходами, а еще можно практиковать такой вариант. Выделяете папку под задачу и складываете в нее отдельные bat файлы с осмысленными названиями, а в коде основного bat обращаетесь по call не к подпрограмме, а к одному из bat в папке, выглядит примерно так:

Скрытый текст

Основной.bat

Код:

@echo off
:: Код
:: Обращение к одному из Вспомогательных1.bat
call "Вспомогательный1.bat" "параметр1" "параметр2" ...
:: Вернулись из "Вспомогательного1.bat" с какими-то результатами (новыми переменными)
:: Код
:: Обращение к одному из Вспомогательных2.bat
call "Вспомогательный2.bat" "параметр1" "параметр2" ...
:: Вернулись из "Вспомогательного2.bat" с какими-то результатами (новыми переменными)
:: Код
exit

Вспомогательный1.bat (и также другие)

Код:

@echo off
:: Код (Какие-то новые переменные)
:: Заканчивать Вспомогательные.bat обязательно по exit /b (exit /b 0 или 1 ...)
exit /b

Iska · Отправлено: **03:36, 30-01-2019** | #23

Цитата Stalker_AleX333:

Ну и не очень нравиться прыжки туда сюда через goto и exit. »

Не существует «прыжков через goto и exit». Либо goto-goto (простые переходы), либо call-exit /b (вызов квазипроцедуры). А goto и exit несовместимы в принципе. И в коде коллеги megaloman их нет. Есть пара именно квазипроцедур с вызовом по call и возвратом по exit /b, и один goto :eof.

Цитата Stalker_AleX333:

У меня и так уже 3676 строк. Читать эту портянку то еще занятие. »

Вот для того и разбивают код на части и организуют те самые процедуры. Или, возможно, у кого-то просто неудачно выбранный редактор

. У меня такой:

Скрытый текст

В нём всё замечательно видно, будь то хоть 1000 строк, хоть 10000 строк.

alpap · Конфигурация компьютера

Цитата Iska:

всё замечательно видно »

в AkeiPad тоже вполне так:

Скрытый текст

Файл 156280

Профиль · Отправлено: **18:39, 30-01-2019** | #25

Я вот что-то сломал и не пойму что, но оно теперь не работает:

Код:

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Проверка доступности файлов панели управления
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

set "HDSoundsPackagesConfigBackup=Silver Raven mods pack data\hd_sounds_packages_backup.cfg"
set "ControlPanelFilesListConfig=Silver Raven mods pack data\fileslist.cfg"
set "ControlPanelFilesListMissingFiles="

:: Проверяем наличие конфиг-файла hd_sounds_packages_backup.cfg от прошлой установки и устанавливаем его как основной
if exist "%HDSoundsPackagesConfigBackup%" (
del /f /q "Silver Raven mods pack data\hd_sounds_packages.cfg"
ren "%HDSoundsPackagesConfigBackup%" hd_sounds_packages.cfg
)

if not exist "%ControlPanelFilesListConfig%" (
cls
color fc
echo.
echo ╔══════════════════════════════════════════╗
echo ║ Панель управления Silver Raven mods pack ║
echo ╚══════════════════════════════════════════╝
echo.
echo.
echo *ОШИБКА! Файл конфигурации fileslist.cfg, необходимый для корректной работы программы, не найден.
echo Извлеките его из установочных архивов со сборкой в папку Silver Raven mods pack data вручную и перезапустите панель управления. Убедитесь, что антивирусное ПО не блокирует ее работу.
echo.
echo.
pause
exit
)

:: Чтение конфиг-файла fileslist.cfg
setlocal EnableDelayedExpansion
for /f "tokens=1,2* delims==" %%A in ("%ControlPanelFilesListConfig%") do set "$%%A=%%B"

:: Проверка наличия всех файлов для панели управления в Silver Raven mods pack data
for %%? in (%$ControlPanelFilesListConfig%) do (
if not exist "%%~?" set ControlPanelFilesListMissingFiles=!ControlPanelFilesListMissingFiles!, "%%~?"
)
setlocal DisableDelayedExpansion

if defined ControlPanelFilesListMissingFiles (
color fc
echo.
echo ╔══════════════════════════════════════════╗
echo ║ Панель управления Silver Raven mods pack ║
echo ╚══════════════════════════════════════════╝
echo.
echo.
echo *ОШИБКА! Следующие файлы, необходимые для корректной работы программы, не найдены:
echo.
echo.
for %%A in (%ControlPanelFilesListMissingFiles%) do echo %%~A
echo.
echo.
echo Извлеките папку Silver Raven mods pack data из установочных архивов со сборкой в папку игры вручную и перезапустите панель управления. Убедитесь, что антивирусное ПО не блокирует ее работу.
echo.
echo.
pause
exit
)

А вообще, не представляю, как все оттестировать (не на ~~кошках~~ юзерах). Есть кто скучающий, упертый, перфикционист? Я отправил бы весь код в личку. Там наверняка можно многое улучшить.
И надо было о переменных подумать заранее. В разных модулях, порой приходится объявлять одни и те же.

Цитата alpap:

вот поэтому и удобнее подпрограммы с наглядными переходами »

Да кто ж спорит то, конечно удобнее. Но напоминаю, у меня это компилируется в exe-шник. Не плодить же, сгенерированные им cmd-шники в подпапках.

Цитата alpap:

это надо пояснить, код в данном случае один, что имелось ввиду? »

В первом куске, мы читаем конфиг-файл, затем через call переходим во второй и там уже пишем. Вот это все я хотел объединить, без переходов.

Цитата Iska:

Или, возможно, у кого-то просто неудачно выбранный редактор»

Notepad++ наше фсе!11 (правда я не пользуюсь темными темами оформления, как большинство, не привык. может, многое теряю)

Iska · Отправлено: **19:13, 30-01-2019** | #26

Цитата alpap:

в AkeiPad тоже вполне так: »

Хе-хе. Теперь я понял, почему заключают set'ы в кавычки

— там лишние пробелы в конце строк. И я бы ещё задал в настройках длину tab'ам не в 8 пробелов, а в 4.

Цитата Stalker_AleX333:

Notepad++ наше фсе!11 »

Не в том дело. Я гляжу, что Вы вложенными отступами для наглядности фактически не пользуетесь.

Цитата Stalker_AleX333:

И надо было о переменных подумать заранее. В разных модулях, порой приходится объявлять одни и те же. »

Ну и хрен с ним — setlocal/endlocal-то на что нам даны?!

Профиль · Отправлено: **20:53, 30-01-2019** | #27

Цитата Iska:

Я гляжу, что Вы вложенными отступами для наглядности фактически не пользуетесь. »

Да как то не приучился.

Цитата Iska:

Ну и хрен с ним — setlocal/endlocal-то на что нам даны?! »

А с ними не пашет вывод символов, вроде * : !
Хотя, я где-то читал, что ! можно забить так: ^^^!

А так, я давно бы перенес все переменные в шапку cmd-шника. И объем кода заметно уменьшился.

Iska · Отправлено: **21:06, 30-01-2019** | #28

Цитата Stalker_AleX333:

А с ними не пашет вывод символов, вроде * : ! »

Да ладно. На обработку символа ! влияет параметр enabledelayedexpansion, но никак не сама команда setlocal.

Профиль · Отправлено: **21:26, 30-01-2019** | #29

Цитата Iska:

Да ладно. На обработку символа ! влияет параметр enabledelayedexpansion, но никак не сама команда setlocal. »

Ну значит у меня уже крыша потихоньку едет, от этого всего.

И кстати, без PowerShell-а создать ярлык с атрибутами и указанным путем к отображаемой иконке возможно?

megaloman · Отправлено: **22:00, 30-01-2019** | #30

Stalker_AleX333, Попробуйте сначала так:

Код:

@Echo Off
cls
	Set "A=Main"
	Echo %A%
	Call :Kuku
	Echo %A%
Pause
Exit /B

:Kuku
	Set "A=kuku"
	Echo %A%
Exit /B

Потом вот так

Код:

@Echo Off
cls
	Set "A=Main"
	Echo %A%
	Call :Kuku
	Echo %A%
Pause
Exit /B

:Kuku
SetLocal
	Set "A=kuku"
	Echo %A%
EndLocal
Exit /B

Пара SetLocal - EndLocal позволяет "экранироваить" область видимости переменных. Переменные с одинаковыми именами в одной части программы не будут изменяться в другой части, то есть, внутри подпрограммы Вы можете объявлять переменные без боязни их переопределить в других частях программы.
Если у Вас длинный код, для читаемости и удобства написания можно оформить отдельные функционально обусловленные куски в виде процедур, при необходимости применяя SetLocal - EndLocal
А переменные в знаках ! - это уже другая песТня