[MKN]

Serg866,
Вот вариант для PAGE_INSTFILES с собственным окном для текста, с текстом-заголовком над этим окном и картинкой :

читать дальше »

Код:

OutFile "PAGE_INSTFILES_TXT_Pict_Test.exe"
Name "PAGE_INSTFILES_TXT_Pict"
InstallDir "$TEMP"
!include MUI2.nsh
!insertmacro MUI_PAGE_DIRECTORY
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ShowTxt
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"
ShowInstDetails nevershow
!define WS_BORDER 0x00800000
!define HWND_TOP            0 
!define SWP_NOSIZE          0x0001 
!define SWP_NOMOVE          0x0002 
!define IDC_BITMAP          1500

Var hBitmap

Function .onInit
  InitPluginsDir
  File /oname=$PLUGINSDIR\vinni.bmp "vinni.bmp"
FunctionEnd

Function ShowTxt
StrCpy $R9 "Текст в окне                                                                       Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                     Текст в окне$\r$\n\
Текст в окне                                                                       Текст в окне"

FindWindow $R0 "#32770" "" $HWNDPARENT

System::Call 'user32::CreateWindowEx(i0,t "EDIT",t "$R9",\
i${DEFAULT_STYLES}|${WS_VSCROLL}|${ES_MULTILINE}|${ES_AUTOVSCROLL}|${WS_BORDER},\
i5,i100,i445,i100,i$R0,i222,i0,i0) i.R1'

SetCtlColors $R1 `0x0000FF` `0x99FFFF`
SendMessage $R0 ${WM_GETFONT} 0 0 $R9
SendMessage $R1 ${WM_SETFONT} $R9 0
SendMessage $R1 ${EM_SETREADONLY} 1 0

StrCpy $R8 "Текст над окном"
System::Call 'USER32::CreateWindowEx(i0,t "STATIC",t "$R8",i ${WS_CHILD}|${WS_VISIBLE},i15,i75,i445,i20,i $R0,i122,i0,i0) i.R5'

SendMessage $R0 ${WM_GETFONT} 0 0 $R8
SendMessage $R5 ${WM_SETFONT} $R8 0

; помещаем на страницу картинку "vinni.bmp" (размеров 58x80)
	System::Call `kernel32::GetModuleHandle(i 0) i.R3`
    System::Call `user32::CreateWindowEx(i 0, t "STATIC", t "", i ${SS_BITMAP}|${WS_CHILD}|${WS_VISIBLE}, i370, i110, i58, i80, i $R0, i ${IDC_BITMAP}, i R3, i 0) i.R1`
    System::Call `user32::SetWindowPos(i R1, i ${HWND_TOP}, i 0, i 0, i 0, i 0, i ${SWP_NOSIZE}|${SWP_NOMOVE})`
    System::Call `user32::LoadImage(i 0, t "$PLUGINSDIR\vinni.bmp", i ${IMAGE_BITMAP}, i 0, i 0, i ${LR_CREATEDIBSECTION}|${LR_LOADFROMFILE}) i.s`
    Pop $hBitmap
    SendMessage $R1 ${STM_SETIMAGE} ${IMAGE_BITMAP} $hBitmap
FunctionEnd

; Free loaded resources.
Function .onGUIEnd
; Destroy the bitmap.
System::Call `gdi32::DeleteObject(i s)` $hBitmap
 FunctionEnd

Section
Sleep 500
SectionEnd

[Painkiller]

Народ , в чем может быть проблема кода :

Код:

${If} ${KeyExists} "${HKLM}\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{0BC570F0-7352-4A3A-B2A2-CA56ADA7375F}"
DetailPrint '[Присутствует] KB2881071 '
${Else}
DetailPrint '[не Установлено] KB2881071'
${EndIf}

Ключ не существует , а код говорит обратное =((
Ось 7 x64

[MKN]

Painkiller,

Что это у тебя за синтаксис ?...

попробуй такие варианты :

Код:

ClearErrors
ReadRegStr $0 HKLM "SOFTWARE\App" ""
${If} ${Errors}
  # ключ не существует
${EndIf}

или

Код:

ClearErrors 
EnumRegKey $ 0 HKCR "SOFTWARE\App" 0 
IfErrors 0 keyexist 
  # ключ не существует 
keyexist:

[Painkiller]

Что это у тебя за синтаксис ?... »

Взял из справочника , использую плагин RegistryFunc

попробуй такие варианты : »

MKN, попробовал твой пример, теперь ключ не существует, не зависимо от того, есть он или нету =((

Код:

ClearErrors
ReadRegStr $0 HKLM "SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{8BEEA2FC-D416-428A-B52A-A3ED45921151}" ""
${If} ${Errors}

DetailPrint '[не Установлено] KB2553140'
${Else}
DetailPrint '[Установлено] KB2553140'

${EndIf}

Нашёл рабочее решение :

Код:

!include "Registry.nsh" 
.....

; ----- KB2881071 -----------
${registry::KeyExists}  "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{0BC570F0-7352-4A3A-B2A2-CA56ADA7375F}" $9
StrCmp $9 0 0 +2
DetailPrint '[Присутствует] KB2881071'
StrCmp $9 -1 0 +2
DetailPrint '[нету] KB2881071'
SectionEnd

Но мне нужно засунь определенные действия в каждый из случаев . ${If} ${Else}${EndIf} не прокатывают =((

[MKN]

Painkiller,
Конечно не работает, ведь ReadRegStr читает не сам ключ, а его значение (а оно у тебя пусто, или по факту какое то есть ? Если есть, то вполне можно "привязаться" к нему)
Если значения нет, используй EnumRegKey, с ним работает :

Код:

ClearErrors
EnumRegKey $0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{0BC570F0-7352-4A3A-B2A2-CA56ADA7375F}" 0
IfErrors 0 keyexist
MessageBox MB_OK "Ключа нет ! Здесь же код для этой ситуации."
keyexist:
MessageBox MB_OK "Дальнейший код"

[K.A.V.]

Но мне нужно засунь определенные действия в каждый из случаев . ${If} ${Else}${EndIf} не прокатывают =(( »

Код:

${registry::KeyExists}  "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{0BC570F0-7352-4A3A-B2A2-CA56ADA7375F}" $9
 ${If} $9 == 0
 MessageBox MB_OK|MB_ICONINFORMATION "[Присутствует] KB2881071"
 ${Else}
 MessageBox MB_OK|MB_ICONINFORMATION "нету KB2881071"
${EndIf}

[Painkiller]

Радовался что все получилось , да вот зря=(( Не все ключ правильно определяет (((

[MKN]

Не все ключ правильно определяет »

В смысле ? Нужно определить не просто наличие ключа, а конкретно его название ?
Тогда можно так :

Код:

${Do}
EnumRegKey $1 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" $0  # перечисляются все разделы в ветке Uninstall
IntOp $0 $0 + 1
StrCpy $2 $1
${If} $2 == "{90140000-0012-0000-0000-0000000FF1CE}_Office14.STANDARD_{0BC570F0-7352-4A3A-B2A2-CA56ADA7375F}"
ClearErrors
MessageBox MB_OK "$1"
${EndIf}
${LoopUntil} $1 == ""

[Painkiller]

MKN, мне нужен код чтобы при наличии ключа выполнял какие-то действия и при его отсутствии тоже выполнял определенные действия ?? Как изменить код , который вы мне оставили для моих нужд ?

[MKN]

Painkiller,

мне нужен код чтобы при наличии ключа выполнял какие-то действия и при его отсутствии тоже выполнял определенные действия ? »

Так пример же дан. :

Код:

MessageBox MB_OK "Ключа нет ! Здесь же код для этой ситуации."
keyexist:
MessageBox MB_OK "Дальнейший код"

Вместо "MessageBox MB_OK "Ключа нет ! Здесь же код для этой ситуации." - пишешь свой код , когда ключа нет.