[Chestnut]

Ап! Это что невыполнимая задача такая ?

[Iska]

Chestnut, контекстное меню оттого так и называется, что команды его зависят от контекста исполнения. То есть, работает парадигма: «Объект» → «Набор действий, доступных для этого объекта». Потому «лепить» туда создание двух документов в определённой папке совершенно неправильно. «Вывести типа ярлычков этих шаблонов на панель браузера» — всё лучше, чем добавлять в контекстное меню.

Ответьте на ряд вопросов:

1. Озвучьте все имена и пути к документам.
2. Что делать, если по указанному пути существует документ с тем же именем.
3. Опишите подробно, что есть:

и загрузки на определённый ресурс »

[Chestnut]

Iska,

Ответьте на ряд вопросов: 1. Озвучьте все имена и пути к документам. 2. Что делать, если по указанному пути существует документ с тем же именем. 3. Опишите подробно, что есть: »

С удовольствием.

1.Название ...просто "Документы", путь сохранения - рабочий стол и папка "Docs" например , с путём я думаю разберусь мне главное выяснить где его прописать, чтобы при закрытии после редактирования не было никаких уточнений - закрыл и документ там.

2.Если существует - удалять(хотя именно удалить мне вручную ctrr+a не затрудняет,так как там много файлов).

3.Скачивается ряд документов с одного сайта и загружается на другой, это информационные системы. Ряд информации приходится копировать вручную, ссылки там или форму какую и вот именно для таких случаев мне всё это и нужно.

Предполагаю, тут наверное надо задействоать макрос какой(уж не думал,что для таких простых вещей надо так "углубляться"),но я к сожалению в этом ничего не понимаю и разобраться самостоятельно в довольно мудрёном интерфейсе офиса не получится...пробовал так сказать.

[Iska]

1.Название ...просто "Документы", путь сохранения - рабочий стол и папка "Docs" например , с путём я думаю разберусь мне главное выяснить где его прописать, чтобы при закрытии после редактирования не было никаких уточнений - закрыл и документ там. »

хотя именно удалить мне вручную ctrr+a не затрудняет,так как там много файлов »

Речь выше шла о двух документах со строго заданными именами:

пара шаблонов - строго прописать в них названия »

Не понятно.

Вот Вам пример для одного документа на основе одного шаблона (если Вам действительно нужен документ на основе шаблона, отличного от «Normal.dot»/«Normal.dot»):

читать дальше »

Код:

Option Explicit

Const wdUserTemplatesPath = 2
Const wdDoNotSaveChanges  = 0

Dim objFSO
Dim objWshShell
Dim objWord

Dim strTemplateName
Dim strDocumentName
Dim strPath2Save

Dim strPath2Template
Dim strPath2File


Set objFSO      = WScript.CreateObject("Scripting.FileSystemObject")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWord     = WScript.CreateObject("Word.Application")

strTemplateName = "My Template.dotx"
strDocumentName = "Документы.docx"
strPath2Save    = objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), "Docs")

With objWord
	strPath2Template = objFSO.BuildPath(.Options.DefaultFilePath(wdUserTemplatesPath), strTemplateName)
	
	If objFSO.FileExists(strPath2Template) Then
		If objFSO.FolderExists(strPath2Save) Then
			strPath2File = objFSO.BuildPath(strPath2Save, strDocumentName)
			
			With .Documents.Add(strPath2Template)
				If objFSO.FileExists(strPath2File) Then
					objFSO.DeleteFile strPath2File, True
				End If
				
				.SaveAs strPath2File
				.Close wdDoNotSaveChanges
			End With
		Else
			WScript.Echo "Folder [" & strPath2Save & "] not found"
		End If
	Else
		WScript.Echo "Template [" & strPath2Template & "] not found"
	End If
	
	.Quit
End With

Set objWord     = Nothing
Set objWshShell = Nothing
Set objFSO      = Nothing

WScript.Quit 0

Сохраните приведённый код в файле с расширением «.vbs» в кодировке «ANSI»(«Windows-1251»).

Здесь:

Код:

strTemplateName = "My Template.dotx"
strDocumentName = "Документы.docx"
strPath2Save    = objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), "Docs")

имя заданного шаблона, имя документа и путь к папке для сохранения («Рабочий стол» текущего пользователя +"\Docs») соответственно. Задайте свои данные.

Быть может, для Вас будет удобнее сразу его и открывать?

читать дальше »

Код:

Option Explicit

Const wdUserTemplatesPath = 2
Const wdDoNotSaveChanges  = 0

Dim objFSO
Dim objWshShell
Dim objWord

Dim strTemplateName
Dim strDocumentName
Dim strPath2Save

Dim strPath2Template
Dim strPath2File


Set objFSO      = WScript.CreateObject("Scripting.FileSystemObject")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWord     = WScript.CreateObject("Word.Application")

strTemplateName = "My Template.dotx"
strDocumentName = "Документы.docx"
strPath2Save    = objFSO.BuildPath(objWshShell.SpecialFolders("Desktop"), "Docs")

With objWord
	strPath2Template = objFSO.BuildPath(.Options.DefaultFilePath(wdUserTemplatesPath), strTemplateName)
	
	If objFSO.FileExists(strPath2Template) Then
		If objFSO.FolderExists(strPath2Save) Then
			strPath2File = objFSO.BuildPath(strPath2Save, strDocumentName)
			
			With .Documents.Add(strPath2Template)
				If objFSO.FileExists(strPath2File) Then
					objFSO.DeleteFile strPath2File, True
				End If
				
				.SaveAs strPath2File
				.Close wdDoNotSaveChanges
			End With
			
			.Documents.Open strPath2File
			.Visible = True
		Else
			WScript.Echo "Folder [" & strPath2Save & "] not found"
			.Quit
		End If
	Else
		WScript.Echo "Template [" & strPath2Template & "] not found"
		.Quit
	End If
End With

Set objWord     = Nothing
Set objWshShell = Nothing
Set objFSO      = Nothing

WScript.Quit 0

[Chestnut]

Iska,
ЕЕЕЕЕ!!!! Всё получилось . Сам бы не допёр ни в жисть!

хотя именно удалить мне вручную ctrr+a не затрудняет,так как там много файлов »

Речь выше шла о двух документах со строго заданными именами »

Имелось ввиду,что в этой папке и другие файлы,которые после загрузки удаляются из неё вместе с теми файлами,которые создаются по шаблону,ну и так по кругу...Сдаётся мне и этот процесс "выделения и удаления в активном окне" тоже можно сократить до одного клика,но тут уже другая история, поищу подходящий софт с макросами.


Спасибо Вам за отклик и за помощь!!! Сильно помогли, оочень признателен!!

[Iska]

Имелось ввиду,что в этой папке и другие файлы,которые после загрузки удаляются из неё вместе с теми файлами,которые создаются по шаблону »

Спасибо, ясно.

[Chestnut]

Как сделать так, чтобы открываемые шаблоны документа(те варианты, что выше здесь предложены) - сразу открывались в активном окне, при запущенном браузере например???

[Iska]

Chestnut, выше — создаются (а не открываются) документы (а не шаблоны). Поясните, что Вам нужно.

сразу открывались в активном окне »

Активном окне Word'а? Нет ничего проще: INTUIT.ru: Курс: Microsoft Word 2007: ..: Лекция №2: Создание документов и электронных форм.

при запущенном браузере например??? »

Поясните, при чём тут браузер.

[Chestnut]

В общем как хотелось бы: активно окно браузера к примеру(или любое другое приложение) и чтобы после запуска скрипта на создание шаблона документа этот созданный документ открывался поверх активного окна приложения. А то он(документ) появляется у меня в свёрнутом виде в диспетчере задач и по нему надо кликать,вот этот клик и хотелось бы исключить...

И ещё можно ли так, чтоб после копирования при закрытии документа не выводило окна с вопросом да\нет, а сохраняло и закрывало сразу?