[MKN]

Ввод цифрового пароля (в примере - это 77777 ) с сопроводительными сообщениями можно организовать и так :

читать дальше »

Код:

OutFile 'Password-Example.exe'

!include "MUI.nsh"
!include "LogicLib.nsh"
!include "nsDialogs.nsh"
!include 'WordFunc.nsh'

Page custom ConfigPage CheckConfig '' 
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_LANGUAGE 'English'
!insertmacro StrFilter

Var Password_Text
Var Password_Confirm

Function ConfigPage
!insertmacro MUI_HEADER_TEXT 'TEXT' 'HEADER_TEXT'
nsDialogs::Create 1018
Pop $0
${NSD_CreateGroupBox} 50% 0 50% 80% "                            Пароль"
${NSD_CreateLabel} 61% 20u 30% 10% '      Введите пароль'
${NSD_CreateLabel} 60% 70u 33% 10% '    Подтвердите пароль'

${NSD_CreatePassword} 65% 40u 20% 10% ''
Pop $Password_Text
${NSD_CreatePassword} 65% 85u 20% 10% ''
Pop $Password_Confirm

; максимальное количества цифр пароля
${NSD_SetTextLimit} $Password_Text 5
${NSD_SetTextLimit} $Password_Confirm 5
		
${NSD_OnChange} $Password_Text EditNotify
${NSD_OnChange} $Password_Confirm EditNotify

nsDialogs::Show
FunctionEnd

Function CheckConfig
${NSD_GetText} $Password_Text $0
${NSD_GetText} $Password_Confirm $1

${If} $0 == ''
${OrIf} $1 == ''
MessageBox MB_OK 'Введите пароль !'
Abort
${EndIf}

; ПАРОЛЬ
StrCpy $5 77777

${If} $0 != $5
MessageBox MB_OK 'Не правильный пароль ! !'
Abort
${EndIf}

${If} $0 == $5
${AndIf} $1 != $5
MessageBox MB_OK 'Не правильное подтверждение пароля !' 
Abort
${EndIf}
FunctionEnd

Function EditNotify
Pop $R0 
; считываем изменения из $R0 и заносим в переменную $0
${NSD_GetText} $R0 $0

; определяем длину строки из $0  ( заносим значение в $1 )
StrLen $1 $0 	

; фильтруем для $0 ( это $Password_Text ), ввод только цифр (для этого уст значение параметра : 1 )
; заносим результат в $2
${StrFilter} $0 '1' '' '' $2

; определяем длину строки из $2 -  ( заносим значение в $3 )
StrLen $3 $2
	
; если $1 равно любому значению, кроме равного $3
${If} $1 <> $3
MessageBox MB_OK 'Для ввода допустимы только цифры !'
${EndIf}
FunctionEnd

Section
SectionEnd

Ессно можно ещё расширить параметры проверки пароля - проверять количество вводимых символов, разбивку на группы (если надо ), сразу вызывать сообщение , если ввод не верный и т.д.

[MKN]

Появился новый "шкурный" проект для NSIS : VCL Styles for NSIS

http://theroadtodelphi.wordpress.com...yles-for-nsis/

Но размер NSISVCLStyles.dll явно велик, что не есть хорошо...

[K.A.V.]

Но размер NSISVCLStyles.dll явно велик »

1,5-то мегабайт? По сравнению с той dll, которую я в SFX Creator юзаю это просто божественно, там от DMSoft целые 6 Мб (правда там упакованы сразу и необходимые DLL), а как здесь поведёт себя DLL на разных системах - нужно только тестить

Вот парни написали скрипт (может, и девушки), а написать инсталлер своего же скина нормально не смогли, сидел тупил сейчас пару минут, хотел сразу после установки скомпилить скрипт примера, а мне компилятор такой говорит

Invalid command: NSISVCLStyles::LoadVCLStyleA Error in script "C:\Program Files\The Road To Delphi\NSISVCLStyles\Scripts\example1.nsi" on line 47 -- aborting creation process

Прошелся по папкам NSIS - и правда нету dll

Вообщем, у кого ОС 32-bit, бегите за файлом плагина в папочку C:\Program Files (x86)\NSIS

кстати, пока бродил по папкам увидел редакторы скинов, запустил, посмотрел пару минут - вроде всё выглядит довольно серьёзно и на первый взгляд - подход разрабов нравится

[MKN]

1,5-то мегабайт? По сравнению с той dll, которую я в SFX Creator юзаю это просто божественно »

Если инсталлер без скина -100К, а ошкуренный в 10 раз более, то это совсем не божественно...
А с установкой автор действительно промахнулся... У меня эта DLL вообще никак и никуда не попала. Пришлось просто извлечь её из установщика.

[K.A.V.]

Если инсталлер без скина -100К, а ошкуренный в 10 раз более »

Паниковать из-за таких цифр можно было лет 10 назад, когда в ходу были флоппи-дисководы, помню, моя первая скопированная игра другу - копирование ярлыка с рабочего стола
Сейчас же, этот мегабайт особого веса не придаёт, если учесть сжатие и объёмы данных, которые пользователям вообще приходится качать в наше время...К тому же, что это за установщик на 100К? Распаковать пару своих фоток?

Всё равно, для альтернативы пойдёт (к тому же, если присутствует встроенный редактор скинов), хоть какое-то разнообразие в поддержке скинов+составление конкуренции другим разрабам подобных плагинов

[MKN]

Сейчас же, этот мегабайт особого веса не придаёт »

Вообщем то да. За исключением всё же, когда инсталлер малого объёма, что бывает часто (разные служебные утилиты и конструкторы). Вот тут то, если захочешь украсить инсталлер, и удивляешься размеру такой одёжки... Ведь есть же та же SkinH.dll, малого объёма.

[K.A.V.]

Проигрывание WAV-файлов

Код:

!define SND_ASYNC 1
!define SND_FILENAME 0x20000
!define SND_LOOP 8


; Проигрываем с ожиданием завершения 
  System::Call 'Winmm::PlaySound(t"$EXEDIR\sound.wav", i0, i${SND_FILENAME})'

; Проигрываем без ожидания завершения 
  System::Call 'Winmm::PlaySound(t"$EXEDIR\sound.wav", i0, i${SND_FILENAME}|${SND_ASYNC})'

; Проигрываем без ожидания завершения + с зацикливанием
  System::Call 'Winmm::PlaySound(t"$EXEDIR\sound.wav", i0, i${SND_FILENAME}|${SND_ASYNC}|${SND_LOOP})'

Может, кому пригодится, буду юзать в своём креаторе

Минимум ОС: Win2000

[Vincent7]

Скажите, почему в onclick функции не срабатывает abort?

Код:

 ${NSD_OnClick} $button click
function click
MessageBox MB_OK "Abort"
abort
functionend

Сообщение есть, аборта нет

[K.A.V.]

Код:

Function func 

 nsDialogs::Create 1018
 pop $0

 ${NSD_CreateButton} 25u 27u 150u 15u "Жми давай!"
 pop $button
 ${NSD_OnClick} $button click 

 nsDialogs::Show 

FunctionEnd


function click
MessageBox MB_OK "Abort"
abort
MessageBox MB_OK|MB_ICONINFORMATION "after abort"
functionend

Сообщение есть, аборт есть, второго сообщения нет, что я делаю не так, чтобы получить ваше "Сообщение есть, аборта нет"?

[Vincent7]

Код:

!include "nsDialogs.nsh"
Page custom func
OutFile "test.exe"

var button

Function func
nsDialogs::Create 1018
pop $0
${NSD_CreateButton} 25u 27u 150u 15u "Жми давай!"
pop $button
${NSD_OnClick} $button click
nsDialogs::Show
FunctionEnd

function click
MessageBox MB_OK "Abort"
abort
MessageBox MB_OK|MB_ICONINFORMATION "after abort"
FunctionEnd
Section
SectionEnd

Первое сообщение есть, аборта нет, второго сообщения нет.