[Iska]

Например, так:

читать дальше »

Код:

Option Explicit

Sub Sample()
    Dim i As Long
    Dim objRange As Range

    With Application.FileDialog(msoFileDialogOpen)
        With .Filters
            .Clear
            .Add "Microsoft Excel Workbooks", "*.xls"
            .Add "All files", "*.*"
        End With
        
        .AllowMultiSelect = False
        .InitialView = msoFileDialogViewDetails
        
        If Not .Show() = 0 Then
            For i = 1 To .SelectedItems.Count
                Set objRange = Selection
                
                With Application.Workbooks.Open(.SelectedItems.Item(i))
                    .Sheets.Item("Лист1").Range("b3:c8").Copy
                    
                    With ThisWorkbook.Sheets.Item("Лист1")
                        .Paste objRange
                    End With
                    
                    Application.CutCopyMode = False
                    .Close
                End With
                
                Exit For
            Next i
        End If
    End With
End Sub

[storm_Zcooler]

Спасибо огромное!!!

А можно ли сделать так в том файле из которого импортируется даные есть запись, но там ячейки объеденены, а надо чтобы скопировал эту запись и вставил в другой файл в одну ячейку?

еще вопрос в файле из которого импортируется есть ячейка там указаны размеры например 100Х300Х100 (указаны в см) можно ли при импорте разбить эти данные в три разные ячейки и перевести их в метры.

[Iska]

А можно ли сделать так в том файле из которого импортируется даные есть запись, но там ячейки объеденены, а надо чтобы скопировал эту запись и вставил в другой файл в одну ячейку? »

Поясните приложенными примерами документов с подробными пояснениями.

еще вопрос в файле из которого импортируется есть ячейка там указаны размеры например 100Х300Х100 (указаны в см) можно ли при импорте разбить эти данные в три разные ячейки и перевести их в метры. »

Можно. Точно так же: выложите примеры документов — исходного и результирующего.

[storm_Zcooler]

Прикладываю два файла исходный и результирующий, ячейки откуда и куда выделены соответствующими цветами.

[Iska]

Примерно так:

Код:

Sub Sample2()
    Dim objWorksheet As Worksheet
    
    Dim i As Long
    Dim elem As Variant
    
    
    Set objWorksheet = ThisWorkbook.Sheets.Item("Лист1")
    
    With Application.Workbooks.Open("E:\Песочница\0172\исходный.xls")
        objWorksheet.Range("A4").Value = .Names.Item("TTNNum").RefersToRange.Value
        
        i = 1
        
        For Each elem In Split(.Sheets.Item("сторона 1").Range("L9").Value, "x")
            objWorksheet.Range("F4").Item(1, i).Value = CLng(elem) / 1000
            
            i = i + 1
        Next
        
        .Close
    End With
    
    Set objWorksheet = Nothing
End Sub

есть запись, но там ячейки объеденены, »

Тут сие роли не играет, поскольку мы просто берём значение из ячейки. Обращаемся к диапазону по имени («TTNNum»).

есть ячейка там указаны размеры например 100Х300Х100 (указаны в см) можно ли при импорте разбить эти данные в три разные ячейки и перевести их в метры. »

Насколько я понимаю — либо размеры в мм (а не в см), либо пример Вы привели неверный. Аналогично — читаем значение ячейки по адресу, разбиваем по символу «x» в массив, затем заполняем целевые ячейки, просто перебирая элементы массива.

[storm_Zcooler]

Если у меня в исходном файле ячейка называется TTNNum то код получается
objWorksheet.Range("H9").Value = .Names.Item("TTNNum").RefersToRange.Value
а если у меня просто ячейка C9
objWorksheet.Range("H9").Value = .Names.Item("С9").RefersToRange.Value
выдает ошибку....

[Iska]

а если у меня просто ячейка C9 »

.Names — это коллекция имёнованных диапазонов. «C9» — это не именованный диапазон, а адрес ячейки. Смотрите в том же макросе двумя строчками ниже:

Код:

… .Sheets.Item("сторона 1").Range("L9").Value …

и делайте так же. Например:

Код:

objWorksheet.Range("H9").Value = .Sheets.Item("сторона 1").Range("C9").Value

[storm_Zcooler]

Спасибо тебе огромное, но у меня еще вопрос, обновил файлы!

В исходном файле есть "вид упаковки"(Pallet #1) это площадка, на ней стоят коробки, количество площадок и количество коробок не постоянное и может меняться. Как сделать цикл так чтобы во первых скопировав одну строку проверял есть ли данные в другой если есть то копировал их.
Во вторых надо сделать чтобы ккопировал данные которые Pallet #1 потом отделял их толстой линией, и потом копивал данные которые Pallet #2 и т.д. соответственно ячейки Размеры грузовых мест и Масса (кг).

[Iska]

storm_Zcooler, изложенное Вами задание мне не понятно. Попробуйте уточнить более детально.