[Iska]

В чём у Вас сложность написания?

[alek2012]

я думал может у кого есть готовый пример, а то времени сейчас нет

[Iska]

а то времени сейчас нет »

Прямо таки совсем никак не выделите и десяти минут?! «Не верю!»

[megaloman]

есть ли в директориях \\srv1\ и \\srv2\

а где директории? ИМХО, здесь имена серверов, должно быть что-то наподобие \\srv1\траляля. В этом случае можно бы было бы написать

Код:

Dir "\\srv1\траляля\admin" /s /b /A:D
Dir "\\srv1\траляля\admin1" /s /b /A:D
Dir "\\srv2\траляля\admin" /s /b /A:D
Dir "\\srv2\траляля\admin1" /s /b /A:D

[Iska]

megaloman, навряд ли потребно с «/s».

[megaloman]

Iska, телепатией не страдаю, при той постановке приходится фантазировать по полной программе. Вполне возможно, надо определить наличие "\\srv1\admin" и т д, тогда задача вообще неинтересная, а я вот изобрёл способ разнообразить себе жизнь Вот возможный вариант

Код:

@Echo Off

Call :kuku "\\Srv1\Admin"
Call :kuku "\\Srv2\Admin"
Call :kuku "\\Srv1\Admin1"
Call :kuku "\\Srv2\Admin1"

Goto :Eof

:Kuku
if exist %1 (Echo %1 имеется) Else (Echo %1 отсутствует)

Кстати, почему-то в одну строку наманер
Set A="\\Srv1\Admin\"& if exist %A% (Echo %A% имеется) Else (Echo %A% отсутствует)
у меня не получилось, что-то неверно в синтаксисе.

[Iska]

Iska, телепатией не страдаю, при той постановке приходится фантазировать по полной программе. »

Это — да, согласен.

Кстати, почему-то в одну строку наманер Set A="\\Srv1\Admin\"& if exist %A% (Echo %A% имеется) Else (Echo %A% отсутствует) у меня не получилось, что-то неверно в синтаксисе. »

Всё верно. Просто «%A%» раскрывается в момент интерпретации всей строки, целиком, т.е.:

Код:

Set A="\\Srv1\Admin\"& if exist %A% (Echo %A% имеется) Else (Echo %A% отсутствует)

Естественно, переменная окружения «A» к этому моменту пустая. Это поведение равнозначно поведению переменной окружения внутри скобок («for … do (…)», «if … (…) else (…)» и т.п.).

Вот, посмотрите:

Код:

rem @echo off
setlocal enableextensions enabledelayedexpansion


set "sPath=%~dp0" & if exist "%sPath%" (echo [%sPath%] exists) else (echo [%sPath%] not found)

endlocal
exit /b 0

Код: E:\Песочница\0268>rem @echo off E:\Песочница\0268>setlocal enableextensions enabledelayedexpansion E:\Песочница\0268>set "sPath=E:\Песочница\0268\" & if exist "" (echo [] exists ) else (echo [] not found ) [] not found E:\Песочница\0268>endlocal E:\Песочница\0268>exit /b 0

Переменная «sPath» раскрывается в момент интерпретации строки, и потому — пуста.

Можно ещё так показать этот момент:

Код:

rem @echo off
setlocal enableextensions enabledelayedexpansion

set "sPath=bla-bla-bla"

set "sPath=%~dp0" & if exist "%sPath%" (echo [%sPath%] exists) else (echo [%sPath%] not found)

endlocal
exit /b 0

Код: E:\Песочница\0268>rem @echo off E:\Песочница\0268>setlocal enableextensions enabledelayedexpansion E:\Песочница\0268>set "sPath=bla-bla-bla" E:\Песочница\0268>set "sPath=E:\Песочница\0268\" & if exist "bla-bla-bla" (echo [bla-bla-bla] exists ) else (echo [bla-bla-bla] not found ) [bla-bla-bla] not found E:\Песочница\0268>endlocal E:\Песочница\0268>exit /b 0

Вывод — нужно использовать отложенное раскрытие переменной:

Код:

rem @echo off
setlocal enableextensions enabledelayedexpansion

set "sPath=%~dp0" & if exist "!sPath!" (echo [!sPath!] exists) else (echo [!sPath!] not found)

endlocal
exit /b 0

Код: E:\Песочница\0268>rem @echo off E:\Песочница\0268>setlocal enableextensions enabledelayedexpansion E:\Песочница\0268>set "sPath=E:\Песочница\0268\" & if exist "!sPath!" (echo [!sPath!] exists ) else (echo [!sPath !] not found ) [E:\Песочница\0268\] exists E:\Песочница\0268>endlocal E:\Песочница\0268>exit /b 0

[alek2012]

Основная задача заключалась, в том что нужно было взять отключенных пользователей в АД и сравнить их названиями профилей, которые имеют такое же название своих каталогов

[alek2012]

еще такой вопрос, как на PS взять список названий из файла и проверить их существование в директориях например с помощью:

Test-Path \\srv1\ только список имен директорий профайлов admin, admin1, admin2 взять из 1.txt к примеру