[Iska]

В CMD есть риск непредсказуемого поведения команды с маской. »

Везде есть . Поскольку везде используются одни и те же функции WinAPI.

СтОит ли игра свеч? »

Коль это будет более правильно — конечно, стоит. «Более громоздко» — ну, добавится несколько строк для регулярки, например:

Скрытый текст

Код:

Option Explicit

Dim objFSO

Dim objFolder

Dim strSourceFolder

Dim objRegExp


Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")

Set objFolder = WScript.CreateObject("Shell.Application").NameSpace("shell:Local AppData")

If Not objFolder Is Nothing Then
	strSourceFolder = objFSO.BuildPath(objFolder.self.Path, "1C\1cv8")
	
	If objFSO.FolderExists(strSourceFolder) Then
		With WScript.CreateObject("VBScript.RegExp")
			.IgnoreCase = True
			.Pattern = "^[0-9a-f]{8}(?:-[0-9a-f]{4}){4}[0-9a-f]{8}$"
			
			For Each objFolder In objFSO.GetFolder(strSourceFolder).SubFolders
				If .Test(objFolder.Name) Then
					objFolder.Delete True
				End If
			Next
		End With
	Else
		WScript.Echo "Can't find source folder [" & strSourceFolder & "]."
		WScript.Quit 2
	End If
Else
	WScript.Echo "Can't connect to Local AppData folder."
	WScript.Quit 1
End If

Set objFSO = Nothing

WScript.Quit 0

...а буквенные представления 16-ричных значений, т.е. шесть букв: от A до F. »

Именно так. Поскольку название — явно одно из представлений UUID — Википедия.

Спрогнозировать иные выверты работы команд CMD с маской не берусь, сталкивался с ними не раз, для меня это непредсказуемо, хотя когда-то на форуме объяснение звучало »

Коварные короткие имена, особенно для имён, не входящих в A-Z.

[megaloman]

Мой vbs-скрипт с регулярными выражениями и настройками на вид имени

Код:

Plan = Array(8, 4, 4, 4, 12)        ' Число символов в каждой части имени
Delim = "-"                         ' Разделитель
Mask = "[0-9a-z]"                   ' Маска допустимых символов в имени

Set WShell = CreateObject("WScript.Shell")
BoxIn = WShell.ExpandEnvironmentStrings("%LocalAppData%") + "\1C\1cv8"

Set FSO = CreateObject("Scripting.FileSystemObject")

On Error Resume Next
Set InBox = FSO.GetFolder(BoxIn)
If Err.Number <> 0 Then
    MsgBox "Папка" + vbCrLf + vbCrLf + BoxIn + vbCrLf + vbCrLf + Err.Description
    On Error GoTo 0
Else
    On Error GoTo 0
    N1 = LBound(Plan)
    N2 = UBound(Plan)
    NLen = 0
    
    For i = N1 To N2
        InMask = InMask + Mask + "{" + CStr(Plan(i)) + "}"
        NLen = NLen + Plan(i)
        If i <> N2 Then
            InMask = InMask + Delim
            NLen = NLen + 1
        End If
    Next

    Set RegMaska = New RegExp
    RegMaska.Pattern = InMask
    RegMaska.IgnoreCase = True

    Set AllFolders = InBox.SubFolders
    For Each Folder In AllFolders
        NameFolder = Folder.Name
        If NLen = Len(NameFolder) Then
            If RegMaska.Test(NameFolder) Then
                On Error Resume Next
                LL = FSO.DeleteFolder(BoxIn + "\" + NameFolder, True)
                If Err.Number <> 0 Then
                    MsgBox "Папка" + vbCrLf + vbCrLf + BoxIn + "\" + NameFolder + vbCrLf + vbCrLf + Err.Description
                End If
                On Error GoTo 0
'                MsgBox Folder.Name
            End If
        End If
    Next
End If

Если в самом деле в имени папок только шестнадцатиричные числа, то маску нужно указать как
"[0-9a-f]"

[mwz]

Mask = "[0-9a-z]" »

Для данного случая, как вы и сказали в конце, a-f
Вариант заглавных букв (A-F) не учитывается? Я бы учёл на всякий случай.

[Iska]

Вариант заглавных букв (A-F) не учитывается? Я бы учёл на всякий случай. »

Учитывается:

RegMaska.IgnoreCase = True »