[kozikozi]

goto /? »

это я прочел в справке, но все равно понять не могу, как же он тогда тут работает?

Код:

@echo off
setlocal

set /p cnt="Введите начальное значение: "
for /f "delims=" %%i in ('
"dir /a-d/b *.jpg 2>nul"
') do (
 call:rename "%%i"
 )

set /p p="Введите путь перемещения: "
move *.jpg "%p%">nul

endlocal
goto:eof


:rename
 set pref=00%cnt%
 ren %1 "name_%pref:~-3%.jpg"
 set /a cnt+=1
 goto:eof

особенно часть:

Код:

:rename
 set pref=00%cnt%
 ren %1 "name_%pref:~-3%.jpg"
 set /a cnt+=1
 goto:eof

Выполняется переименование файла, потом к переменной прибавляется единица ии.. передает управление в конец.. это же и так конец? куда он управление передает?

[Iska]

А… Тут всё интереснее. Надо ещё читать «call /?»:

… Изменение команды CALL при включении расширенной обработки команд: Команда CALL допускает использование меток в качестве адресата вызова. Применяется следующий синтаксис: Код: CALL :метка аргументы При вызове создается новый контекст текущего пакетного файла с заданными аргументами, и управление передается на инструкцию, расположенную сразу после метки. Для выхода из такого пакетного файла необходимо дважды достичь его конца. Первый выход возвращает управление на инструкцию, расположенную сразу после строки CALL, а второй выход завершает выполнение пакетного файла. …

читать дальше »

• При вызове «call :rename "%%i"» создаётся новый контекст текущего пакетного файла и управление передаётся за метку «:rename».
• Исполняется код после метки «:rename». Как исполнение доходит до «goto :eof» (второго) — происходит передача управления в конец пакетного файла и тем самым — завершение текущего («нового» из предыдущего пункта) контекста, и управление возвращается на следующую после вызывавшего «call» инструкцию.
• Продолжается исполнение пакетного файла, вплоть до «goto :eof» (первого), который аналогично передаёт управление в конец пакетного файла и завершает его работу.

[kozikozi]

А… Тут всё интереснее. Надо ещё читать «call /?»: »

Вот это сильно.. Всё стало сразу понятно как это работает, большое спасибо!!
Вот еще вопросик возник, решил сделать еще проверку введенного пути (код проверки нашел на форуме), вышло вот что:

Код:

@echo off
setlocal

set /p cnt="Какого начальное значение: "
for /f "delims=" %%i in ('
"dir /a-d/b *.jpg 2>nul"
') do (
 call:rename "%%i"
 )

:prov
set /p p="Введите путь перемещения: "
if exist %p% goto next
goto main

:next
move *.jpg "%p%">nul

endlocal
goto:eof

:rename
 set pref=00%cnt%
 ren %1 "name_%pref:~-3%.jpg"
 set /a cnt+=1
 goto:eof

:main
 echo Данный путь: "%p%" не найден, повторите попытку
 goto prov

Что странно с моими знаниями в bat языке, оно работает как надо, а сам вопрос состоит в том, нельзя ли было сделать проверку проще?

[kozikozi]

А так же интересно стало.. что то сразу не приметил. Вот здесь:

Код:

for /f "delims=" %%i in ('
"dir /a-d/b *.jpg 2>nul"
') do (
 call:rename "%%i"
 )

мы создаем переменную, в ней собственно создаем список всех *.jpg файлов в папке и переходим к метке :rename передавая ей переменную i, но когда смотрим метку :rename

Код:

:rename
 set pref=00%cnt%
 ren %1 "name_%pref:~-3%.jpg"
 set /a cnt+=1
 goto:eof

то видим что она работает с переменной 1... так и должно быть?

[Iska]

мы создаем переменную, в ней собственно создаем список всех *.jpg файлов в папке »

Нет. мы получаем в «dir /a-d/b *.jpg 2>nul» набор строк, затем по «for /f» разбираем его на строки (поскольку «"delims="» — используется вся строка целиком, а не какие-то её отдельные части), и затем для каждой строки вызываем процедуру «call :rename».

и переходим к метке :rename передавая ей переменную i, но когда смотрим метку :rename … то видим что она работает с переменной 1... так и должно быть? »

Разумеется. Мы передаём не переменную «%%i», а её содержимое. Внутри нового контекста (помните?) в «:rename» первый переданный параметр будет доступен именно как «%1».

[kozikozi]

Спасибо.. понятно.. А как на счет:

а сам вопрос состоит в том, нельзя ли было сделать проверку проще? »

и я вот еще с чем начал путаться, работая с переменной, ее где то обозначают: %i% или же %%i, а в чем разница?

[Iska]

и я вот еще с чем начал путаться, работая с переменной, ее где то обозначают: %i% или же %%i, а в чем разница? »

Это две разные переменные. Причём вторая — регистрозависима и доступна только внутри того цикла разбора, где она определена.

[kozikozi]

Это две разные переменные. Причём вторая — регистрозависима и доступна только внутри того цикла разбора, где она определена. »

Большое спасибо. И еще выплыл маленький вопрос:

Код:

for /f "delims=" %%i in ('
"dir /a-d/b *.jpg 2>nul"
') do (
 call:rename "%%i"
 )

цифра 2 здесь что дает?

[Iska]

цифра 2 здесь что дает? »

Перенаправление стандартного потока ошибок (Стандартные потоки — Википедия) на пустое устройство (Null device - Wikipedia, the free encyclopedia).

Фактическим результатом является подавление появления сообщений об ошибках (отсутствующий каталог, не найдено файлов и пр.), которые таким образом не попадают ошибочно в разбор по «for /f».

[kozikozi]

Перенаправление стандартного потока ошибок (Стандартные потоки — Википедия) на пустое устройство (Null device - Wikipedia, the free encyclopedia). »

уяснил, большое спасибо! очень помогли