[Iska]

Возможно ли реализовать описанное выше на cmd/bat? »

Реализовать что именно?

[Elven]

Iska, переименование файлов. Например чтобы файл с именем "показатели мятателей молота.xlsx" был переименован в "показатели мЯтателей молота.xlsx"

[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sSourceFolder=E:\Песочница\0421

if exist "%sSourceFolder%\." (
	pushd "%sSourceFolder%"
	
	for /f "usebackq delims=" %%i in (
		`2^>nul dir /b /a:-d "*.*"`
	) do (
		set sName=%%~i
		set sNewName=!sName:я=Я!
		
		if "!sName!" neq "!sNewName!" (
			ren "!sName!" "!sNewName!"
		)
	)
	
	popd
) else (
	echo Can't find source folder [%sSourceFolder%].
	exit /b 1
)

endlocal
exit /b 0

[Elven]

set sNewName=!sName:я=Я! »

Не знал что так можно.
Весьма круто, спасибо.

[Georgio]

с той самой проклятой протоколом буквой »

Строчная буква "я" "проклята" не только "протоколом", но и интерпретатором командной строки, во всяком случае, в современных ОС Windows.




Информация к размышлению (Windows 8.1):



код пакетного файла в кодировке Win-1251:

Код:

@>.txt (
echo яблоко
echo я
echo.я
)

--

вывод результата в файл:

яблоко ђҐ¦Ё¬ ўлў®¤* Є®¬**¤ ** нЄа** (ECHO) ўЄ«озҐ*. я

;


код пакетного файла в кодировке Win-1251:

Код:

@<nul>.txt (
set/p="яблоко"
set/p="я"
)

--

вывод результата в файл:

блоко

.

[Iska]

Georgio, никто и не обещал работоспособность пакетных файлов в кодировке, отличной от OEM.

[Georgio]

Georgio, никто и не обещал работоспособность пакетных файлов в кодировке, отличной от OEM. »

Я обещаю.

Iska, как Вы предлагаете вывести в файл символ "я" (именно символ с кодом "0xFF"), сохранив пакетный файл

Код:

@<nul>.txt set/p="я"

в кодировке OEM-866?

[Foreigner]

Georgio,
chcp 1251

Код:

@echo off
1>nul chcp 1251

0>nul 1>1.txt (

	set/p="я"
	set /p="яблоко"
	
)

[Georgio]

Foreigner, всё верно. Когда писал:

Я обещаю. »

,
я это и имел в виду. И это как раз пример того, что именно сохранение самого пакетного файла в кодировке OEM-866 приводит к его неработоспособности. А символ "я" очень актуален для пакетных файлов, например, тогда, когда нужно вставить BOM:

Код:

@>nul chcp 1251
@<nul>.txt set/p="яю"

.