[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

for /l %%i in (1,1,999) do for %%j in ("rar" "jpg") do (
	set sFile=%%~i.%%~j
	<nul set /p sVar=!sFile!	
	if exist "!sFile!" (
		echo *
	) else (
		echo.
	)
)

endlocal
exit /b 0

[megaloman]

Позаимствовал у Iska кусок кода, предлагаю решение, более наглядное, с моей точки зрения, для анализа наличия файлов. Решение работает для нескольких расширений.

Код:

Echo Off

SetLocal EnableExtensions EnableDelayedExpansion

Echo %Date% %Time% >"%0.log"

for /l %%i in (1,1,999) do (
	Set "Znak="
	Set "nExt="

	for %%j in (rar jpg dbf) do (
		Set "Out=%%i.%%j        "
		Set Out=!Out:~0,8!

		If Exist %%i.%%j (
			Set "Znak=!Znak!+"
			Set "nExt=!nExt! +!Out!"
		) Else (
			Set "Znak=!Znak!-"
			Set "nExt=!nExt! -!Out!"
		)
	)
	Echo !Znak! !nExt!
	Echo !Znak! !nExt! >>"%0.log"
)
Start notepad "%0.log"

[kiripanda]

Код:

@echo off &setlocal enabledelayedexpansion

for /f "delims=" %%a in ('dir /b *.rar *.jpg') do set "%%~na=!%%~na!%%~xa"

del /q log.txt
for /l %%i in (1,1,999) do (
	if /i not "!%%i!"==".rar.jpg" echo %%i: !%%i!>>log.txt
)
endlocal

start log.txt