[kotkovets]

Добавил в шапку: Определение всех ОС WINDOWS (winver2.nsh) >> Расширение функциональности

[Limonica]

Задача, вывести MessageBox "WinName" - "WinType" или "WinServerName" если эта серверная ОС, в примере неправильный вывод, где то нарушена логика, прошу совета.

!include "WinVer2.nsh" OutFile "WinGetVerInfo.exe" Caption WinGetVerInfo Function .OnInit ${WinName} $3 ${WinType} $4 StrCmp $4 "" 0 +3 MessageBox MB_OK "$4" ${WinServerName} $4 MessageBox MB_OK "Win = $3 $4" Quit FunctionEnd Section SectionEnd

[K.A.V.]

Задача, вывести MessageBox "WinName" - "WinType" или "WinServerName" если эта серверная ОС »

Код:

Function .OnInit
 ${WinName} $3
 ${WinType} $4
 ${WinServerName} $5
 StrCmp $5 "" +2 0
 MessageBox MB_OK|MB_ICONINFORMATION "Серверная ОС: $5" idok +2
 MessageBox MB_OK "Win = $3 ($4)"
 Quit
FunctionEnd

[Limonica]

Спасибо за пример, при дальнейшем копании выяснилось, что winver2.nsh конфликтует с nsExec плагином:

Код:

!include "WinVer2.nsh"
OutFile "WinGetVerInfo.exe"
Caption WinGetVerInfo

Function .OnInit

nsExec::exec 'calc.exe'

  ${WinName} $3
  ${WinType} $4
  ${WinServerName} $5

MessageBox MB_OK "$3 $4$5"

FunctionEnd

Section
SectionEnd

В вывод добавляется 0, можно как то это дело исправить?

Код:

---------------------------
WinGetVerInfo
---------------------------
WinXP Professional0
---------------------------
OK   
---------------------------

Код:

---------------------------
WinGetVerInfo
---------------------------
Server 2012 R2 0Server Standard
---------------------------
ОК   
---------------------------

[K.A.V.]

В вывод добавляется 0, можно как то это дело исправить? »

Так удалите с конца 1 символ в строке командой StrCpy (описание есть в справочнике)

Либо просто определяйте ОС до выполнения команды с плагином, на переменные вы не жадный же?

Код:

Function .OnInit
  ${WinName} $3
  ${WinType} $4
  ${WinServerName} $5
  
nsExec::exec 'calc.exe'

MessageBox MB_OK "$3 $4$5"

FunctionEnd

[kotkovets]

Спасибо за пример, при дальнейшем копании выяснилось, что winver2.nsh конфликтует с nsExec плагином »

НЕ конфликтует, плагин оставляет после себя в стеке код возврата, поэтому нужно извлекать код и "очищать"
в доках пишут то так:

Код:

nsExec::exec 'calc.exe'
pop $0

[Flix]

NSIS v3.0 перешла из стадии альфа в стадию бета. Новости здесь. Загрузить релиз можно с оффсайта. Отчеты об ошибках сообщаем на форум NSIS.

[K.A.V.]

NSIS v3.0 перешла из стадии альфа в стадию бета »

Отлично, значит проект реально проснулся, как и наш справочник

Поставил, будем обкатывать, пока что после первых компиляций заметил уменьшение размера всех выходных файлов по сравнению с 3.0a1
В Release notes как-то мало инфы по мелким изменениям даже, как-будто ничего не делали

[MKN]

Расшарить папку и задать права доступа можно с помощью такого кода :

Код:

;создать общий ресурс с полным доступом для всех

outfile "NetShareAdd.exe"
!include "LogicLib.nsh"

# Definitions and user flags
  !define STYPE_DISKTREE                  0
  !define ACCESS_READ                     0x01
  !define ACCESS_WRITE                    0x02
  !define ACCESS_CREATE                   0x04
  !define ACCESS_EXEC                     0x08
  !define ACCESS_DELETE                   0x10
  !define ACCESS_ATRIB                    0x20
  !define ACCESS_PERM                     0x40
  !define ACCESS_ALL                      0x7F

# Permissions
  !define GENERIC_READ                    0x80000000
  !define GENERIC_WRITE                   0x40000000
  !define GENERIC_EXECUTE                 0x20000000
  !define GENERIC_ALL                     0x10000000
  !define NO_INHERITANCE                  0x0
  !define SECURITY_DESCRIPTOR_REVISION    1

# ACCESS_MODE values
  !define NOT_USED_ACCESS                       0
  !define GRANT_ACCESS                          1
  !define SET_ACCESS                            2
  !define DENY_ACCESS                           3
  !define REVOKE_ACCESS                         4
  !define SET_AUDIT_SUCCESS                     5
  !define SET_AUDIT_FAILURE                     6

# MULTIPLE_TRUSTEE_OPERATION values
  !define NO_MULTIPLE_TRUSTEE                   0
  !define TRUSTEE_IS_IMPERSONATE                1

# TRUSTEE_FORM values
  !define TRUSTEE_IS_SID                        0
  !define TRUSTEE_IS_NAME                       1
  !define TRUSTEE_BAD_FORM                      2
  !define TRUSTEE_IS_OBJECTS_AND_SID            3
  !define TRUSTEE_IS_OBJECTS_AND_NAME           4

# TRUSTEE_TYPE values
  !define TRUSTEE_IS_UNKNOWN                    0
  !define TRUSTEE_IS_USER                       1
  !define TRUSTEE_IS_GROUP                      2
  !define TRUSTEE_IS_DOMAIN                     3
  !define TRUSTEE_IS_ALIAS                      4
  !define TRUSTEE_IS_WELL_KNOWN_GROUP           5
  !define TRUSTEE_IS_DELETED                    6
  !define TRUSTEE_IS_INVALID                    7
  !define TRUSTEE_IS_COMPUTER                   8

# Structure Definitions
  !define strSHARE_INFO_2 '(w,i,w,i,i,i,w,w)i'  ;This can be done with the above code by using the SHARE_INFO_2 structure.
  !define strSHARE_INFO_502 '(w,i,w,i,i,i,w,w,i,i)i'
  !define strEXPLICIT_ACCESS '(i,i,i,i,i,i,i,i)i'

!macro CreateNewFullShare SHARENAME SHARE_TYPE SHARE_COMMENT SHARE_PERMISSIONS MAX_USERS CURRENT_USES SHARE_PATH SHARE_PASS
  System::Call /NOUNLOAD '*${strSHARE_INFO_2}("${SHARENAME}",${SHARE_TYPE},"${SHARE_COMMENT}",${SHARE_PERMISSIONS},${MAX_USERS},${CURRENT_USES},"${SHARE_PATH}","${SHARE_PASS}")i.R0'
  System::Call /NOUNLOAD 'netapi32::NetShareAdd(, i 2, i R0, *i .R1) i .r1'
  ${If} $1 <> 0
  MessageBox MB_OK|MB_ICONSTOP|MB_TOPMOST 'There was an error creating the share!'
  ${EndIf}
  System::Free $R0
!macroend

Section
;!insertmacro CreateNewFullShare "Share Name" ${STYPE_DISKTREE} "Share Description" 0 -1 0 "X:\<folder_to_share>" ""
!insertmacro CreateNewFullShare "Temp" ${STYPE_DISKTREE} "Share Description" 0 -1 0 "C:\Temp" ""
SectionEnd

Кроме основного назначения пригодится, например, для админ установки/распаковки MSI пакетов, требующих сетевой путь (продукты ABBYY и др. )

Удалить шару :

Код:

outfile "NetShareDel.exe"
!include "LogicLib.nsh"

!macro RemoveShare SHARENAME
  System::Call /NOUNLOAD 'netapi32::NetShareDel(, w "${SHARENAME}",i 0) i .r1'
  ${If} $1 <> 0
    MessageBox MB_OK|MB_ICONSTOP|MB_TOPMOST 'There was an error removing the share!"'
  ${EndIf}
!macroend

Section
;!insertmacro RemoveShare "ShareName"
!insertmacro RemoveShare "Temp"
SectionEnd

Работает на Win XP и Win 7 (на 8 не проверял)

[Awral]

Как запустить ExecWait в режиме SILENT?