CMD/BAT - CMD - читаю из файла, если первый символ строки =*, то вывести на экран строку

Iska · Отправлено: **21:17, 06-02-2016** | #2

Цитата jester7:

Как бы это организовать правильно ? »

Вот так:

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /f "usebackq delims=" %%i in ("list.txt") do (
	set sVar=%%i
	if "!sVar:~0,1!" equ "*" echo %%i
)

endlocal
exit /b 0

jester7 · Отправлено: **21:40, 06-02-2016** | #3

Спасибо, работает)))

Код:

@echo off
setlocal enableextensions enabledelayedexpansion
for /f "usebackq delims=" %%i in ("list.txt") do (
	set s=%%i
	if "!s:~0,1!" =="\" echo %%i
)



pause

А можно вопросы ламерские?
я уже три дня пытаюсь разобраться в этом старом программировании. (вобще-то я программирую на делфи и прочем)
подскажите, как понят этот язык ?
почему ставятся проценты, а иногда восклицательные знаки ?
= и == я понял логику
почему иногда два процента перед переменной, а иногда окружают переменную с краев?
почему иногда значение текстовой переменной без двойных кавычек, а иногда как у вас с кавычками ?
почему !s:~0,1! - в кавычках ?
почему echo - без собачки спереди ? (кажись понял, вывод на экран убран вначале кода... ЭХО ОФФ)
помогите разобраться...

Iska · Отправлено: **22:58, 06-02-2016** | #4

Цитата jester7:

почему ставятся проценты, а иногда восклицательные знаки ? »

И то, и другое означает раскрытие указанной переменной окружения. Разница в том, что «%…%» раскрывает переменную окружения сразу, в момент разбора команды, а «!…!» — в момент исполнения. В первую очередь это сказывается на операторных скобках — поскольку операторные скобки воспринимаются интерпретатором команд именно как одна единая команда. Например, в Вашем случае:

Цитата jester7:

Код:

For /F "usebackq tokens=* delims=" %%i In ("list.txt") Do (
set d=%i:~0,1%
if %d%== * @echo STROKA= %%i %d%
)

»

«%d%» раскрывается в момент интерпретации команды «for /f» и всё условие выглядит как:

Код:

if == * @echo STROKA= %%i

поскольку в этот момент переменная окружения «d» ещё не существует. Именно для этого вводится понятие отложенного раскрытия переменных окружения, активизируемое командой «setlocal enabledelayedexpansion», а сама переменная окружения для этого обрамляется не символами «%», а «!».

Цитата jester7:

почему иногда два процента перед переменной, »

Это специальные переменные цикла «for». Они не являются переменными окружения и в отличие от них — регистрозависимы. На самом деле символ процента один — просто внутри пакетных файлов символ процента при них должен удваиваться, отсюда и два символа «%» внутри пакетных файлов. А в командной строке будет один символ.

Цитата jester7:

а иногда окружают переменную с краев? »

Это обычные переменные окружения. Вы можете их увидеть по команде «set».

Цитата jester7:

почему иногда значение текстовой переменной без двойных кавычек, а иногда как у вас с кавычками ? почему !s:~0,1! - в кавычках ?»

В пакетных файлах все переменные окружения — строка. Никакими символами строка не выделяется, в том числе и не обрамляется кавычками. В ряде случаев содержимое переменной окружения/переменной цикла может интерпретироваться как число.

В подобном случае:

Цитата Iska:

Код:

if "!sVar:~0,1!" equ "*" echo %%i

»

кавычки обычно используются на случай отсутствия переменной окружения (когда она раскрывается в пустую строку), дабы условие оставалось корректным с точки зрения синтаксиса. Кавычки могут быть заменены, например, на «[» и «]» и т.п.

Цитата jester7:

почему echo - без собачки спереди ? (кажись понял, вывод на экран убран вначале кода... ЭХО ОФФ) »

Именно так.

Foreigner · Отправлено: **23:00, 06-02-2016** | #5

А не проще найти эти строки?

Код:

findstr "^\*.*" file.txt

jester7 · Отправлено: **23:10, 06-02-2016** | #6

Спасибо за пояснение, правда я не все понял )))

блин))) даже С++ проще ))))

Iska · Отправлено: **23:41, 06-02-2016** | #7

Цитата Foreigner:

А не проще найти эти строки? »

Конечно, проще

.

Цитата jester7:

Спасибо за пояснение, правда я не все понял ))) »

Что именно не поняли? Приведённый коллегой Foreigner код делает то же самое, что ранее рассмотренный — выводит строки файла, начинающиеся на «*».

greg zakharov · Отправлено: **10:09, 07-02-2016** | #8

cmd:

Код:

findstr ^\* file

grep:

Код:

grep '^*.*' file

gawk:

Код:

gawk /^*/ file

sed:

Код:

sed -n /^*/p file

powershell:

Код:

Select-String ^\* file

или:

Код:

gc file | ? {$_.StartsWith('*')}

Foreigner · Отправлено: **10:26, 07-02-2016** | #9

Цитата greg zakharov:

sed -n /^*/p file »

Если запускать в cmd.exe, то паттерн надо взять в двойные кавычки, иначе выведет все вхождения "*", включая в других частях строки. В PowerShell работает корректно.

greg zakharov · Отправлено: **10:49, 07-02-2016** | #10

Цитата Foreigner:

Если запускать в cmd.exe, то паттерн надо взять в двойные кавычки, иначе выведет все вхождения "*", включая в других частях строки.

Какой-то странный у Вас sed, однако.