[Busla]

dreamzed, ? в маске обозначает один любой символ:

Код:

dir C:\Users\ПОЛЬЗОВАТЕЛЬ\AppData\Local\1C\1cv8\????????-????-????-????-????????????

[Iska]

Тут бы хорошо смотрелось такое:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=%LocalAppData%\1C\1cv8

set sTemplate=[0-9a-f]
set sTemplate4=%sTemplate%%sTemplate%%sTemplate%%sTemplate%
set sTemplate8=%sTemplate4%%sTemplate4%
set sTemplate12=%sTemplate4%%sTemplate4%%sTemplate4%

if exist "%sSourceFolder%\." (
	pushd "%sSourceFolder%" && (
		for /f "usebackq delims=" %%i in (`2^>nul dir /b /a:d "????????-????-????-????-????????????" ^| findstr.exe /r /i /x /c:"%sTemplate8%-%sTemplate4%-%sTemplate4%-%sTemplate4%-%sTemplate12%"`) do echo rd /s /q "%%~i"
		popd
	)
) else (
	echo Can't find source folder [%sSourceFolder%].
	exit /b 1
)

endlocal
exit /b 0

но, к сожалению, как не крути — шаблон получается на шесть символов длиннее, нежели допустимо для findstr.exe. И это под новыми ОС! Для XP и ниже в плане ограничений всё ещё хуже.

Посему, либо с некоторым низким риском удаления лишнего:

Скрытый текст

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=%LocalAppData%\1C\1cv8

if exist "%sSourceFolder%\." (
	pushd "%sSourceFolder%" && (
		for /f "usebackq delims=" %%i in (`2^>nul dir /b /a:d "????????-????-????-????-????????????"`) do echo rd /s /q "%%~i"
		popd
	)
) else (
	echo Can't find source folder [%sSourceFolder%].
	exit /b 1
)

endlocal
exit /b 0

(для реального удаления убрать выделенное echo), либо WSH/PoSH, где нет таких ограничений.

любые цифры и буквы без спецсимволов и пробелов." »

Судя по внешнему виду — никак не «любые буквы».

[megaloman]

В CMD есть риск непредсказуемого поведения команды с маской.

Вот vbs-скрипт, где задача решена средствами WSH

Код:

Set WShell = CreateObject("WScript.Shell")
WhereDir = WShell.ExpandEnvironmentStrings("%LocalAppData%") + "\1C\1cv8"

Set FSO = CreateObject("Scripting.FileSystemObject")
If Not FSO.FolderExists(WhereDir) Then
    MsgBox "Нет папки" + vbCrLf + vbCrLf + WhereDir
Else
    On Error Resume Next
    LL = FSO.DeleteFolder(WhereDir + "\????????-????-????-????-????????????", True)
    On Error GoTo 0
End If

Здесь под ? тоже понимается любой символ. Можно, конечно, задействовать регулярные выражения, но это получится более громоздко. СтОит ли игра свеч?

[mwz]

Судя по внешнему виду — никак не «любые буквы». »

dreamzed, ...а буквенные представления 16-ричных значений, т.е. шесть букв: от A до F.

[Busla]

В CMD есть риск непредсказуемого поведения команды с маской. »

Почему?
в CMD маски ведут себя эталонно - их там придумали, если в VBS поведение отличается - это как раз вызывает недоумение.

[dreamzed]

#4
у меня сейчас тестовая папка находится по такому пути- D:\1c\1c8
подскажите пожалуйста,что поменять в вашем коде.чтобы он заработал.
Ещё раз прошу прощение за нубизм, первый раз в жизни со скриптами столкнулся)

[megaloman]

Тут бы хорошо смотрелось .... но, к сожалению ...»

Нормальные герои всегда идут в обход

Вот CMD с регулярным выражением.

Код:

@Echo Off
Set "BoxIn=%LocalAppData%\1C\1cv8"

for /f "usebackq delims=" %%i in (`2^>nul dir /b /a:d "%BoxIn%\????????-????-????-????-?????????????"`) Do Call :DelDir "%%i"
GoTo :Eof

:DelDir
	Set "DirName=%~1"
	If "%DirName:~35,1%"=="" GoTo :Eof

	Set "Delim=%DirName:~8,1%%DirName:~13,1%%DirName:~18,1%%DirName:~23,1%%DirName:~36,1%
	If Not "%Delim%"=="----" GoTo :Eof

	Set "Symb=%DirName:~0,8%%DirName:~9,4%%DirName:~14,4%%DirName:~19,4%%DirName:~24,12%
	Echo %Symb%| Findstr.exe /R /I "[^0-9a-z]" >nul|| RD /S /Q "%BoxIn%\%~1"
GoTo :Eof

rem           1         2         3
rem 012345678901234567890123456789012345
rem 73c58a87-39c7-4571-b760-5a70505b271f
rem 12345678 1234 1234 1234 123456789012

у меня сейчас тестовая папка находится по такому пути- D:\1c\1c8 »

Напишите Set "BoxIn=D:\1c\1c8"
В vbs-скрипте WhereDir = "D:\1C\1cv8"

[megaloman]

Busla,

в CMD маски ведут себя эталонно - их там придумали »

ИМХО, это опасное заблуждение, возможно справедливое для файлов с именами формата 8.3. Например (совершенно случайно наткнулся), команда:
dir /B /A:D "????????-????-????-????-????????????"
Выдаст (естественно, при наличии папок)
73c58a87-39c7-4571-b760-3a70505b271
73c58a87-39c7-4571-b760-5a70505b271f
73c58a87-39c7-4571-b760-5

Спрогнозировать иные выверты работы команд CMD с маской не берусь, сталкивался с ними не раз, для меня это непредсказуемо, хотя когда-то на форуме объяснение звучало
А вот CMD с рег выражением отработал и пока обмануть его не получилось.
Кстати, в моём vbs-скрипте с этой маской тоже кривая история, так что надо его переписывать, алгоритм только придумать.

[dreamzed]

Cпасибо Вам Огромное!Да прибудет с Вами высокие зарплаты и крепкое здоровье!