[shisik]

У меня есть .cmd, но он при каждом запуске добавляет новую строку (сколько раз запустишь столько и строк) »

Ну так может его стоит продемонстрировать?

[Iska]

Ну так может его стоит продемонстрировать? »

Давайте я продемонстрирую :

Код:

>>"%SystemRoot%\System32\drivers\etc\hosts" echo 127.0.0.1 XXX.XXX.com

[BKPB]

Это для внесения изменений:

Скрытый текст

@echo off
cd /d "%windir%\system32\drivers"
cd etc

Call :GrantAccess hosts
attrib -R -S -H hosts
echo 127.0.0.1 idb.iobit.com>>hosts
attrib +R hosts
goto :eof

:GrantAccess
takeown /f "%~1"
echo y|cacls "%~1" /g %username%:f
exit /b

Это скрипт, чтобы .bat запускался без показа окна:

Скрытый текст

et WshShell = CreateObject("WScript.Shell")
WshShell.Run chr(34) & "Change.hosts.bat" & Chr(34), 0
Set WshShell = Nothing

[BKPB]

Нашёл .bat который игнорирует адрес если такой уже внесён.

Скрытый текст

@Echo Off
setlocal EnableDelayedExpansion

set sHostFile=%SystemRoot%\System32\drivers\etc\hosts

:: добавление записи в hosts
call :Install 1111.com
:: пишем скрипт отката записи в hosts
call :cl 1111.com

exit /b


:Install
set sHost=%~1

if defined sHost (
for /f "usebackq eol=# tokens=1,2" %%i in ("%sHostFile%") do (
if /i "%%j"=="%sHost%" Set flag=1
)
If not defined flag (echo.127.0.0.1 %sHost%>>"%sHostFile%")
)
goto :eof

:cl
(
echo @Echo Off
echo setlocal enabledelayedexpansion
echo.
echo set sHostFile=%%SystemRoot%%\System32\drivers\etc\hosts
echo set sHost=%~1
echo.
echo for /f "tokens=1* delims=]" %%%%a in ^('find /v /n "" ^^^<"%%sHostFile%%"'^) do ^(
echo echo.%%%%b ^| ^>nul find /i "%%sHost%%" ^|^| ^(echo.%%%%b^>^>"%%SystemRoot%%\System32\drivers\etc\temp_host"^)
echo ^)
echo del /f /q "%%sHostFile%%"
echo ren "%%SystemRoot%%\System32\drivers\etc\temp_host" "hosts"
echo exit /b
)>cl_hosts.cmd
goto :eof

Но осталось два вопроса:

1. Как исправить этот .bat чтобы он только прописывал адрес, но не создавал файл отката внесённых изменений.
2. Можно ли на его основе создать скрипт

[Iska]

(поставил подчёркивания чтобы показать расстояние иначе при сохранении сообщения они принимают одинаковый вид) »

Достаточно использовать предназначенный для того тэг «code».

[BKPB]

Помогите, хотя бы отредактировать .bat чтобы он только прописывал адрес, но не создавал файл отката внесённых изменений.

[y--]

BKPB,
Лень не есть хорошо - ну да ладно - код другой(твой мне не нравится):

Код:

@ECHO OFF
REM Файл для обработки
SET "WORK_FILE=%SystemRoot%\System32\drivers\etc\hosts"
REM Список блокируемых доменов через запятую
SET "BLOCK_DOMAIN=domain1.com,domain2.ru,domain3.net"
FOR %%i IN (%BLOCK_DOMAIN%) DO CALL :WORK "%%~i"
GOTO :EOF
:WORK
FINDSTR /B /I /C:"127.0.0.1" "%WORK_FILE%"|FINDSTR /I /C:"%~1"||(
ECHO 127.0.0.1 %~1>>"%WORK_FILE%"
)
GOTO :EOF

Запуск от имени админа, права переопределять на hosts не стоит(если ты не кулхацкер)...

[BKPB]

y--, Спасибо огромное. И отдельное за совет.

Извините, как поставить благодарность не знаю.

[Iska]

Извините, как поставить благодарность не знаю. »

Так: