[Foreigner]

Код:

@echo off
setlocal

1>nul chcp 1251

subst n: "C:\Path\To\RootDir" 
pushd n:

for /f "tokens=*" %%i in (' dir /b /s /ad ') do (

    pushd "%%i"
    
    for /f "tokens=*" %%j in (' dir /b /a-d ') do call:rep "%%~nxi" "%%j"

    1>>"dir_%%~nxi.htm" (

        echo ^</ul^>
        echo ^</body^>^</html^>    
    
    )
    
    popd

)

md dir_htm

for /f "tokens=*" %%i in (' dir /b /s dir_*.htm ') do move "%%i" dir_htm

popd
subst n: /d
goto:eof

:rep

if not exist "dir_%~1.htm" 1>"dir_%~1.htm" (

    echo ^<html^>^<head^>
    echo ^<meta http-equiv="Content-Type" content="text/html; charset=windows-1251"^>
    echo ^<title^>%~1^</title^>
    echo ^</head^>^<body^>
    echo ^<h2^>%~1^</h2^>
    echo ^<ul^>

)

1>>"dir_%~1.htm" echo ^<li^>^<a href="..%~pnx2"^>%~2^</a^>^</li^>

Где "C:\Path\To\RootDir" корневая директория для создания htm-отчетов.

[ruslaw]

Спасибо огромное, отлично работает!

[ruslaw]

Но вообще говоря есть некоторые проблемы.
У меня WinXP SP3
Я помещаю батник в сканируемую папку, но он ничего не создает в созданной мной папке "C:\Path\To\RootDir"
Но если уничтожить "C:\Path\To\RootDir" то батник создает папку "dir_htm" в сканируемой папке и потом нужно перенести ее в корневой каталог и тогда ссылки работают. Но в некоторых случаях батник не создает папку, а создает файлы в подпапках и их тоже требуется перемещать в корень.
Но вобщем конечно работает, я колоссально продвинулся в деле каталогизации своей библиотеки и остальное доделаю с помощью программ замены символов.
Еще раз спасибо!!!

[Foreigner]

Цитата ruslaw:

"C:\Path\To\RootDir" »

Батник может лежать где-угодно, а это просто пример, поменяйте путь на нужный вам, тот который является корнем для просматриваемых подкаталогов, например на "C:\Program Files" или какой-нибудь D:\Music

[ruslaw]

Спасибо, попробую