[K.A.V.]

Товарищи, рельно ли средствами NSIS в файле opera_install_log.xml все пути C:\Program Files\Opera поменять на путь прописанный в $INSTDIR или нет? »

Реально

[MKN]

Возвращаясь к вышеразбираемому вопросу с определением Provider=* в длинющей строке :

Можно и так :

Код:

Section

;Provider= может находится и в начале
;StrCpy $0 "Provider=SQLOLEDB;Data Source=W2K3SP2\SQLEXPRESS;Initial Catalog=user_db;Persist Security Info=True;User ID=user;Password=user;"

; и  в середине строки

StrCpy $0 "Data Source=W2K3SP2\SQLEXPRESS;Initial Catalog=user_db;Provider=SQLOLEDB;Persist Security Info=True;User ID=user;Password=user;"

${WordFind2X} "$0" "Provider=" ";" "+1" $1

MessageBox MB_OK "$1"   
; В $1 будет SQLOLEDB

SectionEnd

Для сокращения кода строку можно и не заносить в переменную... Хотя может это и дурной тон...

[wolkow70]

Реально »

Обнадеживает. Где можно почитать на счет этого. Это же не простой текстовый файл, а .xml ?

[kotkovets]

wolkow70, в шапке пример парсинга xml
или макросами Word* в папке примеров - большая куча примеров.

[K.A.V.]

Обнадеживает »

Как спросили, так и ответил

Это же не простой текстовый файл, а .xml ? »

Откройте его блокнотом - обычный текстовый файл со множеством строк

Кстати я хотел добавить в справочник пример данного кода (недавно реализовывал для одного проекта)
Чуть причесал и вот сюда выкладываю

Скрипт построчно читает в текстовом файле строки и заменяет определённый текст в строке на ваш

читать дальше »

В начале кода:

Код:

!include "StrFunc.nsh"
!include "WinMessages.nsh"
${StrRep}

Функция поиска и замены фразы в текстовом файле

Код:

Function ReplaceLinesInFile
  Banner::show /NOUNLOAD ""
  Banner::getWindow /NOUNLOAD
        Pop $1
     GetDlgItem $2 $1 1030
; Создаём баннер, чтобы видеть прогресс (для наглядности)

Var /Global _FindInFile ; В эту переменную поместим полный путь к файлу, в котором будем производить замену
Var /Global _LineReplace ; В эту переменную поместим строку, которую будем искать и заменять
Var /Global _LineToInsert ; В эту переменную поместим строку, НА которую мы будем заменять искомую строку
Var /Global _CurLineNumber ; В этой переменной храним номер обрабатываемой строки
Var /Global _CurLine ; В этой переменной храним строку, с которой в данный момент сверяем
Var /Global _LineNumbers ; В этой переменной храним количество строк в искомом файле

StrCpy $_FindInFile '$EXEDIR\opera_install_log.xml' ; Заменяем строки в этом файле
StrCpy $_LineReplace 'C:\Program Files\Opera' ; Ищем и заменяем ЭТУ строку
StrCpy $_LineToInsert '$EXEDIR' ; На что будем заменять

${LineSum} "$_FindInFile" $_LineNumbers ; Подсчитываем количество строк
strcpy $_CurLineNumber 0
startLineRead:
intop $_CurLineNumber $_CurLineNumber + 1

     SendMessage $2 ${WM_SETTEXT} 0 "STR:Обработка строки $_CurLineNumber [Всего: $_LineNumbers]" ; Смотрим прогресс обработки строк =)

IntCmp $_CurLineNumber $_LineNumbers 0 0 endFunc ; Если номер текущей строки больше количества строк в файле - поиск завершен

${LineRead} "$_FindInFile" "$_CurLineNumber" $_CurLine ; Читаем строку по номеру текущей строки
${WordFind} '$_CurLine' "$_LineReplace" "E+1{" $R0 ; Ищем в строке нужный текст

StrCmp $R0 "1" startLineRead 0 ; Если в строке присутствует искомый текст, выполняем код ниже
${LineFind} "$_FindInFile" "" "" "Insert_Line" ; Вызываем функцию Insert_Line, которая произведёт замену
goto startLineRead
endFunc:

  Banner::destroy ; Уничтожаем баннер
FunctionEnd


Function Insert_Line
StrCmp $R8 "$_CurLineNumber" 0 push
        ${StrRep} $_CurLine "$_CurLine" "$_LineReplace" "$_LineToInsert"
	FileWrite $R4 "$_CurLine"
	StrCpy $0 SkipWrite
	push:
	Push $0
FunctionEnd

[wolkow70]

wolkow70, в шапке пример парсинга xml или макросами Word* в папке примеров - большая куча примеров. »

Примерно так, да?

!include "XML.nsh"

SetOutPath "$INSTDIR"
${xml::LoadFile} "$INSTDIR\opera_install_log.xml" $0
${xml::GotoPath} "C:\Program Files\Opera" $0
${xml::SetAttribute} "pathPrefix" "$INSTDIR\" $0
${xml::SaveFile} "" $0
${xml::Unload}

[DruOleg]

Спасибо все за рецепты, сделал так

Код:

;Тип СУБД
StrCpy $DB_type "$connect_string" ;присваиваем строку подключения
${WordFind} "$DB_type" ";" "+1" "$3" ;получаем подстроку до первого символа ' ; '
Strlen $1 "Provider="                  ;вычисляем длину отсекаемой части
StrCpy $DB_type "$3" "" $1                   ;отсекаем 

;Сервер БД
StrCpy $DB_server "$connect_string" ;присваиваем строку подключения
${WordFind} "$DB_server" ";" "+2" "$3" ;получаем подстроку до первого символа ' ; '
Strlen $1 "Data Source="                  ;вычисляем длину отсекаемой части
StrCpy $DB_server "$3" "" $1                   ;отсекаем 

;Имя БД
StrCpy $DB_name "$connect_string" ;присваиваем строку подключения
${WordFind} "$DB_name" ";" "+3" "$3" ;получаем подстроку до первого символа ' ; '
Strlen $1 "Initial Catalog="                  ;вычисляем длину отсекаемой части
StrCpy $DB_name "$3" "" $1                   ;отсекаем 

;Логин пользователя БД
StrCpy $DB_user "$connect_string" ;присваиваем строку подключения
${WordFind} "$DB_user" ";" "+5" "$3" ;получаем подстроку до первого символа ' ; '
Strlen $1 "User ID="                  ;вычисляем длину отсекаемой части
StrCpy $DB_user "$3" "" $1                   ;отсекаем 

;Пароль пользователя БД
StrCpy $DB_password "$connect_string" ;присваиваем строку подключения
${WordFind} "$DB_password" ";" "+6" "$3" ;получаем подстроку до первого символа ' ; '
Strlen $1 "Password="                  ;вычисляем длину отсекаемой части
StrCpy $DB_password "$3" "" $1                   ;отсекаем 

;Определяем тип СУБД: MS SQL или Firebird
${If} $DB_type == "SQLOLEDB"
   StrCpy $DB_type "MS SQL"
   ExecWait "sqlcmd.exe -S $DB_server -d $DB_name -U $DB_user -P $DB_password -i get_version.sql"
${ElseIf} $DB_type == "LCPI.IBProvider"
   StrCpy $DB_type "Firebird"
${Else}
   MessageBox MB_OK "Не удалось определить тип СУБД!!!"
   ;Abort
${EndIf}

Хотел еще спросить как присвоить значение переменной:
ExecWait "sqlcmd.exe -S $DB_server -d $DB_name -U $DB_user -P $DB_password -i get_version.sql"

Запрос:
SELECT REV FROM VERSN - возвращает обычное число... Его и нужно сравнить с числом 14525.

[wolkow70]

K.A.V.,
Попробовал применить приведенную вами функцию. Все работает.

Возникло два вопроса:

1. Если нужно заменить еще значение - назначать новую функцию?
2. Что закомментировать, что бы не было баннера в режиме тихой установки?

[K.A.V.]

wolkow70, сделайте так:

В начале кода

Код:

Var _FindInFile ; В эту переменную поместим полный путь к файлу, в котором будем производить замену
Var _LineReplace ; В эту переменную поместим строку, которую будем искать и заменять
Var _LineToInsert ; В эту переменную поместим строку, НА которую мы будем заменять искомую строку
Var _CurLineNumber ; В этой переменной храним номер обрабатываемой строки
Var _CurLine ; В этой переменной храним строку, с которой в данный момент сверяем
Var _LineNumbers ; В этой переменной храним количество строк в искомом файле

!include "StrFunc.nsh"
${StrRep}

В любой секции или функции вызываем функцию сколько угодно раз, только перед новой заменой, если данные отличаются (в каком файле и что заменить) назначайте переменным новые значения

Код:

Section /o "Моя секция"
StrCpy $_FindInFile '$EXEDIR\opera_install_log.xml' ; Заменяем строки в этом файле
StrCpy $_LineReplace 'C:\Program Files\Opera' ; Ищем и заменяем ЭТУ строку
StrCpy $_LineToInsert '$EXEDIR' ; На что будем заменять
call ReplaceLinesInFile
SectionEnd

Function ReplaceLinesInFile
${LineSum} "$_FindInFile" $_LineNumbers ; Подсчитываем количество строк
strcpy $_CurLineNumber 0
startLineRead:
intop $_CurLineNumber $_CurLineNumber + 1
IntCmp $_CurLineNumber $_LineNumbers 0 0 endFunc ; Если номер текущей строки больше количества строк в файле - поиск завершен
${LineRead} "$_FindInFile" "$_CurLineNumber" $_CurLine ; Читаем строку по номеру текущей строки
${WordFind} '$_CurLine' "$_LineReplace" "E+1{" $R0 ; Ищем в строке нужный текст
StrCmp $R0 "1" startLineRead 0 ; Если в строке присутствует искомый текст, выполняем код ниже
${LineFind} "$_FindInFile" "" "" "Insert_Line" ; Вызываем функцию Insert_Line, которая произведёт замену
goto startLineRead
endFunc:
FunctionEnd

Function Insert_Line
StrCmp $R8 "$_CurLineNumber" 0 push
        ${StrRep} $_CurLine "$_CurLine" "$_LineReplace" "$_LineToInsert"
	FileWrite $R4 "$_CurLine"
	StrCpy $0 SkipWrite
	push:
	Push $0
FunctionEnd

[MKN]

Напомните пожалуйста, каким образом средствами NSIS манипулировать (удалять, заменять, разрегистрировать) "занятые" системой файлы и ключи реестра.
Например, надо разрегистрировать и удалить файлы Adobe Acrobat Reader_а (надо подчистить "хвосты" после неудачного удаления ПО, перед последующей установкой. Такое часто необходимо.) :

\Program Files\Common Files\Adobe\Acrobat\ActiveX\AcroIEHelper.dll и удалить записи его ключей в реестре и др. подобные файлы...
"классически" разрегистрировать и удалить этот файл не возможно...
(Куча ручных действий с выставлением прав - ессно не годится.)

Помнится был способ с назначением системных прав с полным доступом к файлу и рестартом оболочек (Эксплорера или Тотала) Не нахожу никак эту инфу... Желательно без сторонних средств (в смысле, без доп. утилит и дремучих досовских команд). Интересует способ для любых версий ОС.

kotkovets, наверняка решил бы эту проблему средствами API...