.: NSIS

Kopejkin · Конфигурация компьютера

Цитата K.A.V.:

Думаете я просто так... »

И в мыслях не было морочить вам голову!

Ниже приведены сценарии, которые можно сразу скомпилировать и посмотреть результат. Так сказать, работа над ошибками

В первом я объединил два совета K.A.V. для branding-текста и текста описания компонентов.
Т.е. цвет branding-текста, текста подсказки и текстов описания компонентов становится красным, стили текстов отключаются.

Скрипт от K.A.V.

Код:

;Variant by K.A.V..nsh

!include "mui.nsh"
!include "nsDialogs.nsh"

!define NSD_RemoveStyle "!insertmacro _NSD_RemoveStyle_Call"
!macro _NSD_RemoveStyle_Call CONTROL EXSTYLE
  Push `${CONTROL}`
  Push `${EXSTYLE}`
  System::Store SR1R0
  IntOp $R1 $R1 ~
  System::Call `user32::GetWindowLong(iR0,i${GWL_STYLE})i.R2`
  IntOp $R2 $R1 & $R2
  System::Call `user32::SetWindowLong(iR0,i${GWL_STYLE},iR2)`
  System::Store L
!macroend

!insertmacro MUI_PAGE_WELCOME
!define MUI_PAGE_CUSTOMFUNCTION_PRE RemoveDISABLEDStyle     ; команда отключения стиля для BRANDING.
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"
!define MUI_PAGE_CUSTOMFUNCTION_SHOW RemoveDISABLEDStyle_Description ; отключение стиля описания
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE "Russian"

BrandingText "Nullsoft Scriptable Install System"
Name "'Variant by K.A.V.'"
OutFile "kav.exe"
InstallDir "$TEMP"

Section "Первая секция"
SectionEnd

Section "Вторая секция"
SectionEnd

Function RemoveDISABLEDStyle
  GetDlgItem $0 $HWNDPARENT 1028
  ${NSD_RemoveStyle} $0 0x08000000L
  SetCtlColors $0 "0xFF0000" transparent ; Красный цвет текста
FunctionEnd

Function .onMouseOverSection
    FindWindow $R0 "#32770" "" $HWNDPARENT
    GetDlgItem $R0 $R0 1043

    StrCmp $0 -1 "" +2
    SendMessage $R0 ${WM_SETTEXT} 0 "STR:$(MUI_INNERTEXT_COMPONENTS_DESCRIPTION_INFO)"   ; текст
                    ; "Наведите курсор мыши на название компонента, чтобы прочесть его описание."
                    ;  в зависимости от языка графического интерфейса
    StrCmp $0 0 "" +2
    SendMessage $R0 ${WM_SETTEXT} 0 "STR:Описание первой секции"

    StrCmp $0 1 "" +2
    SendMessage $R0 ${WM_SETTEXT} 0 "STR:Описание второй секции"
FunctionEnd

Function RemoveDISABLEDStyle_Description
    FindWindow $0 "#32770" "" $HWNDPARENT
    GetDlgItem $1 $0 1043
    ${NSD_RemoveStyle} $1 0x08000000L
    SetCtlColors $1 "0xFF0000" "0xF0F0F0" ; Красный текст на сером фоне (цвет фона-ОБЯЗАТЕЛЬНО)
    GetDlgItem $1 $0 1042
    SetCtlColors $1 "" ""                 ; Сейчас установлен прозрачный? цвет фона.
                                          ; Белый цвет "0xFFFFFF" фона на слово "Описание".
                                          ; Элемент рамки, цвет текста не меняется.
FunctionEnd

А этот вариант предложил Flix. Решает те же задачи.

Код:

; Variant by Flix.nsi

!include MUI2.nsh
!include nsDialogs.nsh

!define PRODUCT_NAME "'Variant by Flix'"
SetCompressor lzma
BrandingText "Nullsoft Scriptable Install System"

!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit
!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"

; Функция включения элемента с описанием компонентов
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ENABLEDStyle
; Функция включения элемента с описанием компонентов при наведении курсора мышки
!define MUI_CUSTOMFUNCTION_ONMOUSEOVERSECTION ENABLEDStyleOnSel

!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_LANGUAGE "Russian"

Name "${PRODUCT_NAME}"
OutFile "flix.exe"
InstallDir "$TEMP"

Section "Секция 1" SEC1
SectionEnd

Section "Секция 2" SEC2
SectionEnd

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC1} "Описание первой секции"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC2} "Описание второй секции"
!insertmacro MUI_FUNCTION_DESCRIPTION_END

Function onGUIInit
  ; Получаем дескриптор элемента управления с надписью бренда
  GetDlgItem $0 $HWNDPARENT 1028
  ; Включаем элемент управления (1- включить, 0- отключить)
  EnableWindow $0 1
  SetCtlColors $0 "0xFF0000" transparent ; Красный цвет текста
FunctionEnd

Function ENABLEDStyle
  ; Функция включения стиля для элемента с описанием компонентов.
  ; Выполняем поиск окна
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
  SetCtlColors $1 "0xFF0000" "0xF0F000" ; Красный текст на желтом.
  ; Желтый выбран для наглядности. Цвет фона задавать ОБЯЗАТЕЛЬНО!
  ; Если фон прозрачный - тексты описания накладываются.
FunctionEnd

Function ENABLEDStyleOnSel
  ; Функция включения стиля для элемента с описанием компонентов
  ; при наведении курсора мышки на компоненты установки.
  ; Выполняем поиск окна инсталлятора
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
  SetCtlColors $1 "0xFF0000" "0xF0F000" ; Красный текст на желтом фоне
FunctionEnd

Надеюсь, что ничего не переврал.

Я попытался переделать вариант Flix, использующий скины SkinSharp, в инсталлятор с функцией удаления. Чтобы деинсталлятор тоже был "одет". И стили branding-текста и описаний также отключались.
Но запутался окончательно. То uninstall function "***" not referenced, то Function named ".onGUIInit" already exists. То еще чего-нибудь.

Вот все, что у меня получилось. Прошу не бросать на пол-дороги!

Применение скина SkinSharp в инсталляторе и деинсталляторе.

Данный код позволяет использовать разное цветовое оформление для инсталлятора и деинстраллятора (в пределах выбранного скина).

Код:

;Uninstall_SkinH.nsh

!include MUI2.nsh
!include nsDialogs.nsh

!define PRODUCT_NAME "'Install-Uninstall SkinH'"
SetCompressor lzma
BrandingText "Nullsoft Scriptable Install System"

!insertmacro MUI_PAGE_WELCOME

!define MUI_PAGE_CUSTOMFUNCTION_PRE RemoveDISABLEDStyle
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"

; Функция включения элемента с описанием компонентов
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ENABLEDStyle
; Функция включения элемента с описанием компонентов при наведении курсора мышки
!define MUI_CUSTOMFUNCTION_ONMOUSEOVERSECTION ENABLEDStyleOnSel

!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_COMPONENTS
!insertmacro MUI_UNPAGE_INSTFILES

!insertmacro MUI_LANGUAGE "Russian"

Name "${PRODUCT_NAME}"
OutFile "UninSkinH.exe"

; The default installation directory
InstallDir $DESKTOP\UninSkinH"

Section "Секция 1" SEC1
SectionEnd

Section "Секция 2" SEC2
SectionEnd

Section ""
  SetOutPath $INSTDIR
  ;Create uninstaller
  WriteUninstaller "$INSTDIR\Uninstall.exe"
SectionEnd 

!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC1} "Описание первой секции"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC2} "Описание второй секции"
!insertmacro MUI_FUNCTION_DESCRIPTION_END

Section un."Uninstall Skin"
        delete "$INSTDIR\Uninstall.exe"
        SetShellVarContext all
        RMDir /r "$INSTDIR"
      SetAutoClose false
SectionEnd

Function .onInit
  InitPluginsDir
  SetOutPath $PLUGINSDIR
  File "D:\NSIS\SkinSharp\DLL\ANSI\SkinH.dll"
  File "D:\NSIS\SkinSharp\Skins\0012.she"
  ;При помощи функции SkinH_AttachExt загружаем файл стиля с именем 0012.she
  System::Call SkinH::SkinH_AttachExt(t'$PLUGINSDIR\0012.she',,i-150,i-0,i-0)
  #################### Patches for SkinSharp ####################
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.r0
  IntOp $0 $0 + 0x0002CA98
  System::Call Kernel32::GetCurrentProcess()i.s
  System::Call Kernel32::VirtualProtectEx(is,ir0,i4,i0x40,*i)
  System::Call "*$0(&i1 0)"
  ###############################################################
FunctionEnd

Function RemoveDISABLEDStyle
  ; Получаем дескриптор элемента управления с надписью бренда
  GetDlgItem $0 $HWNDPARENT 1028
  ; Включаем элемент управления (1- включить, 0- отключить)
  EnableWindow $0 1
FunctionEnd

Function ENABLEDStyle
  ; Выполняем поиск окна
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
FunctionEnd

Function ENABLEDStyleOnSel
  ; Функция включения стиля для элемента с описанием компонентов
  ; при наведении курсора мышки на компоненты установки.
  ; Выполняем поиск окна инсталлятора
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
FunctionEnd

Function un.onInit
  InitPluginsDir
  SetOutPath $PLUGINSDIR
  File "D:\NSIS\SkinSharp\DLL\ANSI\SkinH.dll"
  File "D:\NSIS\SkinSharp\Skins\0012.she"
  ;При помощи функции SkinH_AttachExt загружаем файл стиля с именем 0012.she
  System::Call SkinH::SkinH_AttachExt(t'$PLUGINSDIR\0012.she',,i-30,i-0,i-0)
  #################### Patches for SkinSharp ####################
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.r0
  IntOp $0 $0 + 0x0002CA98
  System::Call Kernel32::GetCurrentProcess()i.s
  System::Call Kernel32::VirtualProtectEx(is,ir0,i4,i0x40,*i)
  System::Call "*$0(&i1 0)"
  ###############################################################
FunctionEnd

Function .onGUIEnd
  ; Удаление временной папки
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.s
  System::Call Kernel32::FreeLibrary(is)
  System::Call Kernel32::SetCurrentDirectory(t"$EXEDIR\")
FunctionEnd

Function un.onGUIEnd
  ; Удаление временной папки
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.s
  System::Call Kernel32::FreeLibrary(is)
  System::Call Kernel32::SetCurrentDirectory(t"$EXEDIR\")
FunctionEnd

Flix · Отправлено: **03:26, 01-03-2014** | #**1062**

Цитата Kopejkin:

Я попытался переделать вариант Flix, использующий скины SkinSharp, в инсталлятор с функцией удаления. Чтобы деинсталлятор тоже был "одет". »

Не надо было ничего переделывать, а только по аналогии добавить все тоже самое для деинсталлятора.

Код:

# Поддержка Unicode
Unicode true

!include MUI2.nsh

!define PRODUCT_NAME "'Install-Uninstall SkinH'"
SetCompressor lzma
BrandingText "Nullsoft Scriptable Install System"


##################### Диалоги ИНСТАЛЛЯЦИИ #######################
; Подключаем стиль оформления к интерфейсу
!define MUI_CUSTOMFUNCTION_GUIINIT onGUIInit
; Показываем диалог приветствия
!insertmacro MUI_PAGE_WELCOME
; Показываем диалог с лицензией
!insertmacro MUI_PAGE_LICENSE "${NSISDIR}\Docs\Modern UI\License.txt"
; Включаем элемент с описанием компонентов в диалоге компонентов
!define MUI_PAGE_CUSTOMFUNCTION_SHOW ENABLEDStyle
; Включаем элемент с описанием компонентов при наведении курсора мышки
!define MUI_CUSTOMFUNCTION_ONMOUSEOVERSECTION ENABLEDStyle
; Показываем диалог с выбором компонентов установки
!insertmacro MUI_PAGE_COMPONENTS
; Показываем диалог с выбором пути установки
!insertmacro MUI_PAGE_DIRECTORY
; Показываем диалог установки файлов
!insertmacro MUI_PAGE_INSTFILES
; Показываем диалог завершения установки
!insertmacro MUI_PAGE_FINISH
#################################################################

################### Диалоги ДЕИНСТАЛЛЯЦИИ #######################
; Подключаем стиль оформления к интерфейсу
!define MUI_CUSTOMFUNCTION_UNGUIINIT un.onGUIIni
; Показываем диалог приветствия
!insertmacro MUI_UNPAGE_WELCOME
; Показываем диалог подтверждения
!insertmacro MUI_UNPAGE_CONFIRM
; Включаем элемент с описанием компонентов в диалоге компонентов
!define MUI_PAGE_CUSTOMFUNCTION_SHOW un.ENABLEDStyle
; Включаем элемент с описанием компонентов при наведении курсора мышки
!define MUI_CUSTOMFUNCTION_UNONMOUSEOVERSECTION un.ENABLEDStyle
; Показываем диалог с выбором компонентов деинсталляции
!insertmacro MUI_UNPAGE_COMPONENTS
; Показываем диалог удаления файлов
!insertmacro MUI_UNPAGE_INSTFILES
; Показываем диалог завершения
!insertmacro MUI_UNPAGE_FINISH
#################################################################

; Язык инсталлятора - Русский
!insertmacro MUI_LANGUAGE "Russian"

; Имя инсталлятора
Name "${PRODUCT_NAME}"
; Путь и имя файла инсталлятора
OutFile "UninSkinH.exe"

; Путь установки по умолчанию
InstallDir "$PROGRAMFILES\My application"

Section "Секция 1" SEC1
; Файлы для установки
SectionEnd

Section "Секция 2" SEC2
; Файлы для установки
SectionEnd

Section "Секция 3" SEC3
  SetOutPath $INSTDIR
  ;Create uninstaller
  WriteUninstaller "$INSTDIR\Uninstall.exe"
SectionEnd 

; Секция деинсталлятора
Section "Uninstall" SEC4
  delete "$INSTDIR\Uninstall.exe"
  SetShellVarContext all
  RMDir /r "$INSTDIR"
SectionEnd

; Описание компонентов =ИНСТАЛЛЯТОРА=
!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC1} "Описание первой секции"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC2} "Описание второй секции"
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC3} "Описание третьей секции"
!insertmacro MUI_FUNCTION_DESCRIPTION_END

; Описание компонентов =ДЕИНСТАЛЛЯТОРА=
!insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
  !insertmacro MUI_DESCRIPTION_TEXT ${SEC4} "Описание секции деинсталлятора"
!insertmacro MUI_UNFUNCTION_DESCRIPTION_END

; Функция скинизации интерфейса при инициализации GUI =ИНСТАЛЛЯТОРА=
Function onGUIInit
  InitPluginsDir
  SetOutPath $PLUGINSDIR
  File "${NSISDIR}\Plugins\x86-unicode\SkinH.dll"
  File "${NSISDIR}\Contrib\Skins\0012.she"
  
  # Убираем дефект отображения текста с надписью бренда -------
    ; Получаем дескриптор элемента управления с надписью бренда
    GetDlgItem $0 $HWNDPARENT 1028
    ; Включаем элемент управления (1- включить, 0- отключить)
    EnableWindow $0 1
  # -----------------------------------------------------------
  
  ;При помощи функции SkinH_AttachExt загружаем файл стиля с именем 0012.she
  System::Call SkinH::SkinH_AttachExt(t'$PLUGINSDIR\0012.she',,i-150,i-0,i-0)
  
  #################### Patches for SkinSharp ####################
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.r0
  IntOp $0 $0 + 0x0002CA98
  System::Call Kernel32::GetCurrentProcess()i.s
  System::Call Kernel32::VirtualProtectEx(is,ir0,i4,i0x40,*i)
  System::Call "*$0(&i1 0)"
  ###############################################################
FunctionEnd

; Функция выгрузки SkinH.dll при закрытии GUI =ИНСТАЛЛЯТОРА=
Function .onGUIEnd
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.s
  System::Call Kernel32::FreeLibrary(is)
  System::Call Kernel32::SetCurrentDirectory(t"$EXEDIR\")
FunctionEnd

; Функция скинизации интерфейса при инициализации GUI =ДЕИНСТАЛЛЯТОРА=
Function un.onGUIIni
  InitPluginsDir
  SetOutPath $PLUGINSDIR
  File "${NSISDIR}\Plugins\x86-unicode\SkinH.dll"
  File "${NSISDIR}\Contrib\Skins\0012.she"
  
  # Убираем дефект отображения текста с надписью бренда -------
    ; Получаем дескриптор элемента управления с надписью бренда
    GetDlgItem $0 $HWNDPARENT 1028
    ; Включаем элемент управления (1- включить, 0- отключить)
    EnableWindow $0 1
  # -----------------------------------------------------------
  
  ;При помощи функции SkinH_AttachExt загружаем файл стиля с именем 0012.she
  System::Call SkinH::SkinH_AttachExt(t'$PLUGINSDIR\0012.she',,i-30,i-0,i-0)
  
  #################### Patches for SkinSharp ####################
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.r0
  IntOp $0 $0 + 0x0002CA98
  System::Call Kernel32::GetCurrentProcess()i.s
  System::Call Kernel32::VirtualProtectEx(is,ir0,i4,i0x40,*i)
  System::Call "*$0(&i1 0)"
  ###############################################################
FunctionEnd

; Функция выгрузки SkinH.dll при закрытии GUI =ДЕИНСТАЛЛЯТОРА=
Function un.onGUIEnd
  System::Call Kernel32::GetModuleHandle(t"SkinH.dll")i.s
  System::Call Kernel32::FreeLibrary(is)
  System::Call Kernel32::SetCurrentDirectory(t"$EXEDIR\")
FunctionEnd

; Функция, которая включает элемент с описанием компонентов.
; Используется для диалога с выбором компонентов при инсталляции.
Function ENABLEDStyle
  ; Выполняем поиск окна
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
FunctionEnd

; Функция, которая включает элемент с описанием компонентов.
; Используется для диалога с выбором компонентов при деинсталляции.
Function un.ENABLEDStyle
  ; Выполняем поиск окна
  FindWindow $0 "#32770" "" $HWNDPARENT
  ; Получаем дескриптор элемента управления с описанием компонентов
  GetDlgItem $1 $0 1043
  ; Включаем элемент управления
  EnableWindow $1 1
FunctionEnd

Kopejkin · Конфигурация компьютера

Теперь, когда такие чайники, как я, будут "доставать" форум подобными вопросами, можно просто указать ссылку.

Еще раз спасибо.

4eshireCat · Отправлено: **20:22, 01-03-2014** | #**1064**

Ребят, пожалуйста подскажите, если кто знает - возможно ли на кастомной страничке создать кнопку заданного цвета (например красного) без использования скинов и не подгружая битмап, как в SkinnedButton? Может быть это возможно как-то реализовать через WinAPI? Сам я пока в этой теме не сильно разбираюсь и буду очень благодарен, если кто-то поможет.

wolkow70 · Отправлено: **16:27, 02-03-2014** | #**1065**

Столкнулся с такой ситуацией, что нужно запустить exe файл на стадии Function .OnInit, то есть на этой стадии файл уже должен быть в папке $PLUGINSDIR , а добиться этого никак не могу. Кто-нибудь поможет?

Begin2Fly · Отправлено: **16:36, 02-03-2014** | #**1066**

Цитата wolkow70:

Столкнулся с такой ситуацией, что нужно запустить exe файл на стадии Function .OnInit, то есть на этой стадии файл уже должен быть в папке $PLUGINSDIR , а добиться этого никак не могу. Кто-нибудь поможет? »

InitPluginsDir

MKN · Отправлено: **16:50, 02-03-2014** | #**1067**

Цитата 4eshireCat:

возможно ли на кастомной страничке создать кнопку заданного цвета (например красного) без использования скинов и не подгружая битмап, »

Не подгружая битмап - скорее всего нет.

Цитата 4eshireCat:

Может быть это возможно как-то реализовать через WinAPI? »

Дык всё равно придётся загружать битмап с цветом или рисунком...

А почему такая боязнь загрузки битмапа ?

wolkow70 · Отправлено: **17:01, 02-03-2014** | #**1068**

Цитата Begin2Fly:

InitPluginsDir »

Пробовал, не получается...

Function .OnInit
;
InitPluginsDir
SetOutPath $PLUGINSDIR
File "DTOOLS\SPTDinst-x86.exe"
ExecWait '"$PLUGINSDIR\SPTDinst-x86.exe" add /q'
FunctionEnd

Файла в папке нет.

Begin2Fly · Отправлено: **17:10, 02-03-2014** | #**1069**

wolkow70, попробуйте так:

Код:

Function .OnInit
InitPluginsDir
File /oname=$PLUGINSDIR\SPTDinst-x86.exe "DTOOLS\SPTDinst-x86.exe"
ExecWait '"$PLUGINSDIR\SPTDinst-x86.exe" add /q'
FunctionEnd

wolkow70 · Отправлено: **17:54, 02-03-2014** | #**1070**

Цитата Begin2Fly:

попробуйте так: »

Все равно не распаковывается файл. Хотя сама папка создается, и в ней появляется другой плагин, включенный в скрипт.