[Painkiller]

Вместо "MessageBox MB_OK "Ключа нет ! Здесь же код для этой ситуации." - пишешь свой код , когда ключа нет. »

А где писать когда ключ есть ?

Ладно, решу проблему на delphi

[MKN]

А где писать когда ключ есть ? »

Так очевидно же - после метки keyexist: , т.е. вместо "MessageBox MB_OK "Дальнейший код"
Т.е. , ещё раз - нет ключа: весь твой код установки до keyexist:
Есть ключ: весь необходимый код после keyexist:

[MKN]

Используем с помощью функции AddFontResourceEx - на страницах шрифт, НЕ установленный в системе.

Пример 1. Используем свой шрифт для цифрового табло в часиках. Страницу используем с круглым фейсом с перетаскиванием за любую точку, и украсим шрифтом-снежинками.


комплект для сборки : http://www.mediafire.com/?eh3doa9jt5h34gf

читать дальше »

Код:

!addplugindir .
!include nsDialogs.nsh
!include WinMessages.nsh
!include "FileFunc.nsh"

Page Custom mypagecreate
Page InstFiles
OutFile "TimeFont_RoundFace.exe"

Var dlg
Var button
Var Font1
Var Label
Var Label2
Var Label3
; рамка вокруг окна цифрового табло (не нужна при чёрном фоне)
!define WS_BORDER 0x00800000

Function .onInit
 InitPluginsDir
 File "/oname=$pluginsdir\DIGIFACE.ttf" "DIGIFACE.ttf"
 System::Call 'GDI32::AddFontResourceEx(t"$pluginsdir\DIGIFACE.ttf",i 0x30,i0)'
 File "/oname=$pluginsdir\Faux Snow BRK.ttf" "Faux Snow BRK.ttf"
 System::Call 'GDI32::AddFontResourceEx(t"$pluginsdir\Faux Snow BRK.ttf",i 0x30,i0)'
FunctionEnd

Function .onGUIInit
; вызов DLL для перемещения окна за любую точку
MoveAnywhere::Hook
; окно всегда поверх
System::Call "user32::SetWindowPos(i$HWNDPARENT,i-1,i,i,i,i,i3)"
; убрать заголовок  
System::Call `user32::SetWindowLong(i$HWNDPARENT,i${GWL_STYLE},0x9480084C)i.R0`
; убрать пунктирную рамку границы при перетаскивании окна
System::Call "user32::SystemParametersInfo(i0x0025,i0,*i.R0,i0)"
System::Call "user32::SystemParametersInfo(i0x0025,i1,i0,i0)"
FunctionEnd

Function .onGUIEnd
System::Call "user32::SystemParametersInfo(i0x0025,iR0,i0,i0)"
FunctionEnd
 
Function mypagecreate
nsDialogs::Create 1018
Pop $dlg
; цвет фона страницы (круга)
SetCtlColors $HWNDPARENT "" 0x972FFF
SetCtlColors $dlg "" 0x972FFF

${GetTime} "" "L" $0 $1 $2 $3 $4 $5 $6
System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$4 : $5 : $6",\
                      i${DEFAULT_STYLES}|${WS_BORDER},\
                      i5,i60,i170,i50,i$dlg,i222,i0,i0) i.R2'
; цвет цифры - фон
SetCtlColors $R2 `0xFF0000` `0x000000`

CreateFont $R9 "DIGIFACE" 27
SendMessage $R2 ${WM_SETFONT} $R9 0 

${NSD_CreateButton} 50u 82u 30 20 "OFF" 
Pop $button
; фейс в виде круга
System::Call "*(i, i, i, i)i.r0"
System::Call "User32::GetClientRect(i$HWNDPARENT, ir0)"
System::Call "*$0(i, i, i.r1, i.r2)"
IntOp $1 $1 + 5 
IntOp $2 $2 + 30 
System::Call "Gdi32::CreateRoundRectRgn(i0,i0,i200,i200,i200,i200)i.r0"
System::Call "User32::SetWindowRgn(i$HWNDPARENT, ir0, i1)"

  ; Font снежинки (цифры и буквы - форма снежинок)
  CreateFont $Font1 "Faux Snow BRK" 30
  ${NSD_CreateLabel} 50u 5u 20u 20u "0"
  Pop $Label3
  SendMessage $Label3 ${WM_SETFONT} $Font1 0
  SetCtlColors $Label3 0xFFFFFF 0x972FFF
  
  ${NSD_CreateLabel} 20u 78u 20u 20u "0"
  Pop $Label
  SendMessage $Label ${WM_SETFONT} $Font1 0
  SetCtlColors $Label 0xFFFFFF 0x972FFF
  
  ${NSD_CreateLabel} 80u 78u 20u 20u "0"
  Pop $Label2
  SendMessage $Label2 ${WM_SETFONT} $Font1 0
  SetCtlColors $Label2 0xFFFFFF 0x972FFF

${NSD_OnClick} $button done
${NSD_CreateTimer} OnTimer 1000
nsDialogs::Show
${NSD_KillTimer} OnTimer
FunctionEnd

Function OnTimer
${GetTime} "" "L" $0 $1 $2 $3 $4 $5 $6
${NSD_SetText} $R2 "$4 : $5 : $6"
FunctionEnd

Function done
SendMessage $hwndparent ${WM_CLOSE} 0 0
FunctionEnd

Section
SectionEnd

Пример 2. Используем свой шрифт для оригинальных надписей на странице + туда же поместим снежинки


комплект для сборки : http://www.mediafire.com/?re6kc7ts9ww33hd

читать дальше »

Код:

OutFile "PictBg_Font.exe"
Name "MyFont"

Function onguiinit
 InitPluginsDir
 File "/oname=$pluginsdir\OdessaScriptFWF.ttf" "OdessaScriptFWF.ttf"
 System::Call 'GDI32::AddFontResourceEx(t"$pluginsdir\OdessaScriptFWF.ttf",i 0x30,i0)'
 File "/oname=$pluginsdir\Faux Snow BRK.ttf" "Faux Snow BRK.ttf"
 System::Call 'GDI32::AddFontResourceEx(t"$pluginsdir\Faux Snow BRK.ttf",i 0x30,i0)'
 File "/oname=$pluginsdir\Almonte Snow.ttf" "Almonte Snow.ttf"
 System::Call 'GDI32::AddFontResourceEx(t"$pluginsdir\Almonte Snow.ttf",i 0x30,i0)'
 File /oname=$PLUGINSDIR\p.bmp "p.bmp"
FunctionEnd

!define MUI_CUSTOMFUNCTION_GUIINIT onguiinit
!include MUI2.nsh
Page custom fnc_Create
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "English"

Var dlg
Var Bitmap
Var BitmapHandle
Var Label
Var Font
Var Label2
Var Font2
Var Label3
Var Font3

Function fnc_Create
nsDialogs::Create 1044
Pop $dlg
GetDlgItem $1 $hwndparent 1028
ShowWindow $1 0
GetDlgItem $1 $hwndparent 1035
ShowWindow $1 0

CreateFont $Font "Faux Snow BRK" 50
${NSD_CreateLabel} 10u 160u 400u 50u "0 1 2 3 4 5 6"
Pop $Label
SendMessage $Label ${WM_SETFONT} $Font 0
SetCtlColors $Label 0x0080FF transparent
  
CreateFont $Font2 "OdessaScriptFWF" 45 
${NSD_CreateLabel} 50u 10u 300u 50u "С Новым Годом !"
Pop $Label2
SendMessage $Label2 ${WM_SETFONT} $Font2 45
SetCtlColors $Label2 0xFF0000 transparent
  
CreateFont $Font3 "Almonte Snow" 40
${NSD_CreateLabel} 65u 60u 300u 50u "forum.oszone.net"
Pop $Label3
SendMessage $Label3 ${WM_SETFONT} $Font3 40
SetCtlColors $Label3 0x400080 transparent

   ${NSD_CreateBitmap} 0 0 100% 100% ""
   Pop $Bitmap
   StrCpy $0 $PLUGINSDIR\p.bmp
   System::Call 'user32::LoadImage(i 0, t r0, i ${IMAGE_BITMAP}, i 0, i 0, i ${LR_LOADFROMFILE}) i.s'
   Pop $BitmapHandle
   SendMessage $Bitmap ${STM_SETIMAGE} ${IMAGE_BITMAP} $BitmapHandle

nsDialogs::Show
FunctionEnd

Section
SetAutoClose true
SectionEnd

[Mafia_forever]

Хочу чтоб инсталл копировал файл находящийся рядом сним
Пишу так (File "$EXEDIR\setup.arc) на что компилятор ругается , как решить это ?

[Painkiller]

Пишу так (File "$EXEDIR\setup.arc) на что компилятор ругается , как решить это ? »

Код:

${If} ${FileExists} "$EXEDIR\setup.arc" 

тут код копирования 

${EndIf}

[K.A.V.]

Пишу так (File "$EXEDIR\setup.arc) на что компилятор ругается , как решить это ? »

Справочник по NSIS
Почитайте различие команд File и Copyfiles

[Mafia_forever]

Painkiller Большое спасибо!!!

[MKN]

Бегущая текстовая строка

Код:

!include "nsDialogs.nsh" 
OutFile "ScrollTxt.exe" 
Page custom myPage 

var dialog 
var txt 

Function myPage 
nsDialogs::Create 1018 
Pop $dialog 
${NSD_CreateText} 0 0 100% 8% "С Рождеством !  " 
Pop $txt 
SetCtlColors $txt 0xFF0000 0xffffff 
${NSD_CreateTimer} OnTimer 250
nsDialogs::Show
${NSD_KillTimer} OnTimer
FunctionEnd

Function OnTimer
${NSD_GetText} $txt "$1"
StrCpy $2 $1 1   #   в $2 будет помещен первый символ из $1
StrCpy $1 "$1$2" "" 1    #  из $1$2 будет отсечен первый символ и помещён в $1
${NSD_SetText} $txt "$1"
FunctionEnd

Section 
SectionEnd

В данном примере текст "бежит" справа налево. Вопрос : как изменить направление движения ?

[K.A.V.]

В данном примере текст "бежит" справа налево. Вопрос : как изменить направление движения ? »

У тебя же код уже есть, достаточно изменить команды StrCpy в нужный формат...

Код:

!include "nsDialogs.nsh"
OutFile "ScrollTxt.exe"
Page custom myPage

var dialog
var txt

Function myPage
nsDialogs::Create 1018
Pop $dialog
${NSD_CreateText} 0 0 100% 8% "С Рождеством !  "
Pop $txt
SetCtlColors $txt 0xFF0000 0xffffff
${NSD_CreateTimer} OnTimer 250
nsDialogs::Show
${NSD_KillTimer} OnTimer
FunctionEnd

Function OnTimer
${NSD_GetText} $txt "$1"
StrCpy $2 $1 "" -1
StrCpy $1 "$2$1" -1
${NSD_SetText} $txt "$1"
FunctionEnd

Section
SectionEnd

[MKN]

K.A.V.,
Вот спасибо ! Как всё просто. А я нагородил, что все буквы, как взрывом разбрасывало по строке...

Может подскажешь, как в таком забавном коде, задать конкретное направление (слева-направо) ? А то какие то качели получаются :

Задаём траекторию движения с помощью Math и NsResize плагинов ( http://nsis.sourceforge.net/NsResize_plug-in )

Код:

!AddPluginDir .
!include MUI2.nsh
Name MathLabel
OutFile MathLabel_Test.exe

Page Custom MyPage
!insertmacro MUI_LANGUAGE English

Var Label

Function MyPage
  nsDialogs::Create 1018
  Pop $R0
  ${NSD_CreateLabel} 100% 100% 60u 10u `  C Рождеством !`
  Pop $Label
  SetCtlColors $Label 0xFF0000 0xFFFFFF
  StrCpy $R0 0
  ${NSD_CreateTimer} MathMove 50
  nsDialogs::Show
  ${NSD_KillTimer} MathMove
FunctionEnd

Function MathMove
Math::Script `R0 = R0 + 0.05; R1 = 140 + sin(R0) * 140; R2 = 5 + cos(R0) * 0`
nsResize::Set $Label $R1u $R2u `` ``
FunctionEnd

Section
SectionEnd

Движение и скорость, в зависимости от установленных значений, может быть и по окружности и любыми другими загогулинами...
Например, Math::Script `R0 = R0 + 0.1; R1 = 140 + cos(R0) * 140; R2 = 55 + sin(R0) * 50`