CMD/BAT

megaloman · Отправлено: **16:18, 04-06-2016** | #2

westovich, Вы себе противоречите.

Цитата:

Есть задача скопировать файлы с сохранением структуры каталогов в другой каталог и потом грохнуть копируемые файлы

Затем Вы делаете попытку, как мне показалось, скопировать полностью каталог test. Об удалении речь не идёт. При этом Вы пИшите

Цитата:

Места мало, целиком скопировать в другой каталог не получится

Если всё-таки копируете целиком, почему не так? Затем удалить исходные файлы не проблема

Код:

@Echo off

Set "InBox=D:\Test"
Set "OutBox=D:\1"

Pushd "%InBox%"

Xcopy /E *.* "%OutBox%\"

Можно перемещать файлы по папкам, если структура папок в исходном каталоге не надо, её в исходной папке можно легко очистить

Код:

@Echo off

SetLocal EnableExtensions EnableDelayedExpansion

Set "InBox=D:\Test"
Set "OutBox=E:\1"

Pushd "%InBox%"

move /Y *.* "%OutBox%\" >nul 2>nul
FOR /F "usebackq delims=" %%d IN (`Dir /b /s /A:D 2^>nul`) DO (
	Set "Out=%%d"
    	Set Out=!Out:%InBox%=%OutBox%!
	md "!Out!\" 2>nul
	move /Y "%%d\*.*" "!Out!\" >nul 2>nul
)

И, наконец, если структуру каталогов в исходной папке сохранять не надо и если исходная и конечная папки на одном диске. В принципе, исходное дерево каталогов можно восстановить

Код:

@Echo off
cls

Set "InBox=D:\Test"
Set "OutBox=D:\1"

Pushd "%InBox%"

move /Y *.* "%OutBox%\"
FOR /F "usebackq delims=" %%d IN (`Dir /b /A:D 2^>nul`) DO (
	move /Y "%InBox%\%%d" "%OutBox%\" >nul
)

Iska · Отправлено: **16:36, 04-06-2016** | #3

Цитата westovich:

Подскажите пожалуйста, что я делаю не так? »

Пользуйтесь не той операцией для «копирование-удаление». Используйте банальное перемещение, желательно — ручное.

westovich · Отправлено: **09:47, 05-06-2016** | #4

Проблема задачи проста - на резервных носителях HDD, из-за долгого времени хранения (уже больше 7 лет), началась деградация данных. Лечение простое - скопировать данные. Сам носитель цел и для копирования и последующего удаления копируемых данных целиком места там нет. В такой ситуации не спасает и перемещение, т.к. это просто запись файловой системы. Поэтому нужен цикл копирования и последующего удаления копируемого. При этом нужно сохранение структуры - копирую множество каталогов с данными.
В общем нужно из каталога D:\1 по очереди скопировать с подкаталогами все файлы в D:\2 с последующим удалением копируемого и сохранением структуры D\:1

Начал я с цикла копирования, т.к. добавить потом удаление не проблема, как оказалось проблема скопировать.....

Помогите пожалуйста.

Iska · Отправлено: **10:18, 05-06-2016** | #5

westovich, в таком случае просто возьмите DiskFresh - Refresh Hard Disk Signal и используйте.

Foreigner · Отправлено: **10:47, 05-06-2016** | #6

Если уж надо "перекопировать", то:

Код:

@echo off

2>nul md "D:\2"
subst x: "D:\2"

subst z: "D:\1"
pushd z:\

for /f "tokens=*" %%i in ('dir /b /s /ad') do 2>nul md "x:%%~pnxi"
for /f "tokens=*" %%i in ('dir /b /s /a-d') do copy "%%~pnxi" "x:%%~pnxi" && del "%%i"

popd
subst z: /d
subst x: /d

westovich · Отправлено: **08:34, 09-06-2016** | #7

О как, и тот и тот вариант обязательно попробую. Особенно DiskFresh

Спасибо!

З.Ы.
Честно, не знал, что такая тулза есть.