CMD/BAT - CMD Перемещение каталогов с длинными именами.

Elven · Отправлено: **15:32, 11-01-2018** | #2

Код:

robocopy /?

deluxe9999 · Отправлено: **15:42, 18-01-2018** | #3

Цитата Elven:

Код:
robocopy /? »

Если не будет вам сложно, можно чуток по подробнее для новичка по CMD так как у robocopy много функций, затеряться можно?

megaloman · Отправлено: **16:18, 18-01-2018** | #4

,deluxe9999,

Цитата deluxe9999:

Нужно чтобы один компьютер перемещал ежедневные генерированные папки с определенным именем с сервера на свою директорию. »

Зачем это нужно, для хранения или для текущей работы?

Цитата deluxe9999:

сервер каждый день генерирует папку с файлами (Info_User data_2018-1-9-8-2-17_ImmdTask12-Compressed) »

Что обозначают цифры в имени папки?

Цитата deluxe9999:

перемещал ежедневные генерированные папки с определенным именем с сервера на свою директорию. »

Что Вы имеете ввиду под определённым?
И, кстати,

Цитата deluxe9999:

При копирование с XCOPY копируется все данные включая и старые папки сгенерированные в прошлые дни. »

У xcopy есть ключ /d, который позволяет пропустить копирование старых файлов, но при этом необходимо копировать файлы в одну и ту же папку, либо явно указывать дату

Цитата:

/D:m-d-y - Копирование файлов, измененных не ранее указанной даты. Если дата не указана, заменяются только конечные файлы, более старые, чем исходные.

deluxe9999 · Отправлено: **15:28, 19-01-2018** | #5

Цитата megaloman:

Зачем это нужно, для хранения или для текущей работы?
Цитата deluxe9999: »

Добрый день!
Нужны для хранения данных.

а) Цифры в папках это даты которое при ежедневном генерации данных сервер создает.
б) Под определённым имею ввиду то, что сервер создает папки с лишними информация ми, нужно после перемещения примерно называлась "papka_%data%"

megaloman · Отправлено: **15:57, 19-01-2018** | #6

Цитата deluxe9999:

Нужны для хранения данных. »

Почему бы не использовать архиватор? Существенная экономия места даже при низком уровне сжатия.

Цитата deluxe9999:

Цифры в папках это даты которое при ежедневном генерации данных сервер создает. »

Сегодня 19.01.2018. Как называется папка которую надо архивировать?

deluxe9999 · Отправлено: **16:03, 19-01-2018** | #7

Цитата megaloman:

Нужны для хранения данных. »
Почему бы не использовать архиватор? Существенная экономия места даже при низком уровне сжатия. »

Было бы круто с архивированием папку под именем %VLR_дата%.

deluxe9999 · Отправлено: **16:12, 19-01-2018** | #8

папка под именем VLR

megaloman · Отправлено: **17:25, 19-01-2018** | #9

deluxe9999

Архиватор RAR

Код:

@Echo Off
cls

Set "BoxIn=Z:\Box_In\VLR"
Set "BoxArc=Z:\Box_Arc"
Set "ArcName=VLR_"
Set "Arc=%ProgramFiles%\WinRar\WinRar.exe"

FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d"
Set "Tdate=%Tdate:~0,8%"

"%Arc%" a -r -m1 -df -ta%Tdate%000000 -ag%Tdate% "%BoxArc%\%ArcName%" "%BoxIn%\*.*"

Вы не расшифровали имя папки

Цитата deluxe9999:

сервер каждый день генерирует папку с файлами (Info_User data_2018-1-9-8-2-17_ImmdTask12-Compressed) »

На мои непристойные домогательства Вы ответили

Цитата deluxe9999:

папка под именем VLR »

Вам бы

Цитата deluxe9999:

Хотелось бы чтобы перемещались папки а не копировались »

В моём скрипте применяю архиватор Rar. За удаление архивированных файлов отвечает выделенный ключ -df, если этого не нужно, удалите этот ключ.
Укажите свои пути к архивируемой папке, архивной папке и путь к архиватору, если он отличается от стандартного.
Скрипт архивирует в указанной папке все файлы за сегодня, заархивированные файлы удаляются (если Вы не передумаете).
Имя архива имеет вид VLR_ГГГГММДД

XCopy

Просто копирование за сегодня

Код:

@Echo Off
cls

Set "BoxIn=Z:\Box_In\VLR"
Set "BoxArc=Z:\Box_Arc"
Set "ArcName=VLR_"

FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d"
Set "Tdate=%Tdate:~0,8%"
Set "DXcopy=%TDate:~4,2%-%TDate:~6,2%-%TDate:~0,4%"

Pushd "%BoxIn%"
Xcopy /S /I /Y /F /D:%DXcopy% *.* "%BoxArc%\%ArcName%%TDate%"
Popd

Копирование за сегодня с удалением исходных файлов

Код:

@Echo Off
cls

Set "BoxIn=Z:\Box_In\VLR"
Set "BoxArc=Z:\Box_Arc"
Set "ArcName=VLR_"

FOR /F "tokens=2 delims==." %%d in ('WMIC OS GET LOCALDATETIME /VALUE') DO SET "Tdate=%%d"
Set "Tdate=%Tdate:~0,8%"
Set "DXcopy=%TDate:~4,2%-%TDate:~6,2%-%TDate:~0,4%"

Pushd "%BoxIn%"

FOR /F "usebackq tokens=1,2 delims=>" %%i In (`xcopy /S /I /Y /F /D:%DXcopy% *.* "%BoxArc%\%ArcName%%TDate%"`) DO Call :DelCopy "%%i" "%%j"

Popd 
GoTo :Eof

:DelCopy
	If "%~2"=="" GoTo :Eof
	Set "File1=%~1" 
	Set "File1=%File1:~0,-2%"
	Set "File2=%~2" 
	Set "File2=%File2:~1,9999%"
	If Exist "%File2%" Del "%File1%"
GoTo :Eof

Пустые папки не рискнул удалять, не зная задачи подробно

deluxe9999 · Отправлено: **08:40, 22-01-2018** | #10

Спасибо большое за Ваш отклик. Так как суббота и воскресенье не рабочий день. Попробую сегодня и дам Вам свой результат.