[MKN]

Как лучше определить, что юзаем десятку? »

WinVer2.nsh от kotkovets правильно определяет ОС - Win10 + прочие параметры десятки, но... в пределах запуска скомпилированного скрипта с HDD...
Запускаю тот же скомпилированный скрипт с флешки - ОС Win10, почему то определяется как Win8 + прочие параметры восьмёрки...
И как это понимать ? Сначала было даже смешно..., но как работать с флешки ?

[wolkow70]

MKN,
Windows 8.1 - 6.3
Windows 8 - 6.2
Windows 10 - 10.0
https://msdn.microsoft.com/en-us/lib...=vs.85%29.aspx
У меня в реестре почему-то
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion]
"ProductName"="Windows 10 Home"
[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion]
"CurrentVersion"="6.3"

WinVer2.nsh от kotkovets »

Этот хедер не совместим одновременно со стандартным WinVer.nsh, который мне нужен в скрипте. Вот если бы отдельно функцию выдрать...

[MKN]

Т.е. - при запуске exe-скрипта с флешки из под Win10 и с помощью чисто GetVersionEx, и с помощью WinVer2.nsh - ошибочная версия ОС. (при запуске с флешки из под W7 и W8 - всё ОК)
При запуске с флешки из под Win10 с помощью WMI.nsh ( т.е. с использованием WMIC) - всё определяется правильно :

Код:

;http://nsis.sourceforge.net/WMI_header
OutFile "OperatingSystemInfo.exe"
!include MUI2.nsh
!include WMI.nsh
!include LogicLib.nsh
!insertmacro MUI_LANGUAGE "English"

Var WMI_Caption
Var WMI_Version
Var WMI_CSDVersion
Var WMI_ServicePackMajorVersion
Var WMI_ServicePackMinorVersion
Var WMI_PushVar

Section 
; короткое описание версии операционной системы
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Caption callback_Function
 StrCpy $WMI_Caption $WMI_PushVar

 ; версия ОС
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem Version callback_Function
 StrCpy $WMI_Version $WMI_PushVar

; последний установленный сервис-пак (строка); если никакой сервис-пак не установлен, пустая строка.
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem CSDVersion callback_Function
 StrCpy $WMI_CSDVersion $WMI_PushVar

; версия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMajorVersion callback_Function
 StrCpy $WMI_ServicePackMajorVersion $WMI_PushVar

; подверсия сервис-пака
${WMIGetInfo} root\CIMV2 Win32_OperatingSystem ServicePackMinorVersion callback_Function
 StrCpy $WMI_ServicePackMinorVersion $WMI_PushVar
SectionEnd
 
Function callback_Function
System::Call "user32::OemToChar(t R2, t. r2)"
detailprint "$2"
StrCpy $WMI_PushVar $2 
FunctionEnd

А такой код (ранее предложенный kotkovets), в Win10 - c HDD работате нормально, с флешки в Win10 - вообще не работает

Код:

OutFile "WMI_OperatingSystem.exe" 
!include "LogicLib.nsh" 

!macro IWbemClassObject->Get NameObject OUT
    System::Call "*(i,i,i)i.R4"
    System::Call "$R3->4(w'${NameObject}',i0,iR4,i0,i0)"
    System::Call "*$R4(i.R6,i,i.R5)"
    StrCmp $R6 3 0 +2
    IntFmt $R5 %u $R5
    StrCmp $R6 8 0 +2
    !ifdef NSIS_UNICODE
      IntFmt $R5 %s $R5
    !else
      IntFmt $R5 %S $R5
    !endif
    System::Call "ole32::VariantClear(iR4)"
    System::Free $R4
    StrCpy ${OUT} $R5
!macroend

Section
   System::Call "ole32::CoInitializeEx(i0,i2)"
   System::Call "ole32::CoCreateInstance(g'{4590f811-1d3a-11d0-891f-00aa004b2e24}',i0,i1,g'{dc12a687-737f-11cf-884d-00aa004b2e24}',*i.R0)i.R7"
   ${If} $R7 == 0
      System::Call "ole32::CoInitializeSecurity(i0,i-1,i0,i0,i2,i3,i0,i0,i0)"
      System::Call "$R0->3(w'root\CIMV2',i0,i0,i0,i0,i0,i0,*i.R1)i.R7"
      ${If} $R7 == 0
         System::Call "$R1->20(w'WQL', w'SELECT * FROM Win32_OperatingSystem',i48,i0,*i.R2)i.R7"
         System::Call "$R2->4(i0xffffffff,i1,*i.R3,*i)i.R7"
         ${If} $R7 == 0
              
			    !insertmacro IWbemClassObject->Get "Caption" $7
                      MessageBox MB_OK "Caption=$7"
				!insertmacro IWbemClassObject->Get "Version" $7
				     MessageBox MB_OK "Version=$7"
							 
               System::Call "$R0->2()"
               System::Call "$R1->2()"
               System::Call "$R2->2()"
               System::Call "$R3->2()"
         ${Else}
            System::Call "$R0->2()"
            System::Call "$R1->2()"
            System::Call "$R2->2()"
         ${EndIf}
      ${Else}
        System::Call "$R0->2()"
        System::Call "$R1->2()"
      ${EndIf}
  ${EndIf}
SectionEnd

Может Вячеслав скажет в чём тут дело ? (и подправит код...)

PS StdUtils плаг - также правильно определяет параметры Win10, и с флешки и с HDD. (кстати, он обновился Version 1.08, released 2015-10-10 )

[wolkow70]

MKN,
Коды WMI работают, но нужно в какой-то переменной просто получить значение 10, а не полную версию Оси.
Можно конечно отрезать, но это уже гемор дополнительный.

[kotkovets]

с флешки в Win10 - вообще не работает »

спотыкается здесь именно выделенным, возвращается не ноль в $R7, загадка, причины непонятна......

Код:

         System::Call "$R1->20(w'WQL', w'SELECT * FROM Win32_OperatingSystem',i48,i0,*i.R2)i.R7"
         System::Call "$R2->4(i0xffffffff,i1,*i.R3,*i)i.R7"
         ${If} $R7 == 0

[MKN]

Пример "географического" кода для определения параметров локализации
(используются функции GetUserDefaultLangID GetLocaleInfo GetUserGeoID GetGeoInfo ) :

PHP код:

OutFile "GetGeoInfo_test.exe"

!include LogicLib.nsh
; LCTYPE Constants   -  https://msdn.microsoft.com/en-us/library/ms906223.aspx
!define LOCALE_SCOUNTRY 6
!define LOCALE_SENGCOUNTRY 4098
!define LOCALE_SENGLANGUAGE 0x00001001
;  SYSGEOTYPE enumeration  -  https://msdn.microsoft.com/ru-ru/library/windows/desktop/dd374071(v=vs.85).aspx
!define GEOCLASS_NATION 16
!define GEOID_NOT_AVAILABLE -1
!define GEO_ISO2 4
!define GEO_ISO3 5
!define GEO_OFFICIALNAME 9
!define GEO_LATITUDE 2
!define GEO_LONGITUDE 3

Section
System::Call 'KERNEL32::GetUserDefaultLangID()i.r0'
    DetailPrint LANGID=$0  ;  ID языка, по умолчанию используемого в локали текущего пользователя
System::Call 'KERNEL32::GetLocaleInfo(i$0,i${LOCALE_SENGCOUNTRY},t.r1,i1000)'
    DetailPrint LOCALE_SENGCOUNTRY=$1  ; Полное английское название страны / региона. 
System::Call 'KERNEL32::GetLocaleInfo(i$0,i${LOCALE_SCOUNTRY},t.r1,i1000)'
    DetailPrint LOCALE_SCOUNTRY=$1  ; Полное локализованное название страны / региона.
System::Call 'KERNEL32::GetLocaleInfo(i$0,i${LOCALE_SENGLANGUAGE},t.r1,i1000)'
    DetailPrint LOCALE_SENGLANGUAGE=$1 ;  Полное английское название языка по международному стандарту кода языков ( ISO 639 )

; текущий регион (местоположение)
; Table of Geographical Locations  -  https://msdn.microsoft.com/en-us/library/dd374073.aspx
System::Call 'KERNEL32::GetUserGeoID(i${GEOCLASS_NATION})i.r0'
    DetailPrint GEOID=$0 ; Geographical location identifier (Decimal). 203 - Russia
${If} $0 <> ${GEOID_NOT_AVAILABLE} ; Only available if the user has set a country/location
${AndIf} $0 != "error" ; GetUserGeoID is WinXP+

; Извлекаем информацию о заданном географическом местоположении на основании GeoID
System::Call 'KERNEL32::GetGeoInfo(i$0,i${GEO_ISO2},t.r1,i1000,i0)'
    DetailPrint GEO_ISO2=$1  ;  2-буквенный код страны / региона
System::Call 'KERNEL32::GetGeoInfo(i$0,i${GEO_ISO3},t.r1,i1000,i0)'
    DetailPrint GEO_ISO3=$1  ;  3-буквенный код страны / региона
System::Call 'KERNEL32::GetGeoInfo(i$0,i${GEO_OFFICIALNAME},t.r1,i1000,i0)'
    DetailPrint GEO_OFFICIALNAME=$1  ;  Официальное название страны
System::Call 'KERNEL32::GetGeoInfo(i$0,i${GEO_LATITUDE},t.r1,i1000,i0)'
; координаты расположения страны (точка на карте ~ в центре страны)
    DetailPrint GEO_LATITUDE=$1  ; Широта места. Это значение - число с плавающей точкой.
System::Call 'KERNEL32::GetGeoInfo(i$0,i${GEO_LONGITUDE},t.r1,i1000,i0)'
    DetailPrint GEO_LONGITUDE=$1  ; Долгота места. Это значение - числo с плавающей точкой.
${EndIf}
SectionEnd 

В частности, практический интерес представляет функция GetUserGeoID. Можно автоматом (не выбирая язык из списка) устанавливать, к примеру, язык интерфейса установки и т.д., соответствующий локали пользователя, запустившего инсталлятор.

[MKN]

Да... Похоже для определения Windows 10 надо использовать новую функцию - IsWindowsVersionOrGreater
http://stackoverflow.com/questions/3...ect-windows-10
http://www.tek-tips.com/faqs.cfm?fid=7848

Осталось адаптировать эту функцию под NSIS...

[MKN]

Вариант определения major и minor версий ОС с помощью функции NetWkstaGetInfo.
В Win 10 работатет (и с флешки тоже)

Код:

OutFile WinVer-NetWkstaGetInfo.exe
InstallDir $TEMP
ShowInstDetails show
RequestExecutionLevel admin
Page instfiles
# Примечание: В старых версиях NSIS (в том числе 2,46) System plug-in не поддерживае тип р, нужный для правильной работы кода

; используется структура WKSTA_INFO_100 https://msdn.microsoft.com/ru-ru/library/windows/desktop/aa371402(v=vs.85).aspx
; а именно : DWORD wki100_ver_major  и   DWORD wki100_ver_minor;

Section
    System::Call "netapi32::NetWkstaGetInfo(pn,i100,*p.R1)i.R2"  
    System::Call "*$R1(i,p,p,i.R3,i.R4)"
# в $R3 - основной номер версии ОС ver_major, в $R4 - доп. номер версии**ver_minor
    IntOp $R0 $R3 << 16
    IntOp $R0 $R0 | $R4
    System::Call "netapi32::NetApiBufferFree(pR1)"
;Результат в шестнадцатеричной системе счисления
    # 0x00050000  5.0  Windows 2000
    # 0x00050001  5.1  Windows XP
    # 0x00050002  5.2  Windows XP (x64),  Windows Server 2003, Windows Server 2003 R2
    # 0x00060000  6.0  Windows Vista,         Windows Server 2008
    # 0x00060001  6.1  Windows 7,                Windows Server 2008 R2
    # 0x00060002  6.2  Windows 8,                Windows Server 2012
    # 0x00060003  6.3  Windows 8.1,             Windows Server 2012 R2
    # 0x000A0000  10.0 Windows 10,            Windows Server Technical Preview
    IntFmt $R0 "0x%08X" $R0
DetailPrint "$R0"
; получаем ver_major и ver_minor "в десятичном виде"
    IntOp $0 $R0 >> 16
    IntOp $1 $R0 & 0xFFFF
DetailPrint "$0.$1"
SectionEnd

[wolkow70]

MKN,
Я для своих нужд так сделал:

Var IsOSWin10
StrCpy $IsOSWin10 "0"

Push $R0
Push $R1
ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "ProductName"
StrCpy $R1 $R0 10
${If} $R1 == "Windows 10"
StrCpy $IsOSWin10 "1"
${EndIf}
Pop $R1
Pop $R0

${If} $IsOSWin10 == "1"
Выполняем комманды для Windows 10
${EndIf}

[kotkovets]

Вариант определения major и minor версий ОС с помощью функции NetWkstaGetInfo »

будет время попытаюсь, вшить эти директивчики десяточные в winver2

# Примечание: В старых версиях NSIS (в том числе 2,46) System plug-in не поддерживае тип р, нужный для правильной работы кода »

нормально всё работает на 2,46, вместо p - i (integer)