[Foreigner]

nfs911,

Код:

... echo %%~nxA

Код:

for /?
call /?

[nfs911]

Foreigner,

%%~nxA »

переменная раскроется в имя файла и его расширение

А значит я получу вместо желаемого результата
test.exe
abc.txt
qwer.bat
start.7z
dell.dll

Напомню что мне нужно получить

test.exe
abc.txt
fold1\qwer.bat
fold1\dir\start.7z
test_dir\dell.dll

[Iska]

Код:

@echo off
setlocal enableextensions enabledelayedexpansion

set sRootFolder=C:\Temp

if exist "%sRootFolder%\." (
	for /f "usebackq delims=" %%i in (
		`dir /b /s /a:-d "%sRootFolder%\*.*"`
	) do (
		set sVar=%%~i
		set sPath=!sVar:%sRootFolder%\=!
		echo [!sPath!]
	)
) else (
	echo Folder [%sRootFolder%] not found.
	exit /b 1
)

endlocal
exit /b 0

[Georgio]

Код:

@echo off

set path_1=D:\test\a
set virt_disk=B:

subst %virt_disk% "%path_1%"|| exit /b
for /f "usebackq tokens=* delims=\" %%B in (`
 for /f ^"tokens^=*^" %%A in ^('dir /s /b /a-d %virt_disk%\'^) do @echo %%~pnxA
`) do (
echo %%B
)
subst %virt_disk% /d
pause>nul
exit /b

[Foreigner]

Напомню что мне нужно получить test.exe abc.txt fold1\qwer.bat fold1\dir\start.7z test_dir\dell.dll »

Сорри, прочитал названия двух верхних файлов и понял вопрос не так.

Код:

@echo off
setlocal

subst s: "d:\test\a"
pushd s:\
for /f "tokens=*" %%i in ('dir /b /s /a-d ') do echo %%~pnxi
popd
subst s: /d

[Georgio]

Код: @echo off setlocal subst s: "d:\test\a" pushd s:\ for /f "tokens=*" %%i in ('dir /b /s /a-d ') do echo %%~pnxi popd subst s: /d »

Foreigner, в Вашем выводе в начале каждой строки присутствует обратный слеш:

Код:

\abc.txt
\test.exe
\fold1\qwer.bat
\fold1\dir\start.7z
\test_dir\dell.dll

В этом же решении обратного слеша в начале каждой строки нет:

Код: @echo off set path_1=D:\test\a set virt_disk=B: subst %virt_disk% "%path_1%"|| exit /b for /f "usebackq tokens=* delims=\" %%B in (` for /f ^"tokens^=*^" %%A in ^('dir /s /b /a-d %virt_disk%\'^) do @echo %%~pnxA `) do ( echo %%B ) subst %virt_disk% /d pause>nul exit /b »

Напомню что мне нужно получить test.exe abc.txt fold1\qwer.bat fold1\dir\start.7z test_dir\dell.dll

[Iska]

Georgio, но всё равно, согласитесь — решение с subst'ом изящное . Первый слэш можно отсечением убирать.

[Georgio]

Georgio, но всё равно, согласитесь — решение с subst'ом изящное. »

Конечно, согласен. Приоритет ведь за мной:

Код: set virt_disk=B: subst %virt_disk% "%path_1%"|| exit /b »

Первый слэш можно отсечением убирать.

Что и было сделано:

Код: for /f "usebackq tokens=* delims=\" %%B in (` for /f ^"tokens^=*^" %%A in ^('dir /s /b /a-d %virt_disk%\'^) do @echo %%~pnxA `) do ( echo %%B ) »

[Foreigner]

Georgio, Слеш можно и не убирать, добавь точку и будет относительный путь. Например:

Код:

... do echo .%%~pnxi

Что и заявлено в названии топика