[deluxe9999]

Копирование за сегодня с удалением исходных файлов Код: @Echo Off cls Set "BoxIn=Z:\Box_In\VLR" Set "BoxArc=Z:\Box_Arc" Set "ArcName=VLR_" FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d" Set "Tdate=%Tdate:~0,8%" Set "DXcopy=%TDate:~4,2%-%TDate:~6,2%-%TDate:~0,4%" Pushd "%BoxIn%" FOR /F "usebackq tokens=1,2 delims=>" %%i In (`xcopy /S /I /Y /F /D:%DXcopy% *.* "%BoxArc%\%ArcName%%TDate%"`) DO Call :DelCopy "%%i" "%%j" Popd GoTo :Eof :DelCopy If "%~2"=="" GoTo :Eof Set "File1=%~1" Set "File1=%File1:~0,-2%" Set "File2=%~2" Set "File2=%File2:~1,9999%" If Exist "%File2%" Del "%File1%" GoTo :Eof Пустые папки не рискнул удалять, не зная задачи подробно »

Ссори не совсем получается когда указываю сетевой путь


\\172.28.246.10\d$\VLROutPut\* --> сетевой путь откуда брать
D:\Stat\VLR_ --> папка для хранения

насчёт удалении можно все что находится в той папке удалять.

[megaloman]

\\172.28.246.10\d$\VLROutPut\* »

так делать низьзя!
Можно

Код:

Set "BoxIn=\\172.28.246.10\d$\VLROutPut"
Set "BoxArc=D:\Stat\VLR_"

в имени папки подстановочных знаков быть не может
Подозреваю, что не надо указывать подпапку, которую я выделил в Вашем пути красным цветом.
Она указывается в

Код:

Set "ArcName=VLR_"

К VLR_ добавляется дата.

[deluxe9999]

Код: Set "BoxIn=\\172.28.246.10\d$\VLROutPut" Set "BoxArc=D:\Stat\VLR_" в имени папки подстановочных знаков быть не может Подозреваю, что не надо указывать подпапку, которую я выделил в Вашем пути красным цветом. Она указывается в »

Заработало спасибо!
Немного еще Вас побеспокою.
Если путей будет 2 или 3 есть возможность в скрипте сгруппировать, а не по отдельности вписывать скрипт каждому пути?
И как по возможности запаковать каждый в отдельный архив?
Возможно в скрипте чуток я почудил ))

Код: Set "BoxIn1=\\172.28.246.10\d$\VLROutPut" Set "BoxIn2=\\172.28.246.210\d$\VLROutPut" Set "BoxArc=D:\Stat" Set "ArcName=VLR_" Set Rar="C:\Program Files (x86)\WinRAR\WinRAR.exe" a -r -df FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d" Set "Tdate=%Tdate:~0,8%" Set "DXcopy=%TDate:~4,2%-%TDate:~6,2%-%TDate:~0,4%" Pushd "%BoxIn1%" FOR /F "usebackq tokens=1,2 delims=>" %%i In (`xcopy /S /I /Y /F /D:%DXcopy% *.* "%BoxArc%\%ArcName%%TDate%"`) DO Call :DelCopy "%%i" "%%j" Popd Pushd "%BoxIn2%" FOR /F "usebackq tokens=1,2 delims=>" %%i In (`xcopy /S /I /Y /F /D:%DXcopy% *.* "%BoxArc%\%ArcName%%TDate%"`) DO Call :DelCopy "%%i" "%%j" Popd

[megaloman]

Если путей будет 2 или 3 есть возможность в скрипте сгруппировать, а не по отдельности вписывать скрипт каждому пути?
И как по возможности запаковать каждый в отдельный архив?

Код:

@Echo Off
cls

Set "Arc=%ProgramFiles%\WinRar\WinRar.exe"
If Exist "C:\Program Files (x86)\WinRAR\WinRAR.exe" Set "Arc=C:\Program Files (x86)\WinRAR\WinRAR.exe"

FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d"
Set "Tdate=%Tdate:~0,8%"

Call :Archives "Z:\172.28.246.10\d$\VLROutPut" "Z:\Stat" "VLR_172.28.246.10_"
Call :Archives "Z:\172.28.246.210\d$\VLROutPut" "Z:\Stat" "VLR_172.28.246.210_"

GoTo :Eof

:Archives
	"%Arc%" a -r -m1 -df -Y -ed -ta%Tdate%000000 -ag%Tdate% "%~2\%~3.rar" "%~1\*.*"
GoTo :Eof

Если без архивирования и с удалением пустых папок, то

Код:

@Echo Off
cls

FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d"
Set "Tdate=%Tdate:~0,8%"
Set "DXcopy=%TDate:~4,2%-%TDate:~6,2%-%TDate:~0,4%"

Call :Archives "Z:\172.28.246.10\d$\VLROutPut" "Z:\Stat" "VLR_172.28.246.10_"
Call :Archives "Z:\172.28.246.210\d$\VLROutPut" "Z:\Stat" "VLR_172.28.246.210_"

GoTo :Eof

:Archives
	Pushd %1
	FOR /F "usebackq tokens=1,2 delims=>" %%i In (`xcopy /S /I /Y /F /D:%DXcopy% *.* "%~2\%~3%TDate%"`) DO Call :DelCopy "%%i" "%%j"
	For /F "Tokens=*" %%i In ('Dir /B /S /A:D 2^>nul^|Sort /R') Do RD "%%i" 2>nul
	Popd 
GoTo :Eof

:DelCopy
	If "%~2"=="" GoTo :Eof
	Set "File1=%~1" 
	Set "File1=%File1:~0,-2%"
	Set "File2=%~2" 
	Set "File2=%File2:~1,9999%"
	If Exist "%File2%" Del "%File1%"
GoTo :Eof

[deluxe9999]

Если путей будет 2 или 3 есть возможность в скрипте сгруппировать, а не по отдельности вписывать скрипт каждому пути? И как по возможности запаковать каждый в отдельный архив? »

Спасибо огромное! Сработало.